"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg' }"

TextCollector subclass:#Workspace

	instanceVariableNames:'doItAction codeStartPosition errorFgColor errorBgColor

		commentStrings autoDefineWorkspaceVariables simulatedSelf

		autoDefineVariables compilerClass allowValueDrop

		poolsConsideredInDoIts'

	classVariableNames:'DefaultViewBackground DefaultErrorForegroundColor

		DefaultErrorBackgroundColor DefaultWarningBackgroundColor

		DefaultWarningForegroundColor WorkspaceVariables DoItHistory

		Sniplets'

	poolDictionaries:''

	category:'Interface-Smalltalk'

!

Workspace comment:'declared from: ..\..\..\stx\libwidg\abbrev.stc'

!

!Workspace class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    a view for editable text which can evaluate expressions.

    I.e. its basically a view for editable text, with added

    'doIt', 'printIt' and 'inspectIt' functions on the popup-menu.

    The action to be performed on doIt is defined by a block,

    which can be defined by the owner of this view.

    (thus you can put a workspace into more complex widgets, and

     control what should happen on 'doIt').

    A useful default action is automatically defined, which simply 

    evaluates the selection as a smalltalk expression. 

    (but, a lisp or prolog workspace would define its own action,

     to call for another compiler/interpreter  ...)

    Caveat:

        in this version, Workspace does not yet support doIt in MVC setups.

        For now, simulate this by setting the doItAction, to notify the

        model manually about the doIt.

    [instance variables:]

      doItAction      <Block>         block to evaluate for doIt

      errorFgColor    <Color>         fg-Color to be used when highlighting errors 

      errorBgColor    <Color>         bg-Color to be used when highlighting errors

      codeStartPosition               private temporary

    [styleSheet values:]

      codeErrorSelectionForegroundColor     fg color to highlight errors

                                            (default: selection fg)

      codeErrorSelectionBackgroundColor     bg color to highlight errors

                                            (default: selection bg)

    [start with:]

        Workspace open

    [see also:]

        Workspace EditTextView 

        Parser ByteCodeCompiler

    [author:]

        Claus Gittinger

"

! !

!Workspace class methodsFor:'accessing'!

sniplets

    Sniplets isNil ifTrue:[

        Sniplets := Dictionary new.

        self initializeDefaultAbbreviations.

    ].

    ^ Sniplets

    "

     Sniplets := nil

    "

!

sniplets:something

    Sniplets := something.

! !

!Workspace class methodsFor:'defaults'!

defaultLabel

    "my default window label"

    ^ 'Workspace'

    "Created: / 16.5.1998 / 16:53:37 / cg"

!

initializeDefaultAbbreviations

    Sniplets

        at: 'in'    put: 'isNil ';

        at: 'nn'    put: 'notNil ';

        at: 'it'    put: 'ifTrue: [!!]';

        at: 'if'    put: 'ifFalse: [!!]';

        at: 'itf'    put: 'ifTrue: [!!] ifFalse: []';

        at: 'int'   put: 'isNil ifTrue: [!!]';

        at: 'inf'   put: 'isNil ifFalse: [!!]';

        at: 'ints'  put: 'isNil ifTrue: [^self]';

        at: 'infs'  put: 'isNil ifFalse: [^self]';

        at: 'wt'    put: 'whileTrue: [!!]';

        at: 'wf'    put: 'whileFalse: [!!]';

        at: 'do'    put: 'do: [:each | !!]';

        at: 'dt'    put: 'detect: [:each | !!]';   

        at: 'de'    put: 'detect: [:each | !!]';

        at: 'det'   put: 'detect: [:each | !!]';

        at: 'dtn'   put: 'detect: [:each | !!] ifNone: []';

        at: 'cl'    put: 'collect: [:each | !!]';

        at: 'co'    put: 'collect: [:each | !!]';

        at: 'col'   put: 'collect: [:each | !!]';

        at: 'sl'    put: 'select: [:each | !!]';

        at: 'se'    put: 'select: [:each | !!]';

        at: 'sel'   put: 'select: [:each | !!]';

        at: 'rj'    put: 'reject: [:each | !!]';

        at: 're'    put: 'reject: [:each | !!]';

        at: 'rej'   put: 'reject: [:each | !!]';

        at: 'np'    put: 'nextPut: ';

        at: 'npa'   put: 'nextPutAll: ';

        at: 'y'     put: 'yourself.';

        at: 'sh'    put: 'self halt.';

        at: 'ps'    put: 'printString';

        at: 'sr'    put: 'self subclassResponsibility';

        at: 'st'    put: 'Smalltalk';

        at: 'ts'    put: 'Transcript showCR: ';

        at: 'trs'   put: 'Transcript showCR: ';

        at: 'ik'    put: 'includesKey: #';

        at: 'abb'   put: 'Workspace sniplets inspect';

        at: 'ws'    put: 'Delay waitForSeconds: 1'; 

        at: 'wfs'   put: 'Delay waitForSeconds: 1'; 

        at: 'wfm'   put: 'Delay waitForMilliseconds: 1000'; 

        at: 'slef'  put: 'self';

        at: 'ati'   put: 'at:!! ifAbsent: ';

        at: 'A'     put: 'Array';

        at: 'An'    put: 'Array new:';

        at: 'OC'    put: 'OrderedCollection';

        at: 'Di'    put: 'Dictionary';

        at: 'ID'    put: 'IdentityDictionary';

        at: 'Id'    put: 'IdentityDictionary';

        at: 'OCn'   put: 'OrderedCollection new.';

        at: 'Aw'    put: 'Array with:';

        at: 'Aww'   put: 'Array with:!! with:';

        at: 'Awww'  put: 'Array with:!! with: with:';

        yourself

!

updateStyleCache

    "extract values from the styleSheet and cache them in class variables"

    <resource: #style (#'codeErrorSelection.foregroundColor'

                       #'codeErrorSelection.backgroundColor'

                       #'codeView.backgroundColor' )>

    DefaultErrorForegroundColor := StyleSheet colorAt:'codeErrorSelection.foregroundColor'.

    DefaultErrorBackgroundColor := StyleSheet colorAt:'codeErrorSelection.backgroundColor'.

    DefaultViewBackground := StyleSheet colorAt:'codeView.backgroundColor'.

! !

!Workspace class methodsFor:'getting a new Workspace'!

open

    "launch a new workspace"

    |scr topView workspace f|

    topView := StandardSystemView 

                label:(self classResources string:(self defaultLabel)) 

                " minExtent:(100 @ 100)".

    scr := HVScrollableView for:self in:topView.

    scr origin:(0.0 @ 0.0) corner:(1.0 @ 1.0).

    workspace := scr scrolledView.

    "/ adjust topViews extent according to my font

    f := workspace font.

    topView extent:((f widthOf:'x') * 40) @ (f height * 10).

    topView open.

    ^ workspace

    "

     Workspace open

    "

    "Modified: / 16.5.1998 / 16:53:53 / cg"

!

openForRemote:hostName

    "launch a new workspace to evaluate expression on some remote machine.

     Entered expressions are sent over to some partner machine, evaluated there,

     and the result is shown here.

     This requires the RemoteObjects package to be loaded."

    |server remoteCompiler workspace|

    RemoteObjectServer isNil ifTrue:[

        self warn:'no remoteObjectServer available'.

        ^ nil

    ].

    server := RemoteObjectServer on:hostName.

    remoteCompiler := server get:#Compiler.

    workspace := self open.

    workspace topView 

        label:(self classResources string:'Remote Workspace {%1}' with:hostName).

    workspace doItAction:

                [:theCode |

                    remoteCompiler 

                        evaluate:theCode 

                        in:nil 

                        receiver:nil 

                        notifying:workspace 

                        logged:true 

                        ifFail:nil 

                ]

    "

     Workspace openForRemote:'andi'

    "

    "Modified: / 16.5.1998 / 16:57:38 / cg"

!

openWith:initialText selected:selectedBoolean

    "launch a new workspace with some initial contents"

    |workspace|

    workspace := self open.

    workspace contents:initialText selected:selectedBoolean.

    ^ workspace

    "

     Workspace openWith:'Transcript showCR:''hello world'''

    "

! !

!Workspace class methodsFor:'history'!

clearDoItHistory

    DoItHistory := nil

!

doItHistory

    ^ DoItHistory

!

doItHistorySize

    "the number of remembered doIts"

    ^ 20

!

rememberDoIt:aString

    |string|

    string := aString asString string withoutSeparators.

    (string asCollectionOfWords size <= 1) ifTrue:[

        ((Scanner new scanTokens:string) size <= 1) ifTrue:[

            "its a variable only"

            ^ self

        ]

    ].

    DoItHistory isNil ifTrue:[

        DoItHistory := OrderedCollection new.

    ].

    DoItHistory remove:string ifAbsent:nil.

    DoItHistory addFirst:string.

    DoItHistory size > self doItHistorySize ifTrue:[

        DoItHistory removeLast

    ].

    Scanner

! !

!Workspace class methodsFor:'queries'!

isVisualStartable

    "returns whether this application class can be started via #open

     (i.e. via a double click on the class in the browser)"

    ^ self == Workspace

    "Created: / 16.5.1998 / 16:59:00 / cg"

    "Modified: / 16.5.1998 / 16:59:39 / cg"

! !

!Workspace class methodsFor:'workspace variables'!

addWorkspaceVariable:name

    "create a new workspace variable"

    |holder|

    holder := self workspaceVariables at:name ifAbsentPut:[ ValueHolder new ].

    ^ holder

!

anyWorkspaceVariableIsDefined

    ^ WorkspaceVariables notEmptyOrNil

    "Created: / 20-04-2005 / 11:57:53 / cg"

!

removeAllWorkspaceVariables

    "delete all workspace variables"

    WorkspaceVariables := nil

!

removeWorkspaceVariable:name

    "delete a workspace variable"

    WorkspaceVariables notNil ifTrue:[

        WorkspaceVariables removeKey:name ifAbsent:nil.

        WorkspaceVariables isEmpty ifTrue:[

            WorkspaceVariables := nil

        ]

    ].

!

workspaceVariableAt:name

    "retrieve a workspace variable (actually, a holder onto it)"

    WorkspaceVariables isNil ifTrue:[^ nil].

    ^ WorkspaceVariables at:name ifAbsent:nil.

!

workspaceVariableNames

    "retrieve the collection of workspace variable names"

    WorkspaceVariables isNil ifTrue:[^ #()].

    ^ WorkspaceVariables keys

    "Created: / 20-04-2005 / 11:42:45 / cg"

!

workspaceVariables

    "retrieve the collection of workspace variables.

     That is a dictionary associating names to values."

    WorkspaceVariables isNil ifTrue:[

        WorkspaceVariables := Dictionary new.

    ].

    ^ WorkspaceVariables

    "Modified: / 20-04-2005 / 11:43:14 / cg"

! !

!Workspace methodsFor:'accessing'!

allowValueDrop:aBoolean

    "if on (the default), any smalltalk value can be dropped and leads to a workspace variable

     holding on to that being defined. Can be turned off, if youdont like this (for standAlone apps)"

    allowValueDrop := aBoolean.

    "Created: / 28-11-2006 / 16:13:02 / cg"

!

autoDefineVariables

    ^ autoDefineVariables 

!

autoDefineVariables:nilOrSymbol

    "undefined variables handling:

        are automatically defined as workspace variable if nilOrSymbol is #workspace.

        are automatically defined as doit variable if nilOrSymbol is #doit.

        are left undefined if nilOrSymbol is nil."

    autoDefineVariables := nilOrSymbol.

    "Modified: / 28-11-2006 / 16:21:01 / cg"

!

commentStrings:anArrayOfCommentStrings

    "define the comment strings"

    commentStrings := anArrayOfCommentStrings

    "Created: / 9.11.1997 / 01:05:25 / cg"

!

doItAction

    "return the action to be performed when 'doIt' is selected"

    ^ doItAction

!

errorBackgroundColor

    errorBgColor notNil ifTrue:[ ^ errorBgColor ].

    DefaultErrorBackgroundColor notNil ifTrue:[ ^ DefaultErrorBackgroundColor ].

    device hasColors ifTrue:[ ^ Color red ].

    ^ selectionBgColor

!

errorForegroundColor

    errorFgColor notNil ifTrue:[ ^ errorFgColor ].

    DefaultErrorForegroundColor notNil ifTrue:[ ^ DefaultErrorForegroundColor ].

    ^ selectionFgColor

!

hasSelectionOrTextInCursorLine

    ^ (self selectionOrTextOfCursorLine:false) notNil

!

poolsConsideredInDoIts:something

    poolsConsideredInDoIts := something.

!

selectAll

    super selectAll

!

selectionOrTextOfCursorLine

    ^ self selectionOrTextOfCursorLine:true

!

selectionOrTextOfCursorLine:doSelect

    |sel lNr line|

    sel := self selectionAsString.

    sel notNil ifTrue:[^ sel].

    lNr := self cursorLine.

    line := self listAt:lNr.