"{ Package: 'stx:libtool' }"!

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatExpression:aString in:aClass elementsInto:elementsCollection

    ^self formatExpression:aString in:aClass

    "Created: / 25-07-2010 / 08:57:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 04-10-2011 / 19:47:20 / cg"

! !

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatMethod:aString in:aClass using:preferencesOrNil elementsInto: elements

    ^self formatMethod:aString in:aClass using:preferencesOrNil

    "Created: / 25-07-2010 / 08:58:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractTime class methodsFor:'misc ui support'!

iconInBrowserSymbol

    "the browser will use this as index into the toolbariconlibrary"

    <resource: #programImage>

    ^ #timeClassBrowserIcon

! !

!ApplicationModel methodsFor:'debugging'!

inspectorExtraAttributes

    |atts nameDict bindingDict|

    atts := super inspectorExtraAttributes.

    builder notNil ifTrue:[

        (nameDict := builder namedComponents) notNil ifTrue:[

            nameDict keysAndValuesDo:[:eachName :eachWidget |

                atts add:('-[: ',eachName,' :]') -> [ nameDict at:eachName ].

            ].

        ].

        (bindingDict := builder bindings) notNil ifTrue:[

            bindingDict keysAndValuesDo:[:eachName :eachAspect |

                atts add:('-~> ',eachName) -> [ bindingDict at:eachName ].

            ].

        ].

    ].

    ^ atts

! !

!Array methodsFor:'inspecting'!

inspectorValueStringInListFor:anInspector

    "returns a string to be shown in the inspector's list"

    self size == 0 ifTrue:[

        ^ '#()'

    ].

    ^ super inspectorValueStringInListFor:anInspector

! !

!ArrayedCollection methodsFor:'inspecting'!

inspector2TabForHexDump

    "a tab, showing a hex dump; defined here, so that both byteArrays and other bulk data

     containers can define it in their inspector2Tabs methods."

    |wrapper myByteSize v genDump baseAddress|

    myByteSize := self size * self class elementByteSize.

    wrapper := Plug new.

    wrapper respondTo:#size with:[ myByteSize ].

    wrapper respondTo:#at: with:[:byteIdx | self byteAt:byteIdx ].

    wrapper respondTo:#do: with:[:aBlock | 1 to:myByteSize 

                                            do:[:i |

                                                aBlock value:(self byteAt:i) 

                                            ].

                                ].

    baseAddress := 0.

    genDump := [

                    |dump|

                    v topView withWaitCursorDo:[

                        dump := AbstractFileBrowser 

                            contentsOfBytesAsHexDump:wrapper 

                            numberOfAddressDigits:(myByteSize hexPrintString size) 

                            addressStart:baseAddress.

                        v list:dump expandTabs:false scanForNonStrings:false includesNonStrings:false.

                    ].

               ].

    v := ScrollableView for:TextView. 

    genDump value.

    v scrolledView 

        menuHolder:

            [    

                |m| 

                m := v scrolledView editMenu.

                m addLabel:'-' selector:nil.

                m addLabel:'Change Base Address...' selector:#changeBase.

                m actionAt:#changeBase 

                    put:[ 

                        |s b|

                        s := Dialog request:'Base address (hex):' initialAnswer:(baseAddress printStringRadix:16).

                        s notEmptyOrNil ifTrue:[

                            b := Integer readFrom:s radix:16 onError:nil.

                            b notNil ifTrue:[

                                baseAddress := b. genDump value

                            ].

                        ].

                    ].

                m.

            ];

        menuMessage: #value.

    ^ Tools::Inspector2Tab new

            priority: 40;

            label:'Hexdump';

            view: v;

            yourself

    "Created: / 13-02-2012 / 15:08:42 / cg"

! !

!Autoload class methodsFor:'message catching'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ #()

! !

!Bag methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ super inspectorExtraAttributes

        add:('-histogram' -> [ (self sortedCounts collect:[:e| e displayString]) asStringCollection asString ]);

        yourself

! !

!Behavior methodsFor:'misc ui support'!

iconInBrowserSymbol

    "can be redefined for a private icon in the browser (for me and my subclasses).

     The returned symbol must be a selector of the ToolbarIconLibrary.

     The browser will use this as index into the toolbariconlibrary"

    <resource: #programImage>

    self isLoaded ifFalse:[

        ^ #autoloadedClassBrowserIcon

    ].

    (self isBrowserStartable) ifTrue:[

        self isVisualStartable ifTrue:[

            ^ #visualStartableClassBrowserIcon

        ].

        ^ #startableClassBrowserIcon

    ].

    "/ give ruby and other special metaclasses a chance to provide their own icon...

    ^ self class iconInBrowserSymbol

    "Created: / 20-07-2007 / 08:52:17 / cg"

! !

!Behavior methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ super inspectorExtraAttributes

        add:(self isMeta

                ifFalse:[ '-meta' -> [ self theMetaclass ] ]

                ifTrue:[ '-nonMeta' -> [ self theNonMetaclass ] ]);

        add:( '-project definition class' -> [ self theNonMetaclass projectDefinitionClass ] );

        yourself

! !

!Behavior methodsFor:'inspecting'!

inspectorValueStringInListFor:anInspector

    "returns a string to be shown in the inspector's list"

    |nm|

    (nm := self name) notEmptyOrNil ifTrue:[

        ^ nm

    ].

    ^ super inspectorValueStringInListFor:anInspector

! !

!Behavior methodsFor:'queries'!

methodsCount

    "Return a number of methods or nil if number of methods

     is not known (such as for lazy-loaded classes)"

    ^ methodDictionary size

    "Created: / 25-02-2015 / 16:14:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Block methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    |d|

    d := super inspectorExtraAttributes.

    self homeMethod isNil ifTrue:[

        d

            add:'-code' -> 'no home method';

            add:'-source' -> 'no home method'.

    ] ifFalse:[

        d    

            add:'-code' -> [ String streamContents:[:s | self homeMethod decompileTo:s]];

            add:'-source' -> [ self homeMethod source].

    ].

    ^ d

    "Created: / 15-11-2011 / 14:24:10 / cg"

! !

!Boolean methodsFor:'inspecting'!

inspectorValueStringInListFor:anInspector

    "returns a string to be shown in the inspector's list"

    ^ self printString

! !

!Breakpoint methodsFor:'accessing'!

icon

    ^description icon

    "Created: / 11-07-2011 / 18:21:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!BreakpointDescription methodsFor:'accessing'!

icon

    "do not use abbreviations like bpnt or brp or similar;

     when I do not know the exact name, I tend to search for implementors/senders

     of '*break*' or '*disabled*'.

     I will not find anything useful and have to single step if methods are named

     cryptically."

    icon notNil ifTrue:[^ icon].

    condition isNil ifTrue:[

        state == #enabled ifTrue:[^ ToolbarIconLibrary breakpointRedEnabled].

        state == #disabled ifTrue:[^ ToolbarIconLibrary breakpointRedDisabled].

        state == #tracing ifTrue:[^ ToolbarIconLibrary tracepointBlue].

    ] ifFalse:[

        state == #enabled ifTrue:[^ ToolbarIconLibrary breakpointBlueEnabled].

        state == #disabled ifTrue:[^ ToolbarIconLibrary breakpointBlueDisabled].

    ].

    ^nil

    "Created: / 28-06-2011 / 08:29:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 27-01-2012 / 13:46:23 / cg"

! !

!ByteArray methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    |basePrinter|

    basePrinter := 

        [:arr :b |

            String

                streamContents:[:s |

                    arr class isWords ifTrue:[

                        arr asWordArray printOn:s base:b showRadix:true

                    ] ifFalse:[

                        arr class isLongs ifTrue:[

                            arr asLongIntegerArray printOn:s base:b showRadix:true

                        ] ifFalse:[

                            arr asByteArray printOn:s base:b showRadix:true

                        ]

                    ]

                ]

        ].

    ^ super inspectorExtraAttributes

        add:'-hexstring' -> [ self hexPrintString "WithSeparator:Character space" ];

        add:'-hexadecimal' -> [ basePrinter value:self value:16 ];

        add:'-binary' -> [ basePrinter value:self value:2 ];

        add:'-asciiString' -> [ self asString ];

        yourself

! !

!Change methodsFor:'private'!

flattenOnto: aCollection 

	aCollection add: self

! !

!Change methodsFor:'private'!

flattenedChanges

	| changes |

	changes := OrderedCollection new.

	self flattenOnto: changes.

	^changes

! !

!Change methodsFor:'accessing'!

removed

    ^(self objectAttributeAt: #removed) ? false

    "Created: / 24-10-2009 / 21:10:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Change methodsFor:'accessing'!

removed: aBoolean

    ^self objectAttributeAt: #removed put: aBoolean

    "Created: / 24-10-2009 / 21:11:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ChangeSet methodsFor:'utilities'!

condenseChangesForRemoved

    "remove all changes which have been removed 

     (marked for removal by aChange removed: true)"

    |changesToRemove|

    changesToRemove := 

        self select:[:aChange | 

            aChange isCompositeChange ifTrue:[

                aChange condenseChangesForRemoved

            ].        

            aChange removed

        ].

    self condenseChanges:changesToRemove

    "Created: / 05-11-2001 / 14:21:17 / cg"

    "Modified: / 12-10-2006 / 16:51:27 / cg"

! !

!ChangeSet methodsFor:'private'!

flattenOnto: aCollection

    self do:[:change|change flattenOnto: aCollection]

! !

!ChangeSet methodsFor:'private'!

flattenedChanges

	| changes |

	changes := OrderedCollection new.

	self flattenOnto: changes.

	^changes

! !

!ChangeSet methodsFor:'inspecting'!

inspector2TabBrowser

    ^self newInspector2Tab

	label: 'Changes';

	priority: 35;

	"JV@2011-08-06: Cannot do 'UserPreferences current changeSetBrowserClass'

	 here since ChangeSetBrowser has no #on: and it is not an application model.

	 Thus, enforce Tools::ChangeSetBrowser2 here..."

	application: ((Tools::ChangeSetBrowser2 on: self) beOneColumn; yourself)

    "Modified: / 25-07-2011 / 12:22:07 / sr"

    "Modified: / 06-08-2011 / 21:22:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-09-2011 / 11:55:53 / cg"

! !

!ChangeSet methodsFor:'inspecting'!

inspector2Tabs

    ^ super inspector2Tabs , #( inspector2TabBrowser )

    "Created: / 05-07-2011 / 13:40:19 / cg"

    "Modified: / 13-02-2015 / 21:03:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Character methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    |atts|

    atts := super inspectorExtraAttributes.

    atts

        add:'-hexValue' -> [ self codePoint radixPrintStringRadix:16 ];

        add:'-string' -> [ self stringSpecies with:self ];

        add:'-utf8String' -> [ self utf8Encoded ];

        add:'-utf8' -> [ self utf8Encoded asByteArray hexPrintStringWithSeparator:Character space ].

    HTMLUtilities notNil ifTrue:[

        atts add:'-html' -> [ HTMLUtilities escapeCharacterEntities:self asString ]

    ].

    ^ atts

    "

     $a inspect

     $> inspect

     (Character value:16r3124) inspect

    "

    "Created: / 22-10-2006 / 03:52:20 / cg"

! !

!Character methodsFor:'inspecting'!

inspectorValueStringInListFor:anInspector

    "returns a string to be shown in the inspector's list"

    (asciivalue <= 16r7f) ifTrue:[

        ^ self storeString,(' "16r%1 %2"' bindWith:(asciivalue hexPrintString) with:asciivalue)

    ].

    ^ self storeString,(' "%1"' bindWith:asciivalue)

! !

!CharacterArray methodsFor:'inspecting'!

inspector2TabBytes

    |bytesShown|

    "/ ouch - ever tried to inspect a 5Mb string?

    self size < 10000 ifTrue:[

        bytesShown := self asByteArray hexPrintStringWithSeparator:Character space

    ] ifFalse:[

        bytesShown := ((self copyTo:10000) asByteArray hexPrintStringWithSeparator:Character space),

                      Character cr,

                      '... (only the first 10000 bytes are shown)'

    ].

    ^ self newInspector2Tab

        label: 'Bytes';

        priority: 39;

        view: ((HVScrollableView for:EditTextView) 

                autoHideVerticalScrollBar:true;        

                contents:bytesShown; 

                yourself);

        yourself        

    "

     (String new:100000) inspect

    "

    "Created: / 17-02-2008 / 10:10:50 / janfrog"

    "Created: / 20-07-2011 / 16:36:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-08-2011 / 07:32:57 / cg"

! !

!CharacterArray methodsFor:'inspecting'!

inspector2TabDiff

    | diffApp |

    diffApp := Tools::TextDiff2Tool new.

    diffApp labelA: 'self'; textA: self.

    diffApp labelB: 'pasted'; textB: 'Paste some text here'.

    diffApp diffView leftTextView readOnly: true.

    diffApp diffView rightTextView 

        acceptAction:[:contents |

            diffApp textBHolder value: contents asString.

            diffApp updateViews.