"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

'From Smalltalk/X, Version:2.10.5 on 14-mar-1995 at 10:59:34 am'!

View subclass:#ListView

	 instanceVariableNames:'list 

				firstLineShown leftOffset 

				nFullLinesShown nLinesShown 

				fgColor bgColor 

				partialLines leftMargin topMargin

				textStartLeft textStartTop innerWidth 

				tabPositions 

				lineSpacing

				fontHeight fontAscent fontIsFixedWidth fontWidth 

				autoScroll autoScrollBlock autoScrollDeltaT

				searchPattern wordCheck 

				includesNonStrings widthOfWidestLine

				listMsg 

				viewOrigin

				menuHolder menuPerformer

				listChannel'

	 classVariableNames:'DefaultForegroundColor DefaultBackgroundColor 

			     DefaultFont DefaultTabPositions'

	 poolDictionaries:''

	 category:'Views-Text'

!

!ListView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

version

!

documentation

"

    a View for (string-)lists.

    This class can only passively display collections of strings-

    selections, editing, cursors etc. must be done in subclasses.

    see SelectionInListView, TextView etc.

    This code currently handles only fixed-height fonts correctly -

    should be rewritten in some places ...

    It can only scroll by full lines vertically (i.e. setting firstLineShown to ~~ 1)

    which should be changed to have this behavior optionally for smooth scroll.

    The text is internally kept in the list instance variable, and is supposed to consist

    of a collection (Ordered- or StringCollection) of line entries.

    Typically, individual entries are either strings or nil (for empty lines).

    However, any object which supports the displayOn: and widthIn: protocol can be

    used - see MultipleColumnListEntry as an example.

    Therefore, ListView (and all subclasses) are prepared to handle non-string entries

    (especially: attributed Text).

    The internal version of the text has tabulators expanded to blanks - when text is exchanged

    with an external medium (i.e. reading/writing files), these are expanded/compressed assuming

    a tab-setting of 8. This is done independent of the users tab setting, which is used

    while the text is edited. Thus, even if the tab setting is multiple of 4's, tabs are

    written in multiples of 8 when the text is saved. Since this is the default on all ascii

    terminals and printers, this assures that the text looks correctly indented when finally printed.

    Due to historic reasons (ListView implemented scrolling before the general

    scrolling code in View was added), this one does scrolling different from all other

    views. The general scrolling code (in View) uses the transformation for transparent scrolling.

    Here, the transformation is not used, instead it is done again, by keeping the firstLineShown

    (i.e. vertical offset) and leftOffset (horizontal offset).

    The most annoying consequence of this is, that scrolling is done by lines here, 

    while its done in pixels in the View class. Thus, be careful, when changing things

    (better: dont touch it ;-)

    This is being totally rewritten ... so dont depend on the internals; especially the scrolling

    code will be totally removed here and the inherited functionality be used in the next version.

    Instance variables:

      list            <aCollection>           the text strings

      firstLineShown  <Number>                the index of the 1st visible line (1 ..)

      leftOffset      <Number>                left offset for horizontal scroll

      nFullLinesShown <Number>                the number of unclipped lines in visible area

					      (internal; updated on size changes)

      nLinesShown     <Number>                the number of lines in visible area, incl. partial

					      (internal; updated on size changes)

      fgColor         <Color>                 color to draw characters

      bgColor         <Color>                 the background

      partialLines    <Boolean>               allow last line to be partial displayed

      leftMargin      <Number>                margin at left in pixels

      topMargin       <Number>                margin at top in pixels

      textStartLeft   <Number>                margin + leftMargin (internal)

      textStartTop    <Number>                margin + topMargin (internal)

      innerWidth      <Number>                width - margins (internal)

      tabPositions    <aCollection>           tab stops (cols)

      fontHeight      <Number>                font height in pixels (internal)

      fontAscent      <Number>                font ascent in pixels (internal)

      fontIsFixed     <Boolean>               true if its a fixed font (internal)

      fontWidth       <Number>                width of space (internal)

      lineSpacing     <Number>                pixels between lines

      searchPattern   <String>                last pattern for searching

      wordCheck       <Block>                 rule used for check for word boundaries in word select

					      (could be changed to allow for underscore and other

					       characters to be treated as alphaCharacters)

      autoScrollBlock <Block>                 block installed as timeoutBlock when doing an

					      autoScroll (internal)

      autoScrollDeltaT                        computed scroll time delta in seconds (internal)

      includesNonStrings                      cached flag if any non-strings are in list

      widthOfWidestLine                       cached width of widest line

      listMsg                                 if view has a model and listMsg is non-nil,

					      this is sent to the model to aquired a new contents

					      whenever a change of the aspect  (aspectMsg) occurs.

      viewOrigin                              the current origin 

      menuHolder                              who has a menu 

					      (default: nil or model here, self in textViews)

      menuPerformer                           who performs menu actions

					      (default: nil or model here, self in textViews)

    StyleSheet parameters:

      textForegroundColor                defaults to Black

      textBackgroundColor                defaults to White

      textFont                           defaults to defaultFont

      textTabPositions                   defaults to #(1 9 17 25 ...)

"

! !

!ListView class methodsFor:'defaults'!

defaultTabPositions

    ^ self tab8Positions

!

updateStyleCache

    DefaultForegroundColor := StyleSheet colorAt:'textForegroundColor' default:Black.

    DefaultBackgroundColor := StyleSheet colorAt:'textBackgroundColor' default:White.

    DefaultFont := StyleSheet fontAt:'textFont'.

    DefaultTabPositions := StyleSheet at:'textTabPositions'.

    DefaultTabPositions isNil ifTrue:[DefaultTabPositions := self defaultTabPositions].

!

tab4Positions

    ^ #(1 5 9 13 17 21 25 29 33 37 41 45 49 53 57 61 65 69 73 77 81 

	85 89 93 97 101 105 109 113 114 121 125 129 133 137 141 145)

!

tab8Positions

    ^ #(1 9 17 25 33 41 49 57 65 73 81 89 97 105 113 121 129 137 145)

! !

!ListView methodsFor:'accessing-contents'!

size

    "return the size (i.e. number of lines)

     this allows textViews to be used like collections in some places."

    ^ list size.

!

at:lineNr

    "retrieve a line; return nil if beyond end-of-text.

     this allows textViews to be used like collections in some places."

    list isNil ifTrue:[^ nil].

    (lineNr between:1 and:self size) ifFalse:[^ nil].

    ^ list at:lineNr

!

from:from to:to do:aBlock

    "evaluate aBlock on all of my lines"

    ^ list from:from to:to do:aBlock.

!

withoutRedrawAt:index put:aString

    "change a line without redisplay"

    |w|

    self checkForExistingLine:index.

    list at:index put:aString.

    includesNonStrings ifFalse:[

	includesNonStrings := (aString notNil and:[aString isString not]).

    ] ifTrue:[

	(aString isNil or:[aString isString]) ifTrue:[

	    includesNonStrings := (list findFirst:[:l | l notNil and:[l isString not]]) ~~ 0.

	]

    ].

    widthOfWidestLine notNil ifTrue:[

	aString isString ifTrue:[

	    w := font widthOf:aString

	] ifFalse:[

	    w := aString widthIn:self

	].

	w > widthOfWidestLine ifTrue:[

	    widthOfWidestLine := w

	] ifFalse:[

	    widthOfWidestLine := nil "/ means: unknown

	].

    ]

!

at:index put:aString

    "change a line and redisplay"

    self withoutRedrawAt:index put:aString.

    shown ifTrue:[

	self redrawLine:index

    ]

!

list

    "return the contents as a collection of strings"

    ^ list

!

setContents:something

    "set the contents (either a string or a Collection of strings)

     dont change position (i.e. do not scroll).

     This can be used to update a self-changing list 

     (for example: a file list being shown, without disturbing user too much).

     Compare with #contents:, which scrolls to top."

    |l oldSize|

    oldSize := self size.

    l := something.

    l notNil ifTrue:[

	l isString ifTrue:[

	    l := l asStringCollection

	]

    ].

    self setList:l.

    self size ~~ oldSize ifTrue:[

	self contentsChanged

    ]

!

contents:something

    "set the contents (either a string or a Collection of strings)

     also scroll to top. Compare with #setContents:, which does not scroll."

    |l|

    l := something.

    l notNil ifTrue:[

	l isString ifTrue:[

	    l := l asStringCollection

	]

    ].

    self list:l

!

list:aCollection

    "set the contents (a collection of strings or list entries) 

     and scroll to top-left"

    self list:aCollection expandTabs:true

!

list:aCollection expandTabs:expand

    "set the contents (a collection of strings) and scroll to top-left"

    |oldFirst oldLeft|

    (aCollection isNil and:[list isNil]) ifTrue:[

	"no change"

	self scrollToTop.

	self scrollToLeft.

	^ self

    ].

    list := aCollection.

    list notNil ifTrue:[

	expand ifTrue:[

	    self expandTabs

	] ifFalse:[

	    includesNonStrings := true.  "/ actually: do not know

	]

    ].

    widthOfWidestLine := nil.   "/ i.e. unknown

    oldFirst := firstLineShown.

    oldLeft := leftOffset.

    firstLineShown := 1.

    leftOffset := 0.

    realized ifTrue:[

	self contentsChanged.

	"

	 dont use scroll here to avoid the redraw

	"

	oldFirst ~~ firstLineShown ifTrue:[

	    self originChanged:(oldFirst - 1) negated.

	].

	shown ifTrue:[

	    self redrawFromVisibleLine:1 to:nLinesShown

	]

    ]

    "Modified: 30.8.1995 / 19:07:13 / claus"

!

setList:aCollection

    "set the contents (a collection of strings);

     do not change position (i.e. do not scroll).

     This can be used to update a self-changing list 

     (for example: a file list being shown, without disturbing user too much)"

    ^ self setList:aCollection expandTabs:true

!

setList:aCollection expandTabs:expandTabs

    "set the contents (a collection of strings);

     do not change position (i.e. do not scroll).

     This can be used to update a self-changing list 

     (for example: a file list being shown, without disturbing the user too much)"

    |oldFirst|

    (aCollection isNil and:[list isNil]) ifTrue:[

	"no change"

	^ self

    ].

    list := aCollection.

    list notNil ifTrue:[

	expandTabs ifTrue:[

	    self expandTabs

	] ifFalse:[

	    includesNonStrings := true.  "/ actually: do not know

	]

    ].

    self contentsChanged.

"/ new - reposition if too big

    (firstLineShown + nFullLinesShown) > self size ifTrue:[

	oldFirst := firstLineShown.

	firstLineShown := self size - nFullLinesShown + 1.

	firstLineShown < 1 ifTrue:[firstLineShown := 1].

	self originChanged:(oldFirst - 1) negated.

	shown ifTrue:[

	    self clear.

	]

    ].

"/ end new

    shown ifTrue:[

	self redrawFromVisibleLine:1 to:nLinesShown

    ]

!

contents

    "return the contents as a string"

    list isNil ifTrue:[^ ''].

    ^ list asStringCollection asString

!

removeIndexWithoutRedraw:lineNr

    "delete a line, given its lineNr - no redraw;

     return true, if something was really deleted (so sender knows,

     if a redraw is needed)"

    (list isNil or:[lineNr > self size]) ifTrue:[^ false].

    list removeIndex:lineNr.

    lineNr < firstLineShown ifTrue:[

	firstLineShown := firstLineShown - 1

    ].

    self contentsChanged.

    ^ true

!

removeIndex:lineNr

    "delete line, update view"

    |visLine w

     srcY "{ Class: SmallInteger }" |

    (self removeIndexWithoutRedraw:lineNr) ifFalse:[^ self].

    "

     is there a need to redraw ?

    "

    shown ifFalse:[^ self].

    visLine := self listLineToVisibleLine:lineNr.

    visLine notNil ifTrue:[

	w := self widthForScrollBetween:lineNr and:(firstLineShown + nLinesShown).

	srcY := topMargin + (visLine * fontHeight).

	self catchExpose.

	self copyFrom:self x:textStartLeft y:srcY

			 toX:textStartLeft y:(srcY - fontHeight)

		       width:w height:((nLinesShown - visLine) * fontHeight).

	self redrawVisibleLine:nFullLinesShown.

	"

	 redraw last partial line - if any

	"

	(nFullLinesShown ~~ nLinesShown) ifTrue:[

	    self redrawVisibleLine:nLinesShown

	].

	self waitForExpose

    ]

!

add:aString beforeIndex:index

    "add a line and redisplay"

    list add:aString beforeIndex:index.

    includesNonStrings ifFalse:[

	includesNonStrings := (aString notNil and:[aString isString not]).

    ].

    shown ifTrue:[

	self redrawFromLine:index.

	self contentsChanged.             "recompute scrollbars"

    ]

!

grow:n

    "grow our list"

    ^ list grow:n.

!

add:aString

    "add a line and redisplay"

    list add:aString.

    includesNonStrings ifFalse:[

	includesNonStrings := (aString notNil and:[aString isString not]).

    ].

    shown ifTrue:[

	self redrawLine:(self size).

	self contentsChanged.             "recompute scrollbars"

    ]

! !

!ListView methodsFor:'accessing-mvc'!

on:aModel aspect:aspectSymbol

    "ST-80 compatibility"

    ^ self on:aModel aspect:aspectSymbol change:nil list:aspectSymbol menu:nil 

!

on:aModel aspect:aspectSymbol change:changeSymbol 

    "ST-80 compatibility"

    ^self on:aModel aspect:aspectSymbol change:changeSymbol list:aspectSymbol menu:nil 

!

on:aModel aspect:aspectSymbol menu:menuSymbol 

    "ST-80 compatibility"

    ^self on:aModel aspect:aspectSymbol change:nil list:aspectSymbol menu:menuSymbol 

!

on:aModel aspect:aspectSymbol list:listSymbol menu:menuSymbol 

    "ST-80 compatibility"

    ^ self on:aModel aspect:aspectSymbol change:nil list:listSymbol menu:menuSymbol