"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

ApplicationModel subclass:#AbstractFileBrowser

	instanceVariableNames:'aspects'

	classVariableNames:'DirectoryHistory RuntimeAspects DirectoryBookmarks

		LastEnforcedNameSpace CommandHistory DefaultCommandPerSuffix

		CommandHistorySize LastFileDiffFile DefaultFilters RootHolder

		LastFileSelection LastMoveDestination LastScriptBlockString'

	poolDictionaries:''

	category:'Interface-Tools-File'

!

AbstractFileBrowser class instanceVariableNames:'DisabledCursorImage EnabledCursorImage'

"

 The following class instance variables are inherited by this class:

	ApplicationModel - ClassResources

	Model - 

	Object - 

"

!

Object subclass:#Clipboard

	instanceVariableNames:'method files'

	classVariableNames:''

	poolDictionaries:''

	privateIn:AbstractFileBrowser

!

Object subclass:#CodeExecutionLock

	instanceVariableNames:'locked'

	classVariableNames:''

	poolDictionaries:''

	privateIn:AbstractFileBrowser

!

List subclass:#DirectoryHistory

	instanceVariableNames:'forwardList backList lastWasForwardPath lastBackPath lastAddPath

		backForwardList backForwardIndex'

	classVariableNames:'HistorySize'

	poolDictionaries:''

	privateIn:AbstractFileBrowser

!

Object subclass:#DirectoryHistoryItem

	instanceVariableNames:'path position'

	classVariableNames:''

	poolDictionaries:''

	privateIn:AbstractFileBrowser::DirectoryHistory

!

OrderedSet subclass:#FilenameHistory

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:AbstractFileBrowser

!

Object subclass:#SaveAspectItem

	instanceVariableNames:'value isHolder'

	classVariableNames:''

	poolDictionaries:''

	privateIn:AbstractFileBrowser

!

!AbstractFileBrowser class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    [Author:]

        Christian Penk

"

! !

!AbstractFileBrowser class methodsFor:'accessing'!

currentSelection

    LastFileSelection isNil ifTrue:[

        LastFileSelection := #().

    ].

    ^ LastFileSelection

!

currentSelection:aFilenameCol

    LastFileSelection := aFilenameCol collect:[:file | file asFilename]

!

directoryHistory

    DirectoryHistory isNil ifTrue:[

        DirectoryHistory := self directoryHistoryClass new.

"/        DirectoryHistory inspect.

    ].

    ^ DirectoryHistory

!

resetClassVars

    DirectoryHistory := nil.

    LastFileSelection := nil.

    "

     AbstractFileBrowser resetClassVars

    "

!

rootHolder

    ^ RootHolder

!

rootHolder:aRoot

    RootHolder := aRoot

! !

!AbstractFileBrowser class methodsFor:'accessing-bookmarks'!

addBookmark:aDirectoryPath

    |bookmarks idx|

    bookmarks := self directoryBookmarks.

    idx := bookmarks indexOf:aDirectoryPath.

    idx == 0 ifTrue:[

        bookmarks addLast:aDirectoryPath asFilename.

    ].

!

defaultBookMarksFileDirectory

    ^ Filename homeDirectory

!

defaultBookMarksFilename

    ^ '.fileBrowserBookmarks'

!

directoryBookmarks

    DirectoryBookmarks isNil ifTrue:[                     

        self loadBookmarksFrom:(self defaultBookMarksFileDirectory construct:self defaultBookMarksFilename).

        DirectoryBookmarks isEmptyOrNil ifTrue:[

            DirectoryBookmarks := OrderedCollection new.

            DirectoryBookmarks add:Filename homeDirectory asAbsoluteFilename.

            DirectoryBookmarks add:Filename currentDirectory asAbsoluteFilename.

        ]

    ].

    ^ DirectoryBookmarks

    "

     DirectoryBookmarks := nil.

     self directoryBookmarks.

    "

!

hasBookmarks

    ^ self directoryBookmarks notEmptyOrNil

!

loadBookmarksFrom:aFileNameOrString

    |bookmarks s fileName|

    fileName := aFileNameOrString asFilename.

    FileStream openErrorSignal catch:[

        s := fileName readStream.

    ].

    s isNil ifTrue:[

        ^ self.

    ].

    bookmarks := OrderedCollection new.

    [s atEnd] whileFalse:[

        |line path|

        line := s nextLine.

        path := (Base64Coder decodingOf:line) asString.

        bookmarks add:path.

    ].

    s close.

    DirectoryBookmarks := OrderedCollection new.

    bookmarks do:[:eachPath |

        self addBookmark:eachPath asFilename

    ].

!

removeBookmark:aDirectoryPath

    |bookmarks|

    bookmarks := self directoryBookmarks.

    bookmarks isEmptyOrNil ifTrue:[ ^ self].

    bookmarks remove:aDirectoryPath ifAbsent:[].

!

saveBookmarks

    |fn|

    fn := Dialog 

            requestFileName:'Save Bookmarks'

            default:(self defaultBookMarksFilename)

            fromDirectory:(self defaultBookMarksFileDirectory).

    fn isEmptyOrNil ifTrue:[^ self].

    self saveBookmarksIn:fn

!

saveBookmarksIn:aFileNameOrString

    |bookmarks s fileName|

    bookmarks := self directoryBookmarks.

    bookmarks isEmptyOrNil ifTrue:[ ^ self].

    fileName := aFileNameOrString asFilename.

    fileName exists ifTrue:[

        fileName renameTo:(fileName withSuffix:'sav').

    ].

    s := fileName writeStream.

    bookmarks do:[:eachPath |

        |absolutePath|

        absolutePath := eachPath asFilename pathName.

        s nextPutLine:(Base64Coder new lineLimit:nil; encodingOf:absolutePath).

    ].

    s close.

!

saveBookmarksInDefaultBookmarksFile

    self saveBookmarksIn:(self defaultBookMarksFileDirectory construct:self defaultBookMarksFilename)

! !

!AbstractFileBrowser class methodsFor:'accessing-classes'!

directoryHistoryClass

    ^ AbstractFileBrowser::DirectoryHistory

!

filenameHistoryClass

    ^ FilenameHistory

! !

!AbstractFileBrowser class methodsFor:'defaults'!

commandHistory

    CommandHistory isNil ifTrue:[

        CommandHistory := OrderedCollection new.

    ].

    ^ CommandHistory

!

commandHistorySize

    "max no of entries in the HistoryList "

    CommandHistorySize isNil ifTrue:[

        CommandHistorySize := 50

    ].

    ^ CommandHistorySize

!

defaultFilterList

    DefaultFilters isNil ifTrue:[

        DefaultFilters := #(        '*'

                                    '*.st' 

                                    '*.htm*' 

                                    '*.txt' 

                                    '*.gif' 

                                    '*.xpm' 

                                    '*.jpg' 

                                    '*.[h,c]*' 

                                )

    ].

    ^ DefaultFilters.

!

initialCommandFor:fileName in:aDirectory intoBox:aBox

    "set a useful initial command in an execute box."

    |mime cmd select path suffix baseName pathName|

    path := aDirectory filenameFor:fileName.

    baseName := path baseName.

    suffix := path suffix.

    mime := MIMETypes mimeTypeForSuffix:suffix.

"/    mime notNil ifTrue:[

"/        cmd := self initialCommandForMIME:mime file:path

"/    ].

    "/ XXX should be changed to take stuff from a config file

    "/ XXX or from resources.

    (path type == #regular) ifTrue:[

        path isExecutableProgram ifTrue:[

            aBox initialText:(path pathName , ' <arguments>').

            ^ self

        ].

        select := true.

        "some heuristics - my personal preferences ...

         (actually this should come from a configfile)"

        (baseName endsWith:'akefile') ifTrue:[

            aBox initialText:'make target' selectFrom:6 to:11.

            ^ self

        ].

        cmd := MIMETypes defaultCommandPerMIME at:mime ifAbsent:nil.

        cmd notNil ifTrue:[

            select := false

        ].

        cmd isNil ifTrue:[

            suffix := path suffix.

            (suffix = 'C') ifTrue:[

                cmd := 'g++ -c %1'.

                select := 6.

            ] ifFalse:[

                suffix := suffix asLowercase.

                (suffix = 'taz') ifTrue:[

                    aBox initialText:'zcat %1 | tar tvf -'.

                    select := false.

                ].

                (suffix = 'tar') ifTrue:[

                    cmd := 'tar tvf %1'.

                    select := 7.

                ].

                (suffix = 'zoo') ifTrue:[

                    cmd := 'zoo -list %1'.

                    select := 9.

                ].

                (suffix = 'zip') ifTrue:[

                    cmd := 'unzip -l %1'.

                    select := 8.

                ].

                (suffix = 'jar') ifTrue:[

                    cmd := 'unzip -l %1'.

                    select := 8.

                ].

                (suffix = 'z') ifTrue:[

                    (baseName asLowercase endsWith:'tar.z') ifTrue:[

                        cmd := 'zcat %1 | tar tvf -'.

                        select := false.

                    ] ifFalse:[

                        cmd := 'uncompress %1'

                    ].

                ].

                (suffix = 'gz') ifTrue:[

                    (baseName asLowercase endsWith:'tar.gz') ifTrue:[

                        cmd := ('gunzip < %1 | tar tvf -' ).

                        select := false.

                    ] ifFalse:[

                        cmd := 'gunzip %1'.

                    ].

                ].

                (suffix = 'html') ifTrue:[

                    cmd := 'netscape %1'

                ].

                (suffix = 'htm') ifTrue:[

                    cmd := 'netscape %1'

                ].

                (suffix = 'uue') ifTrue:[

                    cmd := 'uudecode %1'

                ].

                (suffix = 'c') ifTrue:[

                    cmd := 'cc -c %1'.

                    select := 5.

                ].

                (suffix = 'cc') ifTrue:[

                    cmd := 'g++ -c %1'.

                    select := 6.

                ].

                (suffix = 'xbm') ifTrue:[

                    cmd := 'bitmap %1'

                ].

                (suffix = 'ps') ifTrue:[

                    cmd := 'ghostview %1'

                ].

                ((suffix = '1') or:[suffix = 'man']) ifTrue:[

                    cmd := 'nroff -man %1'.

                    select := 10.

                ].

            ].

        ].

        cmd isNil ifTrue:[

            DefaultCommandPerSuffix isNil ifTrue:[

                cmd := '<cmd>'

            ] ifFalse:[

                cmd := DefaultCommandPerSuffix 

                        at:suffix

                        ifAbsent:'<cmd>'.

            ].

            cmd := cmd , ' %1'.

        ].

        pathName := path pathName.

        OperatingSystem isUNIXlike ifTrue:[

            pathName includesSeparator ifTrue:[

                pathName := '"' , pathName , '"'

            ]

        ].

        cmd := cmd bindWith:pathName.

        select == false ifTrue:[

            aBox initialText:cmd

        ] ifFalse:[

            select class == Interval ifTrue:[

                aBox initialText:cmd selectFrom:select start to:select stop

            ] ifFalse:[

                select isInteger ifFalse:[

                    select := (cmd indexOf:Character space ifAbsent:[cmd size + 1]) - 1.

                ].

                aBox initialText:cmd selectFrom:1 to:select

            ].

        ]

    ]

    "Modified: / 24.9.1997 / 16:34:52 / stefan"

    "Modified: / 9.4.1998 / 17:15:57 / cg"

!

listOfRuntimeValuesToRemember

    " list of all aspects that will be remembered after closing a FileBrowserV2"

    ^ #( 

"/        #filterModel

        #enableFileHistory

        #fileHistory

        #currentSortOrder

        #sortBlockProperty 

       )

!

resetAspects

    RuntimeAspects := nil.

    "

     self resetAspects

    "

!

runtimeAspects

    RuntimeAspects isNil ifTrue:[

        RuntimeAspects := Dictionary new.

    ].

    ^ RuntimeAspects

!

userPreferencesAspectList

    " list of all aspects that will be saved with save settings

      that aspects will be image consistent if the settings are saved in Launcher

      dont forget to add a access methos in Userpreferences if you add a aspect here

    "

    ^ #(

           #viewDirsInContentsBrowser

           #showDirectoryTree  

           #showHiddenFiles          

           #viewDescription