'From Smalltalk/X, Version:2.7.1 on 10-Jul-1993 at 19:03:09'!

Dictionary subclass:#ResourcePack

         instanceVariableNames:'elements dependents fileName'

         classVariableNames:'packs'

         poolDictionaries:''

         category:'System-Support'

!

!ResourcePack class methodsFor:'initialization'!

initialize

    packs isNil ifTrue:[

        packs := ShadowArray new:30

    ].

    "ResourcePack initialize"

! !

!ResourcePack class methodsFor:'instance creation'!

fromFile:aFileName

    "get the resource definitions from a file"

    |inStream newPack temp idx|

    "first look, if not already here"

    packs isNil ifTrue:[

        self initialize

    ].

    packs do:[:aPack |

        aPack notNil ifTrue:[

            aPack fileName = aFileName ifTrue:[

                ^ aPack

            ]

        ]

    ].

    inStream := Smalltalk systemFileStreamFor:('resources/' , aFileName).

    inStream isNil ifTrue:[^ self new].

    newPack := self new readFromResourceStream:inStream.

    newPack fileName:aFileName.

    inStream close.

    idx := packs identityIndexOf:nil.

    idx notNil ifTrue:[

        packs at:idx put:newPack

    ] ifFalse:[

        temp := ShadowArray new:(packs size).

        temp replaceFrom:1 with:packs.

        packs := temp

    ].

    ^ newPack

    "ResourcePack fromFile:'SBrowser.rs'"

    "ResourcePack fromFile:'FBrowser.rs'"

    "ResourcePack fromFile:'Smalltalk.rs'"

!

for:aClass

    "get the resource definitions for aClass"

    |superPack|

    aClass == Object ifTrue:[

	^ self fromFile:((Smalltalk fileNameForClass:aClass name) , '.rs')

    ].

    superPack := self for:aClass superclass.

    ^ (self fromFile:((Smalltalk fileNameForClass:aClass name) , '.rs')) merge:superPack

! !

!ResourcePack methodsFor:'merging'!

merge:anotherPack

    anotherPack associationsDo:[:assoc |

	self at:(assoc key) put:(assoc value)

    ]

! !

!ResourcePack methodsFor:'accessing'!

dependents:aCollection

    dependents := aCollection

!

at:aKey

    ^ self at:aKey ifAbsent:[aKey]

!

fileName

    ^ fileName

!

fileName:aString

    fileName := aString

!

dependents

    ^ dependents

!

at:aKey default:default

    ^ self at:aKey ifAbsent:[default]

!

array:anArray

    ^ anArray collect:[:r | self at:r default:r]

!

string:s

    ^ self at:s ifAbsent:[s]

!

string:s with:arg

    ^ self string:s withArgs:(Array with:arg)

!

string:s with:arg1 with:arg2

    ^ self string:s withArgs:(Array with:arg1 with:arg2)

!

string:s withArgs:argArray

    | template expandedString idx start stop next |

    template := self at:s ifAbsent:[s].

    expandedString := ''.

    stop := template size.

    start := 1.

    [start < stop] whileTrue:[

        idx := template indexOf:$% startingAt:start.

        idx == 0 ifTrue:[

            ^ expandedString , (template copyFrom:start to:stop)

        ].

        "found a %"

        next := template at:(idx + 1).

        (next == $%) ifTrue:[

            expandedString := expandedString , '%'

        ] ifFalse:[

            expandedString := expandedString , (argArray at:(next digitValue)) printString

        ].

        start := idx + 2

    ]

! !

!ResourcePack methodsFor:'file reading'!

readFromResourceStream:inStream

    |lineString rest value ifLevel skipping l name first|

    ifLevel := 0.

    skipping := false.

    [inStream atEnd] whileFalse:[

        lineString := inStream nextLine.

        (lineString notNil and:[lineString isEmpty not]) ifTrue:[

            first := lineString at:1.

            first == $; ifFalse:[

                first == $# ifTrue:[

                    (lineString startsWith:'#if') ifTrue:[

                        skipping ifFalse:[

                            rest := lineString copyFrom:4.

                            value := Compiler evaluate:rest.

                            (value == #Error) ifTrue:[

                                Transcript show:('error in resource:' , lineString).

                            ].

                            (value == false) ifTrue:[

                                skipping := true

                            ]

                        ].

                        ifLevel := ifLevel + 1

                    ] ifFalse:[

                        (lineString startsWith:'#endif') ifTrue:[

                            ifLevel := ifLevel - 1.

                            ifLevel == 0 ifTrue:[

                                skipping := false

                            ]

                        ].

                    ].

                ] ifFalse:[

                    skipping ifFalse:[

                        lineString := lineString withoutSeparators.

                        name := nil.

                        (lineString at:1) == $' ifTrue:[

                            l := lineString indexOf:$' startingAt:2.

                            l ~~ 0 ifTrue:[

                                name := (lineString copyFrom:2 to:l-1).

                                l := l + 1

                            ]

                        ] ifFalse:[

                            l := lineString indexOfSeparatorStartingAt:1.

                            l ~~ 0 ifTrue:[

                                name := lineString copyFrom:1 to:l-1.

                            ]

                        ].

                        name notNil ifTrue:[

                            rest := lineString copyFrom:l.

                            value := Compiler evaluate:rest.

                            (value == #Error) ifTrue:[

                                Transcript show:('error in resource:' , name).

                            ].

                            self at:name put:value.

                        ]

                    ]

                ]

            ]

        ]

    ].

! !

ResourcePack initialize!