"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

View subclass:#PullDownMenu

	instanceVariableNames:'receiver menus titles selectors activeMenuNumber

		showSeparatingLines topMargin fgColor bgColor activeFgColor

		activeBgColor onLevel offLevel edgeStyle keepMenu toggleKeep

		raiseTopWhenActivated actions'

	classVariableNames:'DefaultViewBackground DefaultForegroundColor

		DefaultBackgroundColor DefaultHilightForegroundColor

		DefaultHilightBackgroundColor DefaultLevel DefaultHilightLevel

		DefaultShadowColor DefaultLightColor DefaultEdgeStyle

		DefaultKeepMenu DefaultToggleKeep DefaultSeparatingLines'

	poolDictionaries:''

	category:'Views-Menus'

!

!PullDownMenu class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    PullDown menu provides the top (always visible) part of these menus. 

    It controls display of its menus, which become visible when one of the 

    PullDownMenus entries is pressed.

    A PullDownMenu itself consists of a single row of labels, which activate

    a pulled menu when clicked. Entries may be empty (i.e. have no menu)

    and empty entries may (optionally) also perform some action when clicked.

    An entries selector is used as the key to define and access submenus

    and (for empty entries:) the selector sent to the receiver of the menu.

    [Instance variables:]

      menus                   <Collection>    the sub menus

      titles                  <Collection>    the strings in the menu

      selectors               <Collection>    the selectors to send to the menu-

                                              receiver (for empty pull-menus)

                                              if nil (the default), title entries

                                              do not send anything.

      activeMenuNumber        <Number>        the index of the currently active menu

      showSeparatingLines     <Boolean>       show separating lines between my menu-strings

      topMargin               <Number>        number of pixels at top

      fgColor                 <Color>         fg color to draw passive menu-titles

      bgColor                 <Color>         bg color to draw passive menu-titles

      activeFgColor           <Color>         fg color to draw activated menu-titles

      activeBgColor           <Color>         bg color to draw activated menu-titles

      onLevel                 <Integer>       3D level of entry-buttons when pressed

      offLevel                <Integer>       3D level of entry-buttons when released

      edgeStyle               <Symbol>        how to draw edges

      keepmenu                <Boolean>       if on, pulled menu stays on click,

                                              till clicked again (motif & windows behavior)

      toggleKeep              <Boolean>       if on and keepMenu is on,

                                              clicking again on label closes menu

     except menus, titles and selectors, instvars are usually defined from

     defaults in the styleSheet; you should not care for them.

    [StyleSheet values:]

      pullDownMenuViewBackground              view background Color for the menu bar

                                              default: menuViewBackground

      pullDownMenuForegroundColor             foreground drawing color for the menu bar

                                              default: menuForegroundColor

      pullDownMenuBackgroundColor             background drawing color for the menu bar

                                              default: menuBackgroundColor

      pullDownMenuHilightForegroundColor      active foreground drawing color for the menu bar

                                              default: menuHilightForegroundColor

      pullDownMenuHilightBackgroundColor      active background drawing color for the menu bar

                                              default: menuHilightBackgroundColor

      pullDownMenuHilightLevel                level (3D only) when active

                                              default: menuHilightLevel

      pullDownMenuEdgeStyle                   edge style (nil or #soft)

      pullDownMenuKeepMenu                    if true, pulled menu stays open until button

                                              is pressed again outside of the item-area (motif behavior)

                                              if false, menu closes on release (default)

      pullDownMenuToggleKeep                  if true, pulled menu closes when an entry is pressed

                                              again. Otherwise, only press outside of the items area

                                              hides it. default is false

      pullDownMenuLevel                       level (3D only)

      pullDownMenuFont                        font to use for the menu bar

                                              default: menuFont

      pullDownMenuShowSeparatingLines         if true, lines are drawn between items.

                                              default: false

      pullDownMenuRaiseTop                    if true, topview is raised whenever an entry

                                              is activated.

                                              default: true

    [author:]

        Claus Gittinger

"

!

examples 

"

                                                                        [exBegin]

        |top menu|

        top := StandardSystemView new.

        top extent:300@300.

        menu := PullDownMenu origin:0.0@0.0 corner:1.0@30 in:top.

        menu labels:#('foo' 'bar').

        menu selectors:#(foo bar).

        menu at:#foo

             putLabels:#('foo1' 'foo2' 'foo3')

             selectors:#(foo1 foo2 foo3)

             receiver:nil.

        menu at:#bar 

             putLabels:#('bar1' 'bar2' 'bar3')

             selectors:#(bar1 bar2 bar3)

             receiver:nil.

        top open

    empty entries are possible as selectable items (with non-nil seletor) ...

                                                                        [exEnd]

        |top menu|

        top := StandardSystemView new.

        top extent:300@300.

        menu := PullDownMenu origin:0.0@0.0 corner:1.0@30 in:top.

        menu labels:#('foo' 'bar' 'baz').

        menu selectors:#(foo bar baz).

        menu at:#foo

             putLabels:#('foo1' 'foo2' 'foo3')

             selectors:#(foo1 foo2 foo3)

             receiver:nil.

        menu at:#baz 

             putLabels:#('baz1' 'baz2' 'baz3')

             selectors:#(baz1 baz2 baz3)

             receiver:nil.

        top open

    ... or as separators (with nil selector)

                                                                        [exBegin]

        |top menu|

        top := StandardSystemView new.

        top extent:500@200.

        menu := PullDownMenu origin:0.0@0.0 corner:1.0@30 in:top.

        menu labels:#('foo' '    ' 'bar' ' baz' '    ' 'moreFoo' 'moreBar' 'moreBaz').

        menu selectors:#(foo nil bar baz nil moreFoo moreBar moreBaz).

        menu at:#foo

             putLabels:#('foo1' 'foo2' 'foo3')

             selectors:#(foo1 foo2 foo3)

             receiver:nil.

        menu at:#bar 

             putLabels:#('bar1' 'bar2' 'bar3')

             selectors:#(bar1 bar2 bar3)

             receiver:nil.

        menu at:#baz 

             putLabels:#('baz1' 'baz2' 'baz3')

             selectors:#(baz1 baz2 baz3)

             receiver:nil.

        top open

    use the menus default height

                                                                        [exEnd]

        |top menu|

        top := StandardSystemView new.

        top extent:300@300.

        menu := PullDownMenu in:top.

        menu origin:0.0@0.0 corner:1.0@(menu height).

        menu labels:#('foo' 'bar').

        menu selectors:#(foo bar).

        menu at:#foo

             putLabels:#('foo1' 'foo2' 'foo3')

             selectors:#(foo1 foo2 foo3)

             receiver:nil.

        top open

    although you can change the font, colors etc. (as shown below)

    you should NOT do it - since if you do so, the styleSheet settings

    are ineffective (which users probably won't like)

    BTW: The styleSheet entries for below are pullDownMenuForegroundColor,

         pullDownMenuBackgroundColor and pullDownMenuFont

                                                                        [exBegin]

        |top menu|

        top := StandardSystemView new.

        menu := PullDownMenu in:top.

        menu font:(Font family:'courier' size:20).

        menu foregroundColor:Color red.

        menu backgroundColor:Color yellow.

        menu viewBackground:Color yellow.

        menu showSeparatingLines:true.

        menu origin:0.0@0.0 corner:1.0@(menu height).

        menu labels:#('foo' 'bar').

        menu selectors:#(foo bar).

        menu at:#foo

             putLabels:#('foo1' 'foo2' 'foo3')

             selectors:#(foo1 foo2 foo3)

             receiver:nil.

        (menu menuAt:#foo) font:(Font family:'courier' size:36).

        top open

    you can use icons, too ...

                                                                        [exEnd]

        |labels top menu|

        top := StandardSystemView new.

        top extent:300@300.

        menu := PullDownMenu in:top.

        menu origin:0.0@0.0 corner:1.0@(menu height).

        labels := Array with:((Image fromFile:'SmalltalkX.xbm') magnifiedTo:16@16)

                        with:'foo'

                        with:'bar'.

        menu labels:labels.

        menu selectors:#(about foo bar).

        menu at:#about 

             putLabels:#('about PullDownMenus')

             selectors:#(aboutMenus)

             receiver:nil.

        menu at:#foo

             putLabels:#('foo1' 'foo2' 'foo3')

             selectors:#(foo1 foo2 foo3)

             receiver:nil.

        top open

    a concrete example (combining things described above)

    (using a Plug, since we have no application class here):

                                                                        [exBegin]

        |labels top menu textView appModel|

        appModel := Plug new.

        appModel respondTo:#quit with:[top destroy].

        appModel respondTo:#showAbout with:[self information:'some info here ...'].

        appModel respondTo:#help with:[self information:'some help here ...'].

        top := StandardSystemView new.

        top extent:300@300.

        menu := PullDownMenu in:top.

        menu receiver:appModel.

        menu origin:0.0@0.0 corner:1.0@(menu height).

        textView := ScrollableView forView:(EditTextView new).

        textView origin:0.0@menu height corner:1.0@1.0.

        top addSubView:textView.

        labels := Array with:((Image fromFile:'SmalltalkX.xbm') magnifiedTo:16@16)

                        with:'file'

                        with:'edit'

                        with:'help'.

        menu labels:labels.

        menu selectors:#(about file edit help).

        menu at:#about 

             putLabels:#('about PullDownMenus')

             selectors:#(showAbout)

             receiver:appModel.

        menu at:#file 

             putLabels:#('quit')

             selectors:#(quit)

             receiver:appModel.

        menu at:#edit 

             putLabels:#('copy' 'cut' 'paste')

             selectors:#(copySelection cut paste)

             receiver:textView.

        top open

                                                                        [exEnd]

"

! !

!PullDownMenu class methodsFor:'instance creation'!

labels:titleArray

    "create and return a new PullDownMenu"

    ^ self new labels:titleArray

! !

!PullDownMenu class methodsFor:'defaults'!

updateStyleCache

    "extract values from the styleSheet and cache them in class variables"

    <resource: #style (#pullDownMenuViewBackground #menuViewBackground

                       #pullDownMenuForegroundColor #menuForegroundColor

                       #pullDownMenuBackgroundColor #menuBackgroundColor

                       #pullDownMenuHilightForegroundColor #menuHilightForegroundColor

                       #pullDownMenuHilightBackgroundColor #menuHilightBackgroundColor

                       #pullDownMenuHilightLevel #menuHilightLevel

                       #pullDownMenuEdgeStyle #pullDownMenuKeepMenu

                       #pullDownMenuToggleKeep #pullDownMenuLevel

                       #pullDownMenuFont #menuFont

                       #pullDownMenuSeparatingLines)>

    |styleSheet|

    styleSheet := StyleSheet.

    DefaultViewBackground := styleSheet colorAt:'pullDownMenuViewBackground'.

    DefaultViewBackground isNil ifTrue:[

        DefaultViewBackground := styleSheet colorAt:'menuViewBackground'.

    ].

    DefaultForegroundColor := styleSheet colorAt:'pullDownMenuForegroundColor'.

    DefaultForegroundColor isNil ifTrue:[

        DefaultForegroundColor := styleSheet colorAt:'menuForegroundColor'.

    ].

    DefaultBackgroundColor := styleSheet colorAt:'pullDownMenuBackgroundColor'.

    DefaultBackgroundColor isNil ifTrue:[

        DefaultViewBackground notNil ifTrue:[

            DefaultBackgroundColor := DefaultViewBackground

        ] ifFalse:[

            DefaultBackgroundColor := styleSheet colorAt:'menuBackgroundColor'.

        ]

    ].

    DefaultHilightForegroundColor := styleSheet colorAt:'pullDownMenuHilightForegroundColor'.

    DefaultHilightForegroundColor isNil ifTrue:[

        DefaultHilightForegroundColor := styleSheet colorAt:'menuHilightForegroundColor'.

    ].

    DefaultHilightBackgroundColor := styleSheet colorAt:'pullDownMenuHilightBackgroundColor'.

    DefaultHilightBackgroundColor isNil ifTrue:[

        DefaultHilightBackgroundColor := styleSheet colorAt:'menuHilightBackgroundColor'.

    ].

    DefaultHilightLevel := styleSheet at:'pullDownMenuHilightLevel'.

    DefaultHilightLevel isNil ifTrue:[

        DefaultHilightLevel := styleSheet at:'menuHilightLevel' default:0.

    ].

    DefaultEdgeStyle := styleSheet at:'pullDownMenuEdgeStyle'.

    DefaultKeepMenu := styleSheet at:'pullDownMenuKeepMenu' default:false.

    DefaultToggleKeep := styleSheet at:'pullDownMenuToggleKeep' default:false.

    DefaultLevel := styleSheet at:'pullDownMenuLevel' default:1.

    DefaultFont := styleSheet fontAt:'pullDownMenuFont'.

    DefaultFont isNil ifTrue:[DefaultFont := styleSheet fontAt:'menuFont'].

    DefaultSeparatingLines := styleSheet at:'pullDownMenuSeparatingLines' default:false.

    "

     PullDownMenu updateStyleCache

    "

    "Modified: 1.3.1996 / 13:45:19 / cg"

! !

!PullDownMenu methodsFor:'accessing'!

add:label selector:selector

    "add a new title-item at the end.

     The corresponding label can later be set with #at:putMenu:

     or #at:putLabels:selectors:..."

    self add:label selector:selector after:nil

    "Modified: 5.6.1996 / 16:45:46 / cg"

!

add:label selector:selector after:indexOrString

    "add a new title-item after an existing item, indexOrString,

     or at the end if the after-arg is nil.

     The corresponding label can later be set with #at:putMenu:

     or #at:putLabels:selectors:..."

    |idx|

    indexOrString isNil ifTrue:[

        idx := titles size

    ] ifFalse:[

        idx := self indexOf:indexOrString.

    ].

    titles isNil ifTrue:[

        menus := Array with:nil.

        titles := Array with:label.

        selectors := Array with:selector.

    ] ifFalse:[

        menus := (menus copyTo:idx) , #(nil) , (menus copyFrom:idx+1).

        titles := ((titles copyTo:idx) copyWith:label) , (titles copyFrom:idx+1).

        selectors := ((selectors copyTo:idx) copyWith:selector) , (selectors copyFrom:idx+1).

    ].

    shown ifTrue:[

        self redraw

    ]

    "

     |top m|

     top := StandardSystemView new.

     m := PullDownMenu in:top.

     m labels:#('file' 'edit').

     m selectors:#(file #edit).

     m add:'help' selector:#help after:#file.

     m at:#help putMenu:(MenuView labels:#('foo' 'bar')

                               selectors:#(foo bar)

                                receiver:nil).

     top open

    "

    "Modified: 5.7.1996 / 11:40:47 / cg"

!

add:label selector:selector before:indexOrString

    "add a new title-item before an existing item, indexOrString,

     or at the beginning if the before-arg is nil.

     The corresponding label can later be set with #at:putMenu:

     or #at:putLabels:selectors:..."

    |idx|

    indexOrString isNil ifTrue:[

        idx := 1

    ] ifFalse:[

        idx := self indexOf:indexOrString.

    ].

    titles isNil ifTrue:[

        menus := Array with:nil.

        titles := Array with:label.

        selectors := Array with:selector.

    ] ifFalse:[

        menus := (menus copyTo:idx-1) , #(nil) , (menus copyFrom:idx).

        titles := ((titles copyTo:idx-1) copyWith:label) , (titles copyFrom:idx).

        selectors := ((selectors copyTo:idx-1) copyWith:selector) , (selectors copyFrom:idx).

    ].

    shown ifTrue:[