"{ Package: 'stx:libtool' }"

AbstractFileBrowser subclass:#FileApplicationNoteBook

	instanceVariableNames:'canvasHolder selectedEditorPage listOfApplications tabMenuIndex

		tabList selectionHistoryList privateTabList'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-Tools-File'

!

AbstractFileApplicationNoteBookComponent subclass:#ArchiveViewApplication

	instanceVariableNames:'archiveFileList enableStopButton fileTable currentSortOrder

		selectionHolder tableColumns commandProcess errorListHolder

		viewErrorList temporaryDirectory enableRemoveErrorOutput

		errorListVisibilityHolder hasListEntriesHolder archiver process

		terminateByMe columnDescriptors inDropMode'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

Object subclass:#ArchivItem

	instanceVariableNames:'fileName size dateAndTime permissions icon ownerGroup method crc

		compressSize ratio version type isDirectory'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook::ArchiveViewApplication

!

AbstractFileApplicationNoteBookComponent subclass:#CommandResult

	instanceVariableNames:'resultStream enableStopButton process labelHolder'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#HtmlViewApplication

	instanceVariableNames:'htmlView labelHolder infoLabelHolder'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#ImageViewApplication

	instanceVariableNames:'imageFile imageView image fitSize fitMode'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#Terminal

	instanceVariableNames:'terminalView'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#TextEditor

	instanceVariableNames:'fileContentsModel doSaveFile modifiedChannel editView enableSave

		enableReload presentation changeItemProcess closeApplication

		semaChangeItem printAsHexDump itemChanged itemRemoved

		enableHexToggle textEditorChangeModificationTime'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#XViewApplication

	instanceVariableNames:'xView xFile vncServerPID vncPortNr vncConnection viewerPID

		vncLock vncServerIsTerminated xItem ext'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

!FileApplicationNoteBook class methodsFor:'application list'!

applicationList

" returns a list of all applications to start by the NoteBookApplication with 

                #className                         #type                    

            example:

            #(  #'FooEditor'                       nil                      )

"

    ^ #(

            #(  #'TextEditor'                      #file                    )

            #(  #'TextEditor'                      #directoryDescription    )

            #(  #'HtmlViewApplication'             nil                      )

            #(  #'FindFileApplication'             nil                      )

            #(  #'Terminal'                        nil                      )

            #(  #'ImageViewApplication'            nil                      )

            #(  #'ArchiveViewApplication'          nil                      )

            #(  #'CommandResult'                   nil                      )

            #(  #'XViewApplication'                nil                      )

       )

!

classFor:aApplicationListItem

    |rawName cls|

    rawName := aApplicationListItem at:1.

    (cls := self privateClassesAt:rawName) isNil ifTrue:[

        cls := Smalltalk at:rawName.

    ].

    ^ cls

!

defaultApplication

" returns the application to be started if no itemQuery returns true or no supportedSuffix is supported

"

    ^ self applicationList detect:[: applItem|

        (((self classFor:applItem) == self textEditorClass)

        and:[(self typeFor:applItem) == #file])

    ] ifNone:[nil].

!

typeFor:aApplicationListItem

    ^ aApplicationListItem at:2

! !

!FileApplicationNoteBook class methodsFor:'classAccess'!

textEditorClass

    ^ TextEditor

! !

!FileApplicationNoteBook class methodsFor:'defaults'!

openAnotherApplicationOnSameItem

    ^ false

! !

!FileApplicationNoteBook class methodsFor:'interface specs'!

windowSpec

    "This resource specification was automatically generated

     by the UIPainter of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the UIPainter may not be able to read the specification."

    "

     UIPainter new openOnClass:NoteBookApplication andSelector:#windowSpec

     NoteBookApplication new openInterface:#windowSpec

     NoteBookApplication open

    "

    <resource: #canvas>

    ^ 

     #(#FullSpec

        #name: #windowSpec

        #window: 

       #(#WindowSpec

          #label: 'FileBrowserV2TextEditor'

          #name: 'FileBrowserV2TextEditor'

          #min: #(#Point 10 10)

          #max: #(#Point 1024 768)

          #bounds: #(#Rectangle 16 42 316 342)

        )

        #component: 

       #(#SpecCollection

          #collection: #(

           #(#NoteBookViewSpec

              #name: 'CommandAndTextEditor'

              #layout: #(#LayoutFrame 0 0.0 0 0.0 0 1.0 0 1.0)

              #model: #selectedEditorPage

              #menu: #tabList

              #useIndex: true

              #accessTabMenuAction: #tabMenuAt:

              #canvas: #canvasHolder

              #keepCanvasAlive: true

            )

           )

        )

      )

! !

!FileApplicationNoteBook class methodsFor:'menu specs'!

tabMenu

    "This resource specification was automatically generated

     by the MenuEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the MenuEditor may not be able to read the specification."

    "

     MenuEditor new openOnClass:FileApplicationNoteBook andSelector:#tabMenu

     (Menu new fromLiteralArrayEncoding:(FileApplicationNoteBook tabMenu)) startUp

    "

    <resource: #menu>

    ^ 

     #(#Menu

        #(

         #(#MenuItem

            #label: 'Close'

            #translateLabel: true

            #value: #doCloseApplication

          )

         )

        nil

        nil

      )

! !

!FileApplicationNoteBook methodsFor:'accessing'!

listOfApplications

    "return the value of the instance variable 'listOfApplications' (automatically generated)"

    listOfApplications isNil ifTrue:[

        listOfApplications := OrderedCollection new.

    ].

    ^ listOfApplications

!

selectionHistoryList

    selectionHistoryList isNil ifTrue:[

        selectionHistoryList := OrderedCollection new.

    ].

    ^ selectionHistoryList

!

selectionHistoryList:aCol

    selectionHistoryList := aCol 

! !

!FileApplicationNoteBook methodsFor:'accessing applications'!

getAllApplicationsByClass:aClass andType:aType

    ^ self listOfApplications select:[ : appl  |

        ((appl class = aClass)

        and:[appl type = aType])

    ].

!

getApplicationByType:aType

    ^ self listOfApplications detect:[ : appl  | 

        (appl type == aType)

    ] ifNone:[nil].

!

getIndexFor:aApplication

    | index |

    index := self listOfApplications indexOf:aApplication.

    index ~~ 0 ifTrue:[

        ^ index.

    ].

    ^ nil.

!

getSameApplicationsFor:aApplication

    ^ self listOfApplications select:[ : appl |

        ( (appl ~= aApplication)    

        and:[ (appl isKindOf:(aApplication class)) 

        and:[ (appl item = (aApplication item)) 

        and:[ (appl type == aApplication type) ]]])

    ].

! !

!FileApplicationNoteBook methodsFor:'actions-app-common'!

changeItem:aItem for:aAppl

    | applIndex string|

    applIndex := self getIndexFor:aAppl.

    (aItem notNil and:[aItem isDirectory not " and:[aAppl type ~= #directoryDescription]"]) ifTrue:[

        (aAppl changeItem:aItem) ifFalse:[ ^ self].

        self fileHistory add:aItem.

        self enableFileHistory value:true.

    ].

    string := aAppl getTabString.

    self privateTabList at:applIndex put:string.

    self doSelect:aAppl.

!

closeSubCanvas:aApplication

    | applIndex historyList localHistoryList selectedPage|

    applIndex := self getIndexFor:aApplication.

    applIndex notNil ifTrue:[

"/        "/ UPDATE THE LAST SELECTION BECAUSE SEL INDEX IS DECREMENTED FOR HIGHER INDEXES

"/        self lastSelection:applIndex.

        historyList := self selectionHistoryList.

        historyList remove:applIndex ifAbsent:nil.

        localHistoryList := OrderedCollection new.

        historyList notEmpty ifTrue:[

            selectedPage := historyList last.

        ] ifFalse:[

            selectedPage := 1.

        ].  

        self selectedEditorPage value:selectedPage.

        historyList do:[ : index |

            index <= applIndex ifTrue:[

                localHistoryList add:index

            ] ifFalse:[

                localHistoryList add:(index - 1)

            ]

        ].

        self selectionHistoryList:localHistoryList.

        self listOfApplications removeIndex:applIndex.

        self privateTabList removeIndex:applIndex.

        self privateTabList isEmpty ifTrue:[

            self viewNoteBookApplicationHolder value:false.

            self enableViewNoteBookApplication value:false.

        ] ifFalse:[

            historyList notEmpty ifTrue:[

                self selectedEditorPage value:(self selectionHistoryList last).

            ]

        ]

    ].

    "/ because subCanvas was configured to keep its view,

    "/ we must destroy it here.

    aApplication window destroy.

!

doCloseApplication

    | appl |

    appl := self listOfApplications at:tabMenuIndex.

    appl doClose.

!

openApplByFileItem:aItem

" use the default class list for open of applications by item "

    | applList applItem itemClass|

    aItem isNil ifTrue:[ ^ self ].

    applList := self applicationList.

    applItem := applList detect:[: aApplItem|

        itemClass := self class classFor:aApplItem.

        (itemClass canOpenItem:aItem).

    ] ifNone:[nil].

    applItem isNil ifTrue:[ ^ self openDefaultApplicationByItem:aItem].

    applItem notNil ifTrue:[

        |  itemType |

        itemType := self class typeFor:applItem.

        itemClass := self class classFor:applItem.

        (self openApplicationClass:itemClass withItem:aItem withType:itemType) isNil ifTrue:[

            ^ self openDefaultApplicationByItem:aItem.            

        ].

    ].

!

openApplicationClass:aClass withItem:aItem withType:aType

    | existingAppl newAppl|

    " do not open not readable items "

    (aItem notNil and:[aItem isDirectory not and:[aItem fileName isReadable not]]) ifTrue:[

        Dialog warn:'Can not open unreadable file ', aItem fileName baseName.

        AbortSignal raise.

    ].

    existingAppl := self tryToGetExistingApplFor:aClass withItem:aItem withType:aType.

    existingAppl notNil ifTrue:[

        self doSelect:existingAppl.

        ^ existingAppl

    ].

    newAppl := aClass new.

    newAppl type:aType.

    (newAppl item:aItem) ifFalse:[ ^ nil ].

    (aItem notNil and:[(aItem isDirectory not) and:[aType ~= #directoryDescription]]) ifTrue:[

        self fileHistory add:aItem.

        self enableFileHistory value:true.

    ].

    self setSameFileIndexFor:newAppl.

    self startApplication:newAppl.

    ^ newAppl

!

openDefaultApplicationByItem:aItem

" open the default application if no application for item is available or the start of the

  available application failed

"

    | applItem |

    applItem := self class defaultApplication.

    applItem notNil ifTrue:[

        |  itemType itemClass|

        itemType := self class typeFor:applItem.

        itemClass := self class classFor:applItem.

        ^ self openApplicationClass:itemClass withItem:aItem withType:itemType.

    ].

    ^ nil

!

setSameFileIndexFor:anAppl

    |sameFiles index item|

    self class openAnotherApplicationOnSameItem not ifTrue:[

        anAppl sameFileIndex:nil.

        ^ self.

    ].

    item := anAppl item.

    item notNil ifTrue:[

        | hasSameFiles |

        sameFiles := self getSameApplicationsFor:anAppl.

        hasSameFiles := sameFiles notEmpty.

        hasSameFiles ifTrue:[

            (sameFiles size == 1 and:[sameFiles first sameFileIndex isNil]) ifTrue:[

                anAppl sameFileIndex:1.

                ^ self

            ] ifFalse:[

                index :=  (sameFiles collect:[:el | (el sameFileIndex ? 1)]) max.

                anAppl sameFileIndex:index + 1.

                ^ self

            ]

        ]. 

        anAppl sameFileIndex:nil.

    ].

!

startApplication:aApplication

    | window|

    aApplication masterApplication:self.

    aApplication window ifNil:[

        window := ApplicationSubView new.

        aApplication createBuilder.

        window client:aApplication.

    ].

    self listOfApplications add:aApplication.

    self privateTabList add:(aApplication getTabString).

    self viewNoteBookApplicationHolder value:true.

    self enableViewNoteBookApplication value:true.

    self doSelect:aApplication.

"/    [

        aApplication postOpenWith:aApplication builder.

"/    ] forkAt:Processor activePriority.

!

tabStringAdd:aString for:aAppl

    | index text stream|

    index := self getIndexFor:aAppl.

    index isNil ifTrue:[ ^ self].

    text := self privateTabList at:index.

    stream := WriteStream on:''.

    stream nextPutAll:text.

    stream space.

    stream nextPutAll:aString.

    self privateTabList at:index put:stream contents.

    stream close.

!

tabStringChangeTo:aString for:aAppl

    | index|

    index := self getIndexFor:aAppl.

    index isNil ifTrue:[ ^ self].

    self privateTabList at:index put:aString.

!

tryToGetExistingApplFor:aClass withItem:aItem withType:aType

    |sameAppl changeAppl selAppl|

    aClass wantNewApplicationAnyway ifTrue:[^ nil].

    sameAppl := self getAllApplicationsByClass:aClass andType:aType.

    sameAppl isEmpty ifTrue:[^ nil].

    ((aType == #directoryDescription) or:[aType == #commandResult]) ifTrue:[

        changeAppl := sameAppl first.

    ] ifFalse:[

        (self openMultipleApplicationsForType value) ifTrue:[

        "/ open more than one application for a class and a type

            (self class openAnotherApplicationOnSameItem) ifTrue:[

                "/ open a new application anyway, no matters if item already open

                ^ nil

            ] ifFalse:[

                "/ if item already changed select the application

                selAppl := sameAppl detect:[ : appl  | 

                        (appl item = aItem) 

                ] ifNone:[nil].

            ].

        ] ifFalse:[

            "/ keep in same application change the first application of the same class and type - if item not changed otherwise open new

                changeAppl := sameAppl detect:[ : appl  | 

                        (appl isModified not)

                ] ifNone:[nil].

        ].

    ].

    changeAppl notNil ifTrue:[

        self changeItem:aItem for:changeAppl.

        selAppl := changeAppl.

    ].

    ^ selAppl.

! !

!FileApplicationNoteBook methodsFor:'actions-app-spec'!

changeDirectoryDescription