"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

DeviceDrawable subclass:#Form

	instanceVariableNames:'depth localColorMap offset data fileName'

	classVariableNames:'VeryLightGreyForm LightGreyForm GreyForm DarkGreyForm

		VeryDarkGreyForm AdditionalBitmapDirectoryNames

		BlackAndWhiteColorMap DitherPatternArray'

	poolDictionaries:''

	category:'Graphics-Display Objects'

!

!Form class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Instances of this class represent forms (i.e. bit- and pixmaps)

    Not all devices will support forms.

    NOTICE:

        the Form class is a historic leftover and now only used for real

        device forms (i.e. on devices which support downloading bitmaps).

        In your application, you should always use Image, both for compatibility

        with ST-80 and for device independence, since Form may not be supported

        by all devices (for example: PostscriptPrinters).

    [See also]

        Image DeviceDrawable

"

! !

!Form class methodsFor:'initialization'!

initialize

    "initialize set of dictionaries to look for bitmaps"

    AdditionalBitmapDirectoryNames isNil ifTrue:[

	AdditionalBitmapDirectoryNames := #('/usr/lib/X11/bitmaps').

	"want to be informed when returning from snapshot"

	ObjectMemory addDependent:self.

    ]

!

reinitializeAllOn:aDevice

    "recreate all forms on aDevice; called by Workstation, to

     have all background bitmaps at hand, when views are restored"

    Lobby do:[:aDrawable |

	(aDrawable device == aDevice) ifTrue:[

	    aDrawable isForm ifTrue:[

		"now, try to recreate it"

		aDrawable recreate.

	    ]

	]

    ]

!

update:something

    "sent just before snapOut and just after a snapIn"

    (something == #save) ifTrue:[

	"get all bits from the device into saveable arrays"

	Lobby do:[:aDrawable |

	    aDrawable isForm ifTrue:[

		aDrawable getBits

	    ]

	]

    ].

    (something == #restarted) ifTrue:[

	"remove all left-over device info"

	Lobby do:[:aDrawable |

	    aDrawable isForm ifTrue:[

		aDrawable restored.

		Lobby registerChange:aDrawable 

	    ]

	]

    ]

! !

!Form class methodsFor:'instance creation'!

black

    "ST80 compatibility;

     in st80, return a black form - here we return black color"

    ^ Color black

!

darkGray

    "ST80 compatibility;

    in st80, return a darkGrey form - here we return darkGrey color"

    ^ Color darkGrey

!

darkGrey

    "ST80 compatibility;

    in st80, return a darkGrey form - here we return darkGrey color"

    ^ Color darkGrey

!

extent:ext

    "create a new, cleared form, take dimensions from ext.

     Smalltalk-80 compatibility"

    |newForm|

    newForm := self width:(ext x) height:(ext y).

    newForm fill:(Color colorId:0).

    newForm paint:(Color colorId:1).

    ^ newForm

!

extent:ext fromArray:data

    "create a new form, take dimensions from ext, bits from data.

     Smalltalk-80 compatibility."

    ^ self width:(ext x) height:(ext y) offset:0@0 fromArray:data

!

extent:ext fromArray:data offset:offs

    "create a new form, take dimensions from ext, bits from data.

     Smalltalk-80 compatibility."

    ^ self width:(ext x) height:(ext y) offset:offs fromArray:data

!

extent:ext offset:anOffset

    "create a new, cleared form, take dimensions from ext.

     Smalltalk-80 compatibility"

    ^ (self extent:ext) offset:anOffset.

!

gray

    "ST80 compatibility;

    in st80, return a grey form - here we return grey color"

    ^ self grey

!

grey

    "ST80 compatibility;

    in st80, return a grey form - here we return grey color"

    ^ Color grey

!

lightGrey

    "ST80 compatibility;

    in st80, return a lightGrey form - here we return lightGrey color"

    ^ Color lightGrey

!

white

    "ST80 compatibility;

     in st80, return a white form - here we return white color"

    ^ Color white

!

width:w height:h

    "create a new form on the default device"

    ^ (self on:Screen current) width:w height:h

!

width:w height:h depth:d

    "create a new form on the default device"

    ^ (self on:Screen current) width:w height:h depth:d

!

width:w height:h depth:d on:aDevice

    "create a new form with depth d on device, aDevice"

    ^ (self on:aDevice) width:w height:h depth:d

!

width:w height:h fromArray:anArray

    "create a new form on the default device"

    ^ (self on:Screen current) width:w height:h fromArray:anArray

!

width:w height:h fromArray:anArray on:aDevice

    "create a new form on device, aDevice and

     initialize the pixels from anArray"

    ^ (self on:aDevice) width:w height:h fromArray:anArray

!

width:w height:h offset:offs fromArray:anArray

    "create a new form on the default device"

    ^ (self on:Screen current) width:w height:h offset:offs fromArray:anArray

!

width:w height:h on:aDevice

    "create a new form on device, aDevice; depth is what device likes most"

    ^ (self on:aDevice) width:w height:h

! !

!Form class methodsFor:'ST-80 compatibility'!

and

    "return a constant usable as bitblt-combinationrule"

    ^ #and

!

over

    "return a constant usable as bitblt-combinationrule"

    ^ #copy

!

paint

    "return a constant usable as bitblt-combinationrule"

    ^ #copy

!

reverse

    "return a constant usable as bitblt-combinationrule"

    ^ #xor

!

under

    "return a constant usable as bitblt-combinationrule"

    ^ #or

! !

!Form class methodsFor:'cleanup'!

lowSpaceCleanup

    "cleanup in low-memory situations"

    DitherPatternArray := nil

! !

!Form class methodsFor:'file search'!

findBitmapFile:fileName

    "find the bitmap file in one of the standard places;

     return the pathName or nil"

    |aStream path|

    ((fileName at:1) == $/) ifTrue:[^ fileName].

    (fileName startsWith:'../') ifTrue:[^ fileName].

    (fileName startsWith:'./') ifTrue:[^ fileName].

    fileName asFilename exists ifTrue:[^ fileName].

    aStream := Smalltalk bitmapFileStreamFor:fileName.

    aStream notNil ifTrue:[

	path := aStream pathName.

	aStream close.

	^ path

    ].

    AdditionalBitmapDirectoryNames notNil ifTrue:[

	AdditionalBitmapDirectoryNames do:[:aPath |

	    path := aPath , '/' , fileName.

	    (OperatingSystem isReadable:path) ifTrue:[

		^ path

	    ]

	]

    ].

    ^ nil

! !

!Form class methodsFor:'fileIn/Out'!

fromFile:filename

    "create a new form taking the bits from a file on the default device.

     WARNING:

     Please do no longer use this, since it will not work

     correctly in multi-display applications (creates the form on the

     default Display).

     Use #fromFile:on: and pass the devive as argument."

    ^ self fromFile:filename on:Screen current

!

fromFile:filename on:aDevice

    "create a new form on device, aDevice and

     initialize the pixels from the file filename"

    ^ (self on:aDevice) readFromFile:filename

!

fromFile:filename resolution:dpi

    "create a new form taking the bits from a file on the default device

     the data in the file is assumed to be for dpi resolution;

     if it is different from the displays resolution, magnify or

     shrink the picture (but only in integer magnification steps).

     WARNING:

     Please do no longer use this, since it will not work

     correctly in multi-display applications (creates the form on the

     default Display).

     Use #fromFile:resolution:on: and pass the devive as argument."

    ^ self fromFile:filename resolution:dpi on:Screen current

!

fromFile:filename resolution:dpi on:aDevice

    "create a new form on device, aDevice and

     initialize the pixels from the file filename;

     the data in the file is assumed to be for dpi resolution;

     if it is different from the displays resolution, magnify or

     shrink the picture (but only in integer magnification steps)"

    ^ (self on:aDevice) readFromFile:filename resolution:dpi

!

readFrom:fileName

    "same as Form>>fromFile: - for ST-80 compatibility.

     WARNING:

     Please do no longer use this, since it will not work

     correctly in multi-display applications (creates the form on the

     default Display).

     Use #fromFile:on: and pass the devive as argument."

    ^ self fromFile:fileName on:Screen current

! !

!Form class methodsFor:'patterns'!

darkGreyFormBits

    "return a pattern usable to simulate darkGray on monochrome device"

    ^ #(2r10111011

	2r11101110

	2r10111011

	2r11101110)

!

ditherBitsForXin64:x

    "return a dither pattern for x/64; x in 1..63"

    ^ #(

        "/ 1in64

          #[2r10000000

            2r00000000

            2r00000000

            2r00000000

            2r00000000

            2r00000000

            2r00000000

            2r00000000]

        "/ 2in64

          #[2r10000000

            2r00000000

            2r00000000

            2r00000000

            2r00001000

            2r00000000

            2r00000000

            2r00000000]

        "/ 3in64

          #[2r10000000

            2r00000000

            2r00000000

            2r00000000

            2r10001000

            2r00000000

            2r00000000

            2r00000000]

        "/ 4in64

          #[2r10001000

            2r00000000

            2r00000000

            2r00000000

            2r10001000

            2r00000000

            2r00000000

            2r00000000]

        "/ 5in64

          #[2r10001000

            2r00000000

            2r00000000

            2r00000000

            2r10001000

            2r00000000

            2r00000010

            2r00000000]

        "/ 6in64

          #[2r10001000

            2r00000000

            2r00100000

            2r00000000

            2r10001000

            2r00000000

            2r00000010

            2r00000000]

        "/ 7in64

          #[2r10001000

            2r00000000

            2r00100010

            2r00000000

            2r10001000

            2r00000000

            2r00000010

            2r00000000]

        "/ 8in64

          #[2r10001000

            2r00000000

            2r00100010

            2r00000000

            2r10001000

            2r00000000

            2r00100010

            2r00000000]

        "/ 9in64

          #[2r10001000

            2r00000000

            2r00100010

            2r00000000

            2r10001000

            2r00000000

            2r10100010

            2r00000000]

            /* 10 */

          #[2r10001000

            2r00000000

            2r00101010

            2r00000000

            2r10001000

            2r00000000

            2r10100010

            2r00000000]

        "/ 11in64

          #[2r10001000

            2r00000000

            2r00101010

            2r00000000

            2r10001000

            2r00000000

            2r10101010

            2r00000000]

        "/ 12in64