"

 COPYRIGHT (c) 1992 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

DisplayMedium subclass:#DeviceDrawable

	instanceVariableNames:'device drawableId gcId realized deviceFont foreground background'

	classVariableNames:'CachedScaledForms CachedScales Lobby'

	poolDictionaries:''

	category:'Graphics-Support'

!

!DeviceDrawable class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1992 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    I provide the common protocol for any drawable which is associated with a device (i.e. Bitmaps, 

    Pixmaps, RootWindow and Windows in Xs world, but also postscript printer pages or fax pages).

    My instance variables are mainly caching device-related stuff (such as font- and color-Ids)

    to avoid needless message traffic. This class is abstract, no direct instances of it

    exist in the system.

    All real work is done by my device, most drawing requests are simply forwarded to it, others

    are simulated by using more basic drawing functions.

    The added variables foreground/background are the drawing colors actually 

    used; these are the real (i.e. non dithered) colors supported by the device.

    Direct access to fg/bg is discouraged, since in the future, these may be 

    totally replaced by paint/bgPaint 

    (there are some operations and special cases, for which a direct access to 

     fg/bg makes sense)

"

! !

!DeviceDrawable class methodsFor:'initialization'!

initialize

    Lobby isNil ifTrue:[

	Lobby := Registry new.

    ]

! !

!DeviceDrawable class methodsFor:'instance creation'!

new

    "create a new drawable - take the current display as

     its device (for now, this may be changed until the view is

     physically created)"

"

    'Warning: DeviceDrawables (' print. self name print. ') should not be created with new' printNL.

"

    ^ self onDevice:Screen current "Display"

!

on:aDevice

    "create a new drawable on aDevice"

    ^ self onDevice:aDevice

!

onDevice:aDevice

    "create a new drawable on aDevice"

    |newDrawable|

    newDrawable := self basicNew.

    "

     set display before its initialized 

     - so it can do something useful (i.e. get font sizes etc.) in its

     intitialize method(s)

    "

    newDrawable device:aDevice.

    newDrawable initialize.

    Lobby register:newDrawable.

    ^ newDrawable

! !

!DeviceDrawable class methodsFor:'cleanup'!

lowSpaceCleanup

    CachedScaledForms := CachedScales := nil

! !

!DeviceDrawable methodsFor:'accessing'!

at:aPoint

    "return the pixel at the coordinate given by aPoint"

    ^ device

	getPixelX:(aPoint x)

		y:(aPoint y)

	     from:drawableId

!

at:aPoint put:aPixel

    "set a pixel"

    |oldFg|

    oldFg := foreground.

    self foreground:aPixel.

    self displayPointX:(aPoint x) y:(aPoint y).

    self foreground:oldFg

!

atX:x y:y

    "return the pixel at the coordinate given by x/y"

    ^ device getPixelX:x y:y from:drawableId

!

atX:x y:y put:aPixel

    "set a pixel"

    |oldFg|

    oldFg := foreground.

    self foreground:aPixel.

    self displayPointX:x y:y.

    self foreground:oldFg

!

background

    "return the current background drawing color.

     OBSOLETE: use paint:/paint:on:"

    ^ background

!

background:aColor

    "set the internal background color for drawing - aColor must be a real color.

     OBSOLETE: this method will vanish; use paint:/paint:on:"

    |bgId|

    (aColor ~~ background) ifTrue:[

	aColor notNil ifTrue:[

	    background := aColor.

	    gcId notNil ifTrue:[

		background := background on:device.

		bgId := background colorId.

		"

		 mhmh the following is a kludge ....

		"

		bgId isNil ifTrue:[

		    (background greyIntensity >= 50) ifTrue:[

			bgId := device whitepixel

		    ] ifFalse:[

			bgId := device blackpixel

		    ]

		].

		device setBackground:bgId in:gcId

	    ]

	]

    ]

!

backgroundPaint:aColor

    "set the background-paint color; this is used in opaque-draw

     operations"

    (aColor ~~ bgPaint) ifTrue:[

	aColor notNil ifTrue:[

	    bgPaint := aColor.

	    gcId notNil ifTrue:[

		bgPaint isColor ifTrue:[

		    bgPaint := aColor on:device.

		    bgPaint colorId notNil ifTrue:[

			background := bgPaint.

			device setBackground:(bgPaint colorId) in:drawableId.

			^ self

		    ]

		].

		self paint:paint on:aColor

	    ]

	]

    ].

!

basicFont:aFont

    "set the font for drawing if it has changed.

     This is a low level entry, which is not to be redefined

     (i.e. it must not imply a redraw operation)"

    |id|

    (aFont ~~ font) ifTrue:[

        aFont notNil ifTrue:[

            font := aFont.

            gcId notNil ifTrue:[

                font := font on:device.

                id := font fontId.

                id notNil ifTrue:[

                    device setFont:id in:gcId

                ]

            ]

        ]

    ]

    "Modified: 23.2.1996 / 17:01:06 / cg"

    "Created: 23.2.1996 / 17:16:51 / cg"

!

capStyle:aSymbol

    "set the style in which the endpoints of lines

     are drawn - aSymbol may be #notLast, #butt, #round, #projecting"

    (aSymbol ~~ capStyle) ifTrue:[

	capStyle := aSymbol.

	gcId notNil ifTrue:[

	    device setLineWidth:lineWidth 

			  style:lineStyle

			    cap:aSymbol

			   join:joinStyle

			     in:gcId

	]

    ]

!

clipRect

    "return the clipping rectangle for drawing. If there is currently no clipRect,

     a dummy is created."

    |rect|

    clipRect isNil ifTrue:[

        rect := 0@0 extent:width@height.

        transformation notNil ifTrue:[

            rect := transformation applyInverseTo:rect.

        ].

        ^ rect

    ].

    ^ clipRect

    "Modified: 10.4.1996 / 14:32:22 / cg"

!

clipRect:aRectangle

    "set the clipping rectangle for drawing (in logical coordinates);

     a nil argument turn off clipping (i.e. whole view is drawable)"

    |x y w h|

    aRectangle isNil ifTrue:[

	clipRect isNil ifTrue:[^ self].

	gcId notNil ifTrue:[

	    device noClipIn:gcId

	]

    ] ifFalse:[

	clipRect notNil ifTrue:[

	    (clipRect = aRectangle) ifTrue:[^ self]

	].

	gcId notNil ifTrue:[

	    x := aRectangle left.

	    y := aRectangle top.

	    w := aRectangle width.

	    h := aRectangle height.

	    transformation notNil ifTrue:[

		x := transformation applyToX:x.

		y := transformation applyToY:y.

		w := transformation applyScaleX:w.

		h := transformation applyScaleY:h.

	    ].

	    (x class == SmallInteger) ifFalse:[

		w := w + (x - x truncated).

		x := x truncated

	    ].

	    (y class == SmallInteger) ifFalse:[

		h := h + (y - y truncated).

		y := y truncated

	    ].

	    (w class == SmallInteger) ifFalse:[

		w := w truncated + 1

	    ].

	    (h class == SmallInteger) ifFalse:[

		h := h truncated + 1

	    ].

	    device setClipX:x y:y width:w height:h in:gcId

	]

    ].

    clipRect := aRectangle

!

clippingRectangleOrNil

    "return the clipping rectangle for drawing, nil if there is none."

    ^ clipRect

    "Created: 10.4.1996 / 14:32:02 / cg"

!

device

    "return the device, the receiver is associated with"

    ^ device

!

device:aDevice

    "set the device"

    device := aDevice

!

font:aFont

    "set the font for drawing if it has changed.

     This should be redefined in some widget to perform an automatic

     redraw. See also: #basicFont:"

    (aFont ~~ font) ifTrue:[

        self basicFont:aFont

    ]

    "Modified: 6.3.1996 / 18:17:40 / cg"

!

foreground

    "return the current foreground drawing color.

     OBSOLETE: use paint:/paint:on:"

    ^ foreground

!

foreground:aColor

    "set the internal foreground color for drawing - aColor must be a real color.

     OBSOLETE: this method will vanish; use paint:/paint:on:"

    |fgId|

    (aColor ~~ foreground) ifTrue:[

	aColor notNil ifTrue:[

	    foreground := aColor.

	    gcId notNil ifTrue:[

		(foreground class == SmallInteger) ifTrue:[

		    fgId := foreground

		] ifFalse:[

		    foreground := foreground on:device.

		    fgId := foreground colorId.

		].

		"mhmh the following is a kludge ...."

		fgId isNil ifTrue:[

		    (foreground greyIntensity >= 50) ifTrue:[

			fgId := device whitepixel

		    ] ifFalse:[

			fgId := device blackpixel

		    ]

		].

		device setForeground:fgId in:gcId.

		paint := foreground

	    ]

	]

    ]

!

foreground:fgColor background:bgColor

    "set both internal foreground and internal background colors 

     - these must be real colors.

     OBSOLETE: this method will vanish; use paint:/paint:on:"

    |fgPixel bgPixel|

    ((fgColor ~~ foreground) or:[bgColor ~~ background]) ifTrue:[

	fgColor notNil ifTrue:[

	    foreground := fgColor

	].

	bgColor notNil ifTrue:[

	    background := bgColor

	].

	gcId notNil ifTrue:[

	    foreground := foreground on:device.

	    background := background on:device.

	    fgPixel := foreground colorId.

	    bgPixel := background colorId.

	    "mhmh the following is a kludge ...."

	    fgPixel isNil ifTrue:[

		(foreground greyIntensity >= 50) ifTrue:[

		    fgPixel := device whitepixel

		] ifFalse:[

		    fgPixel := device blackpixel

		]

	    ].

	    bgPixel isNil ifTrue:[

		(background greyIntensity >= 50) ifTrue:[

		    bgPixel := device whitepixel

		] ifFalse:[

		    bgPixel := device blackpixel

		]

	    ].

	    device setForeground:fgPixel background:bgPixel in:gcId.

	    paint := foreground

	]

    ]

!

foreground:fgColor background:bgColor function:fun

    "set foreground, background colors and function.

     OBSOLETE: this method will vanish; use paint:/paint:on:"

    self foreground:fgColor background:bgColor.

    self function:fun

!

foreground:aColor function:fun

    "set the foreground color and function for drawing.

     OBSOLETE: this method will vanish; use paint:/paint:on:"

    |fgPixel|

    ((aColor ~~ foreground) or:[fun ~~ function]) ifTrue:[

	foreground := aColor.

	function := fun.

	gcId notNil ifTrue:[

	    foreground := foreground on:device.

	    fgPixel := foreground colorId.

	    "mhmh the following is a kludge ...."

	    fgPixel isNil ifTrue:[

		(foreground greyIntensity >= 50) ifTrue:[

		    fgPixel := device whitepixel

		] ifFalse:[

		    fgPixel := device blackpixel

		]

	    ].

	    device setForeground:fgPixel in:gcId.

	    device setFunction:fun in:gcId.

	    paint := foreground

	]

    ]

!

function:aSymbol

    "set the drawing function if it has changed"

    (aSymbol ~~ function) ifTrue:[

	function := aSymbol.

	gcId notNil ifTrue:[

	    device setFunction:aSymbol in:gcId

	]

    ]

!

gcId

    "return the receivers graphic context id on the device"

    ^ gcId

!

id

    "return the id of the dravable on the device"

    ^ drawableId

!

joinStyle:aSymbol

    "set the style in which 2 lines are connected in polygons -