"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview2' }"

EventListener subclass:#ActiveHelp

	instanceVariableNames:'lastHelpText listeningForAll applicationsOrTopViewsWithHelp'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-Help'

!

ActiveHelp class instanceVariableNames:'DelayTime ShowTime TheOneAndOnlyHelpListener'

"

 No other class instance variables are inherited by this class.

"

!

!ActiveHelp class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    The active help listener.

    The one and only instance of myself intercepts incoming mouse & keyboard 

    events for the display device, being especially interested in view-enter/

    leave events. When such an event arrives, it asks the corresponding view

    or its model for a help message and display it via an ActiveHelpView.

    (actually, the view is first asked if it would like to display it itself

     - for example, in some information-view).

    The query for the helpText is repeated along the views superView chain, 

    until any model or view returns a nonNil answer for the #helpTextFor:at 

    or #helpTextFor message.

    All I need for automatic help is some model/view/applicationModel along

    the superview chain of the entered component, which responds to the

    #helpTextFor: message with a non-nil (string-) answer.

    I close down the help view after a while, if a key is pressed or the mouse

    moved to another view.

    Who should provide the helpText:

        the best place is the application object (an instance of ApplicationModel)

        or the topView, if its a derived class of StandardSystemView.

        This should know about its components and return the string

        when asked via #helpTextFor:aComponent.

        See examples in FileBrowser, Launcher etc.

    Be aware, that for applicationModels, there must be a link from the

    topView to this applicationModel 

    (set via: aTopView application:anApplicationModel)

    otherwise, the helpManager has no means of finding the application which

    corresponds to a view.

    Who should display the helpText:

        by default, the helpListener opens a little popup view, which displays the

        returned help message. However, a nice trick which can be used by applications

        is to create an infoLabel as a subview of the topFrame (a la windows)

        and display the text right in the #helpTextFor: method. To cheat the

        help listener, this method should then return nil, to keep it silent.

    Usage:

        If help is to be shown for all views (as enabled by the launchers help menu),

        use 'ActiveHelp start' and 'ActiveHelp stop'.

        Individual apps may enable/disable active help for themself by:

        'ActiveHelp startFor:app' or 'ActiveHelp stopFor:app', passing either

        the topView or the topViews application as argument.

        This is usually done by applications which want to show contextHelp in

        some infoView.

    [author:]

        Claus Gittinger

    [start with:]

        ActiveHelp start

        ActiveHelp stop

    [See also:]

        ActiveHelpView

        WindowGroup WindowEvent

        ApplicationModel StandardSystemView

"

!

examples

"

  Active Help for a single view

  or app (whatever the global settings are):

  Can be initiated by an app when its opened.

                                                                        [exBegin]

        |app top myAppClass|

        Class withoutUpdatingChangesDo:[

            myAppClass := ApplicationModel 

                            subclass:#'Demos::DemoApp'

                            instanceVariableNames:''

                            classVariableNames:''

                            poolDictionaries:''

                            category:'demos'.

            myAppClass 

                compile:'helpTextFor:aView    Transcript showCR:''hello''. ^ ''this is some helpText'''.

        ].

        app := myAppClass new.

        top := StandardSystemView new.

        top extent:300@100.

        top application:app.

        top open.

        ActiveHelp startFor:app.

        Class withoutUpdatingChangesDo:[

            myAppClass removeFromSystem

        ]

                                                                        [exEnd]

  Active Help (for all views):

    (make certain that activeHelp is turned on ...

     ... otherwise, you will see nothing)

    the following example uses a Plug as a model replacement.

    In concrete application, you would create a method to implement the helpText

    query message.

                                                                        [exBegin]

        |app top button1 button2|

        app := Plug new.

        app respondTo:#helpTextFor:

                 with:[:view | 

                               view == button1 ifTrue:[

                                 'this is button1'

                               ] ifFalse:[

                                 view == button2 ifTrue:[

                                   'some help for button2'

                                 ] ifFalse:[

                                   nil

                                 ]

                               ]

                      ].

        top := StandardSystemView new.

        top extent:300@100.

        button1 := Button label:'b1' in:top.

        button1 origin:0.0@0.0 corner:0.5@30. 

        button2 := Button label:'b2' in:top.

        button2 origin:0.5@0.0 corner:1.0@30.

        top model:app. '<-- normally this would be: top application:app'.

        top open

                                                                        [exEnd]

    (make certain that activeHelp is turned on ...

     ... otherwise, you will see nothing)

    alternatively, display of the helpMessage in a local, private view:

                                                                        [exBegin]

        |app top button1 button2 infoView|

        app := Plug new.

        app respondTo:#helpTextFor:

                 with:[:view | infoView label:'info ...'.

                               view == button1 ifTrue:[

                                 infoView label:'this is button1'

                               ].

                               view == button2 ifTrue:[

                                 infoView label:'some help for button2'

                               ].

                               nil

                      ].

        top := StandardSystemView new.

        top extent:300@100.

        button1 := Button label:'b1' in:top.

        button1 origin:0.0@0.0 corner:0.5@30. 

        button2 := Button label:'b2' in:top.

        button2 origin:0.5@0.0 corner:1.0@30.

        infoView := Label label:'info ...' in:top.

        infoView level:-1; origin:0.0@1.0 corner:1.0@1.0.

        infoView topInset:(infoView preferredExtent y negated - 3);

                 leftInset:3; 

                 rightInset:3; 

                 bottomInset:3;

                 adjust:#left.

        top model:app. '<-- normally this would be: top application:app'.

        top open

                                                                        [exEnd]

"

! !

!ActiveHelp class methodsFor:'initialization'!

initialize

    "set default delay & help-display times"

    ShowTime := 10.

    DelayTime := 0.4.

    "

     ActiveHelp initialize

    "

    "Modified: 27.4.1996 / 15:07:27 / cg"

! !

!ActiveHelp class methodsFor:'queries'!

currentHelpListener

    "return the activeHelp listener if activeHelp is turned on, nil otherwise"

    ^ TheOneAndOnlyHelpListener

    "Created: 28.6.1997 / 13:59:44 / cg"

!

delayTime

    ^ DelayTime

!

isActive

    "return true, if activeHelp is turned on"

    ^ TheOneAndOnlyHelpListener notNil

    "Modified: 27.4.1996 / 15:07:57 / cg"

!

showTime

    ^ ShowTime

! !

!ActiveHelp class methodsFor:'start & stop'!

start

    "start activeHelp for all apps"

    TheOneAndOnlyHelpListener isNil ifTrue:[

        TheOneAndOnlyHelpListener := self new.

    ].

    TheOneAndOnlyHelpListener listenForAll

    "

     ActiveHelp start

     FlyByHelp start

    "

    "Modified: / 26.10.1997 / 23:16:54 / cg"

!

startFor:anApplicationOrTopView

    "start activeHelp for a single app"

    TheOneAndOnlyHelpListener isNil ifTrue:[

        TheOneAndOnlyHelpListener := self new.

    ].

    TheOneAndOnlyHelpListener listenFor:anApplicationOrTopView

    "Modified: / 26.10.1997 / 23:17:05 / cg"

!

stop

    "stop activeHelp for all (except for individual apps)"

    TheOneAndOnlyHelpListener notNil ifTrue:[

        TheOneAndOnlyHelpListener unlistenAll.

        TheOneAndOnlyHelpListener := nil.

    ].

    "

     ActiveHelp stop

     FlyByHelp stop

    "

    "Modified: / 26.10.1997 / 23:18:58 / cg"

!

stopFor:anAppOrTopView

    "stop activeHelp for a single app"

    TheOneAndOnlyHelpListener notNil ifTrue:[

        TheOneAndOnlyHelpListener unlistenFor:anAppOrTopView.

    ].

    "Modified: / 26.10.1997 / 23:12:55 / cg"

    "Created: / 26.10.1997 / 23:18:41 / cg"

! !

!ActiveHelp class methodsFor:'times'!

delayTime:numberOfSeconds

    "set the delay (the time, the cursor has to be in the view

     before help is shown). The default is 2 seconds."

    DelayTime := numberOfSeconds

    "

     ActiveHelp delayTime:0.5

     ActiveHelp delayTime:2

     ActiveHelp delayTime:10

    "

!

showTime:numberOfSeconds

    "set the number of seconds, a help messages is to be shown.

     The default is 15 seconds."

    ShowTime := numberOfSeconds

    "

     ActiveHelp showTime:10

     ActiveHelp showTime:99999 

     ActiveHelp showTime:30

    "

! !

!ActiveHelp methodsFor:'listening'!

buttonMotion:state x:x y:y view:aView

    "handle motion events - prepare to show help"

    self handleMouseIn:aView x:x y:y.

    ^ false

!

buttonPress:state x:x y:y view:view

    "unconditionally hide the help view"

    self hideHelpIgnoringErrors.

    ^ false

    "Modified: / 28.7.1998 / 02:52:00 / cg"

!

keyPress:key x:x y:y view:view

    "unconditionally hide the help view"

    self hideHelpIgnoringErrors.

    ^ false

    "Modified: 27.4.1996 / 15:09:57 / cg"

!

pointerEnter:state x:x y:y view:aView

    "handle pointer entering a view; prepare to show help"

    self handleMouseIn:aView x:x y:y.

    ^ false

!

pointerLeave:state view:view

    "handle pointer leaving a view; hide help text"

    self hideHelpIgnoringErrors.

    ^ false

! !

!ActiveHelp methodsFor:'private'!

helpTextFor:aView at:aPointOrNil 

    "retrieve helptext for aView as a string; 

     walk along the views superView chain,

     asking models and views encountered while walking.

     The first one who understands and returns a nonNil answer to the

     #helpTextFor:at: or #helpTextFor: message ends this search and the

     returned string is returned."

    |model app1 app2 text view v sv topView|

    view := aView.

    ((aView respondsTo:#application)

    and:[ (app1 := aView application) notNil ]) ifTrue:[

        text := self helpTextFromModel:app1 view:aView at:aPointOrNil.

        text notNil ifTrue:[ ^ text ].

    ] ifFalse:[

        "/ old style (i.e. StandardSystemView ...)

        topView := aView topView.

        (topView notNil and:[topView ~~ aView]) ifTrue:[

            text := self helpTextFromModel:topView view:aView at:aPointOrNil.

            text notNil ifTrue:[ ^ text ].

        ]

    ].

    (model := aView model) notNil ifTrue:[

        model ~~ app1 ifTrue:[

            text := self helpTextFromModel:model view:aView at:aPointOrNil.

            text notNil ifTrue:[ ^ text ].

        ].

    ].

    text := self helpTextFromView:aView at:aPointOrNil.

    text notNil ifTrue:[ ^ text ].

    "walk up the chain - maybe someone knows about its subview ..."

    v := aView.

    [

        (sv := v container) notNil

    ] whileTrue:[

        (model := sv model) notNil ifTrue:[

            text := self helpTextFromModel:model view:aView at:aPointOrNil.

            text notNil ifTrue:[ ^ text ].

        ].

        text := self helpTextFromView:sv at:nil.

        text notNil ifTrue:[ ^ text ].

        v := sv

    ].

    (v notNil and:[v respondsTo:#application]) ifTrue:[

        (app2 := v application) notNil ifTrue:[

            (app2 ~~ app1) ifTrue:[

                text := self helpTextFromModel:app2 view:aView at:aPointOrNil.

                text notNil ifTrue:[ ^ text ].

            ]

        ]

    ].

    (v notNil and:[v respondsTo:#model]) ifTrue:[

        (model := v model) notNil ifTrue:[

            text := self helpTextFromModel:model view:aView at:aPointOrNil.

            text notNil ifTrue:[ ^ text ].

        ]

    ].

    ^ nil

    "Modified: / 31.8.1995 / 20:38:00 / claus"

    "Modified: / 28.7.1998 / 01:47:27 / cg"

!

helpTextFromModel:aModel view:aView at:aPointOrNil 

    "helper: ask aModel for its helpText."

    |text|

    aPointOrNil notNil ifTrue:[

        (aModel respondsTo:#helpTextFor:at:) ifTrue:[

            text := aModel helpTextFor:aView at:aPointOrNil.

        ].

    ].

    text isNil ifTrue:[

        (aModel respondsTo:#helpTextFor:) ifTrue:[

            text := aModel helpTextFor:aView.

        ].

    ].

    ^ text

!

helpTextFromView:aView at:aPointOrNil 

    "helper: ask aView for its helpText."

    |text|

    aPointOrNil notNil ifTrue:[

        (aView respondsTo:#helpTextAt:) ifTrue:[

            text := aView helpTextAt:aPointOrNil.

        ].

    ].

    text isNil ifTrue:[

        (aView respondsTo:#helpText) ifTrue:[