1 "

     2  COPYRIGHT (c) 1989 by Claus Gittinger

     3 	      All Rights Reserved

     4 

     5  This software is furnished under a license and may be used

     6  only in accordance with the terms of that license and with the

     7  inclusion of the above copyright notice.   This software may not

     8  be provided or otherwise made available to, or used by, any

     9  other person.  No title to or ownership of the software is

    10  hereby transferred.

    11 "

    12 

    13 SimpleView subclass:#ScrollableView

    14 	instanceVariableNames:'scrolledView vScrollBar hScrollBar scrollBarPosition lockUpdates

    15 		hideVScrollBar hideHScrollBar hasHorizontalScrollBar

    16 		hasVerticalScrollBar horizontalMini verticalMini vScrollBarHidden

    17 		hScrollBarHidden'

    18 	classVariableNames:'DefaultScrolledViewLevel DefaultScrolledViewMargin

    19 		DefaultScrollBarSpacing DefaultScrolledViewBorderWidth

    20 		DefaultLevel DefaultScrollBarLevel MyDefaultViewBackgroundColor'

    21 	poolDictionaries:''

    22 	category:'Views-Basic'

    23 !

    24 

    25 !ScrollableView class methodsFor:'documentation'!

    26 

    27 copyright

    28 "

    29  COPYRIGHT (c) 1989 by Claus Gittinger

    30 	      All Rights Reserved

    31 

    32  This software is furnished under a license and may be used

    33  only in accordance with the terms of that license and with the

    34  inclusion of the above copyright notice.   This software may not

    35  be provided or otherwise made available to, or used by, any

    36  other person.  No title to or ownership of the software is

    37  hereby transferred.

    38 "

    39 !

    40 

    41 documentation

    42 "

    43     a view containing a scrollbar and some other (slave-)view.

    44     This view wraps scrollbar(s) around the view to be scrolled.

    45     The scrollbars are setup to send scrollUp/scrollDown/scrollVerticalTo

    46     and scrollLeft/scrollRight/scrollHorizontalTo- messages whenever moved.

    47     The view itself has to implement these (there is a default implementation

    48     in the common View class for this - so your widgets usually dont have to

    49     care for this).

    50 

    51     For the scrollbars to know about the full (maximum) size, the view

    52     MUST implement #heightOfContents and/or #widthOfContents.

    53     The values returned by those methods are used to compute the fraction

    54     which is visible (i.e. the scrollers thumb heights).

    55 

    56     There are three ways to setup a scrollableView:

    57     if the type of the view to be scrolled is known in advance,

    58     use:

    59 	v := ScrollableView for:<ViewClass>

    60     or:

    61 	v := ScrollableView for:<ViewClass> in:someSuperView

    62 

    63 

    64     otherwise, create an empty scrollableView with:

    65 

    66 	v := ScrollableView new

    67     or:

    68 	v := ScrollableView in:someSuperView

    69 

    70     and define the view later with:

    71 

    72 	v scrolledView:aViewToBeScrolled

    73 

    74 

    75     Finally, if the view to be scrolled has been already created,

    76     use:

    77 

    78 	v := ScrollableView forView:aViewToBeScrolled

    79     or:    

    80 	v := ScrollableView forView:aViewToBeScrolled in:someSuperView

    81 

    82     It is also possible to change the scrolledView later (even multiple times).

    83     This may be useful, if different views are needed to display different types

    84     of data (see example2) and at creation time, it is not known what type

    85     of view is required (multidocument format applications).

    86 

    87     If you want to scroll a bucnh of other views (instead of a views contents),

    88     you need a companion class (ViewScroller). See the documentation there.

    89 

    90     If you need horizontal scrolling too, use an instance of HVScrollableView.

    91 

    92     By default, scrollbars are full size scrollbars - for horizontal scrolling

    93     (which is less often used), scrollableViews can optionally be created with

    94     miniscrollers which take up less screen space.

    95 

    96     TODO:

    97 	this is pretty old and needs a rewrite. There are quite some

    98 	historic leftovers found here and things can be done better

    99 	(especially in initializeFor...)

   100 

   101 	Also, it should be rewritten into one class which supports both

   102 	Vertical-only, Horizontal-only and HV scrolling.

   103 	Currently, horizontal-only scrolling is not available.

   104 	(you have to write your own class ...)

   105 

   106 	Finally, some means to hide scrollbars should be added - this would

   107 	give more screenspace to the view when all is visible 

   108 	(and therefore, the scrollbars are not needed, anyway)

   109 

   110 	Expect the above things to be fixed in an upcoming version.

   111 

   112     Recent changes:

   113 	Originally, there where two classes, for vertical-only and

   114 	horizontal+vertical scrollability.

   115 	These have now been merged into the common ScrollableView class,

   116 	and each scrollability can be controlled individually.

   117 	The original HVScrollableView class is almost empty, but remains

   118 	for backward compatibility (it simply initializes the scrollability

   119 	flags for H+V scrollability).

   120 

   121     [author:]

   122 	Claus Gittinger

   123 

   124     [see also:]

   125 	ScrollBar Scroller

   126 	 HVScrollableView

   127 "

   128 !

   129 

   130 examples

   131 "

   132   simple scrolled text:

   133 									[exBegin]

   134 	|top scr txt|

   135 

   136 	top := StandardSystemView label:'scroll example1'.

   137 	top extent:200@100.

   138 

   139 	scr := ScrollableView for:EditTextView in:top.

   140 	scr origin:0.0@0.0 corner:1.0@1.0.

   141 	txt := scr scrolledView.

   142 

   143 	txt list:#('line1'

   144 		   'line2'

   145 		   'line3'

   146 		   'line4'

   147 		   'line5'

   148 		   'line7'

   149 		   'line8'

   150 		   'line9'

   151 		   'line10'

   152 		  ).

   153 	top open

   154 									[exEnd]

   155 

   156 

   157   changing the scrolledView later:

   158 									[exBegin]

   159 	|top scr txtView1 txtView2 browserView|

   160 

   161 	top := StandardSystemView label:'scroll example2'.

   162 	top extent:300@100.

   163 

   164 	scr := ScrollableView in:top.

   165 	scr origin:0.0@0.0 corner:1.0@1.0.

   166 

   167 	top open.

   168 

   169 	(Delay forSeconds:5) wait.

   170 

   171 	txtView1 := EditTextView new.

   172 	txtView1 list:#(

   173 			'wait 5 seconds to see the other text'

   174 			'line2'

   175 			'line3'

   176 			'line4'

   177 			'line5'

   178 			'line7'

   179 			'line8'

   180 			'line9'

   181 			'line10'

   182 		  ).

   183 	scr scrolledView:txtView1.

   184 

   185 	(Delay forSeconds:5) wait.

   186 

   187 	txtView2 := EditTextView new.

   188 	txtView2 list:#('this is the other views text' 

   189 			'alternative line2'

   190 			'alternative line3'

   191 			'alternative line4'

   192 			'alternative line5'

   193 			'alternative line6').

   194 	scr scrolledView:txtView2.

   195 									[exEnd]

   196 

   197 

   198 

   199 

   200   using a miniscroller:

   201 									[exBegin]

   202 	|top scr txt|

   203 

   204 	top := StandardSystemView label:'scroll example3'.

   205 	top extent:200@100.

   206 

   207 	scr := ScrollableView for:EditTextView miniScroller:true in:top.

   208 	scr origin:0.0@0.0 corner:1.0@1.0.

   209 	txt := scr scrolledView.

   210 

   211 	txt list:#('line1'

   212 		   'line2'

   213 		   'line3'

   214 		   'line4'

   215 		   'line5'

   216 		   'line7'

   217 		   'line8'

   218 		   'line9'

   219 		   'line10'

   220 		  ).

   221 	top open

   222 									[exEnd]

   223 

   224 

   225 

   226   scrolling in both directions:

   227     Notice: HVScrollableView remains existent for backward compatibility;

   228 	    scrollability can now be controlled in both directions at any

   229 	    time (see examples below).

   230 									[exBegin]

   231 	|top scr txt|

   232 

   233 	top := StandardSystemView label:'scroll example4'.

   234 	top extent:200@100.

   235 

   236 	scr := HVScrollableView for:EditTextView in:top.

   237 	scr origin:0.0@0.0 corner:1.0@1.0.

   238 	txt := scr scrolledView.

   239 

   240 	txt list:#('line1'

   241 		   'line2'

   242 		   'line3'

   243 		   'line4'

   244 		   'line5'

   245 		   'line7'

   246 		   'line8'

   247 		   'line9'

   248 		   'line10'

   249 		  ).

   250 	top open

   251 									[exEnd]

   252 

   253 

   254 

   255   using a full scroller vertically, miniscroller horizontally:

   256     Notice: HVScrollableView remains existent for backward compatibility;

   257 	    scrollability can now be controlled in both directions at any

   258 	    time (see examples below).

   259 									[exBegin]

   260 	|top scr txt|

   261 

   262 	top := StandardSystemView label:'scroll example5'.

   263 	top extent:200@100.

   264 

   265 	scr := HVScrollableView for:EditTextView miniScrollerH:true in:top.

   266 	scr origin:0.0@0.0 corner:1.0@1.0.

   267 	txt := scr scrolledView.

   268 

   269 	txt list:#('line1'

   270 		   'line2'

   271 		   'line3'

   272 		   'line4'

   273 		   'line5'

   274 		   'line7'

   275 		   'line8'

   276 		   'line9'

   277 		   'line10'

   278 		  ).

   279 	top open

   280 									[exEnd]

   281 

   282 

   283 

   284   using miniscrollers for both directions:

   285     Notice: HVScrollableView remains existent for backward compatibility;

   286 	    scrollability can now be controlled in both directions at any

   287 	    time (see examples below).

   288 									[exBegin]

   289 	|top scr txt|

   290 

   291 	top := StandardSystemView label:'scroll example6'.

   292 	top extent:200@100.

   293 

   294 	scr := HVScrollableView for:EditTextView miniScroller:true in:top.

   295 	scr origin:0.0@0.0 corner:1.0@1.0.

   296 	txt := scr scrolledView.

   297 

   298 	txt list:#('line1'

   299 		   'line2'

   300 		   'line3'

   301 		   'line4'

   302 		   'line5'

   303 		   'line7'

   304 		   'line8'

   305 		   'line9'

   306 		   'line10'

   307 		  ).

   308 	top open

   309 									[exEnd]

   310   controlling scrollability:

   311 									[exBegin]

   312 	|top scr txt|

   313 

   314 	top := StandardSystemView label:'scroll example6'.

   315 	top extent:200@100.

   316 

   317 	txt := EditTextView new.

   318         

   319 	scr := ScrollableView forView:txt in:top.

   320 	scr origin:0.0@0.0 corner:1.0@1.0.

   321 	scr horizontalScrollable:true.

   322 	scr verticalScrollable:false.

   323 

   324 	txt list:#('line1'

   325 		   'line2'

   326 		   'line3'

   327 		   'line4'

   328 		   'line5'

   329 		   'line7'

   330 		   'line8'

   331 		   'line9'

   332 		   'line10'

   333 		  ).

   334 	top open

   335 									[exEnd]

   336   controlling scrollability and miniScroller:

   337 									[exBegin]

   338 	|top scr txt|

   339 

   340 	top := StandardSystemView label:'scroll example6'.

   341 	top extent:200@100.

   342 

   343 	txt := EditTextView new.

   344 

   345 	scr := ScrollableView forView:txt in:top.

   346 	scr origin:0.0@0.0 corner:1.0@1.0.

   347 	scr horizontalScrollable:true; horizontalMini:false.

   348 	scr verticalScrollable:true; verticalMini:true.

   349 

   350 	txt list:#('line1'

   351 		   'line2'

   352 		   'line3'

   353 		   'line4'

   354 		   'line5'

   355 		   'line7'

   356 		   'line8'

   357 		   'line9'

   358 		   'line10'

   359 		  ).

   360 	top open

   361 									[exEnd]

   362   autohiding scrollbars (edit the text to make scrollbars visible/invisible)

   363   (NOTICE:

   364 	this is controlled by the styleSheet and 

   365 	should normally NOT be done by the program):

   366 									[exBegin]

   367 	|top scr txt|

   368 

   369 	top := StandardSystemView label:'scroll example6'.

   370 	top extent:200@100.

   371 

   372 	txt := EditTextView new.

   373 

   374 	scr := ScrollableView forView:txt in:top.

   375 	scr origin:0.0@0.0 corner:1.0@1.0.

   376 	scr horizontalScrollable:true; horizontalMini:false.

   377 	scr verticalScrollable:true; verticalMini:true.

   378 	scr autoHideScrollBars:true.

   379 

   380 	txt list:#('line1'

   381 		   'line2'

   382 		   'line3'

   383 		   'line4'

   384 		   'line5'

   385 		   'line7'

   386 		   'line8'

   387 		   'line9'

   388 		   'line10'

   389 		  ).

   390 	top open

   391 									[exEnd]

   392 "

   393 ! !

   394 

   395 !ScrollableView class methodsFor:'instance creation'!

   396 

   397 for:aViewClass

   398     "return a new scrolling view scrolling an instance of aViewClass.

   399      The subview is created here.

   400      The view will have full scrollbars."

   401 

   402     ^ self 

   403         for:aViewClass

   404         hasHorizontalScrollBar:self defaultHorizontalScrollable

   405         hasVerticalScrollBar:self defaultVerticalScrollable

   406         miniScrollerH:false 

   407         miniScrollerV:false 

   408         origin:nil

   409         corner:nil 

   410         in:nil

   411 

   412     "Created: 6.3.1997 / 18:06:22 / cg"

   413     "Modified: 6.3.1997 / 23:18:32 / cg"

   414 !

   415 

   416 for:aViewClass hasHorizontalScrollBar:hasH hasVerticalScrollBar:hasV miniScrollerH:miniH miniScrollerV:miniV 

   417     "return a new scrolling view scrolling an instance of aViewClass.

   418      The subview is created here.

   419      The view will have full scrollbars if the corresponding miniH/miniV

   420      is false, miniscrollers if true."

   421 

   422     |newView|

   423 

   424     aViewClass notNil ifTrue:[

   425 	newView := aViewClass new.

   426     ].

   427     ^ self

   428 	forView:newView

   429 	hasHorizontalScrollBar:hasH 

   430 	hasVerticalScrollBar:hasV 

   431 	miniScrollerH:miniH 

   432 	miniScrollerV:miniV 

   433 	origin:nil 

   434 	corner:nil 

   435 	in:nil

   436 

   437     "Created: 7.4.1997 / 19:00:14 / cg"

   438 !

   439 

   440 for:aViewClass hasHorizontalScrollBar:hasH hasVerticalScrollBar:hasV miniScrollerH:miniH miniScrollerV:miniV origin:org corner:corn in:aView

   441     "return a new scrolling view scrolling an instance of aViewClass.

   442      The subview is created here.

   443      The view will have full scrollbars if the corresponding miniH/miniV

   444      is false, miniscrollers if true."

   445 

   446     |newView|

   447 

   448     aViewClass notNil ifTrue:[

   449         newView := aViewClass new.

   450     ].

   451     ^ self

   452         forView:newView

   453         hasHorizontalScrollBar:hasH 

   454         hasVerticalScrollBar:hasV 

   455         miniScrollerH:miniH 

   456         miniScrollerV:miniV 

   457         origin:org 

   458         corner:corn 

   459         in:aView

   460 

   461     "

   462      |top scr|

   463 

   464      top := StandardSystemView extent:200@200.

   465      scr := ScrollableView for:nil

   466                  hasHorizontalScrollBar:true

   467                  hasVerticalScrollBar:true

   468                  miniScrollerH:false

   469                  miniScrollerV:false

   470                  origin:0.0@0.0

   471                  corner:1.0@1.0

   472                  in:top.

   473      top open

   474     "

   475 

   476     "Modified: 6.3.1997 / 18:36:01 / cg"

   477 !

   478 

   479 for:aViewClass in:aView

   480     "return a new scrolling view scrolling an instance of aViewClass.

   481      The subview is created here.

   482      The view will have full scrollbars."

   483 

   484     ^ self 

   485         for:aViewClass

   486         hasHorizontalScrollBar:self defaultHorizontalScrollable

   487         hasVerticalScrollBar:self defaultVerticalScrollable

   488         miniScrollerH:false 

   489         miniScrollerV:false 

   490         origin:nil

   491         corner:nil 

   492         in:aView

   493 

   494     "Modified: 6.3.1997 / 23:18:41 / cg"

   495 !

   496 

   497 for:aViewClass miniScroller:mini

   498     "return a new scrolling view scrolling an instance of aViewClass.

   499      The subview is created here.

   500      The view will have full scrollbars if mini is false, miniscrollers

   501      if true."

   502 

   503     ^ self 

   504         for:aViewClass

   505         hasHorizontalScrollBar:self defaultHorizontalScrollable

   506         hasVerticalScrollBar:self defaultVerticalScrollable

   507         miniScrollerH:mini 

   508         miniScrollerV:mini 

   509         origin:nil

   510         corner:nil 

   511         in:nil

   512 

   513     "Modified: 6.3.1997 / 23:18:45 / cg"

   514 !

   515 

   516 for:aViewClass miniScroller:mini in:aView

   517     "return a new scrolling view scrolling an instance of aViewClass.

   518      The subview is created here.

   519      The view will have full scrollbars if mini is false, miniscrollers

   520      if true."

   521 

   522     ^ self 

   523         for:aViewClass

   524         hasHorizontalScrollBar:self defaultHorizontalScrollable

   525         hasVerticalScrollBar:self defaultVerticalScrollable

   526         miniScrollerH:mini 

   527         miniScrollerV:mini 

   528         origin:nil

   529         corner:nil 

   530         in:aView

   531 

   532     "Modified: 6.3.1997 / 23:18:50 / cg"

   533 !

   534 

   535 for:aViewClass miniScroller:mini origin:org corner:corn in:aView

   536     "return a new scrolling view scrolling an instance of aViewClass.

   537      The subview is created here.

   538      The view will have full scrollbars if mini is false, miniscrollers

   539      if true."

   540 

   541     ^ self 

   542         for:aViewClass

   543         hasHorizontalScrollBar:self defaultHorizontalScrollable

   544         hasVerticalScrollBar:self defaultVerticalScrollable

   545         miniScrollerH:mini 

   546         miniScrollerV:mini 

   547         origin:org

   548         corner:corn 

   549         in:aView

   550 

   551     "Modified: 6.3.1997 / 23:18:53 / cg"

   552 !

   553 

   554 for:aViewClass miniScrollerH:miniH

   555     "return a new scrolling view scrolling an instance of aViewClass.

   556      The subview is created here.

   557      The view will have full scrollbars if miniH is false, 

   558      and a horizontal miniscroller if true."

   559 

   560      ^ self 

   561 	for:aViewClass

   562 	hasHorizontalScrollBar:true

   563 	hasVerticalScrollBar:true

   564 	miniScrollerH:miniH 

   565 	miniScrollerV:false

   566 	origin:nil

   567 	corner:nil 

   568 	in:nil

   569 

   570     "Modified: 6.3.1997 / 18:30:15 / cg"

   571 !

   572 

   573 for:aViewClass miniScrollerH:miniH in:aView

   574     "return a new scrolling view scrolling an instance of aViewClass.

   575      The subview is created here.

   576      The view will have full scrollbars if the corresponding miniH/miniV

   577      is false, miniscrollers if true."

   578 

   579      ^ self 

   580 	for:aViewClass

   581 	hasHorizontalScrollBar:true

   582 	hasVerticalScrollBar:true

   583 	miniScrollerH:miniH 

   584 	miniScrollerV:false

   585 	origin:nil

   586 	corner:nil 

   587 	in:aView

   588 

   589     "Modified: 6.3.1997 / 18:30:31 / cg"

   590 !

   591 

   592 for:aViewClass miniScrollerH:miniH miniScrollerV:miniV

   593     "return a new scrolling view scrolling an instance of aViewClass.

   594      The subview is created here.

   595      The view will have full scrollbars if the corresponding miniH/miniV

   596      is false, miniscrollers if true."

   597 

   598      ^ self 

   599 	for:aViewClass

   600 	hasHorizontalScrollBar:true

   601 	hasVerticalScrollBar:true

   602 	miniScrollerH:miniH 

   603 	miniScrollerV:miniV

   604 	origin:nil

   605 	corner:nil 

   606 	in:nil

   607 

   608     "Modified: 6.3.1997 / 18:30:47 / cg"

   609 !

   610 

   611 for:aViewClass miniScrollerH:miniH miniScrollerV:miniV in:aView

   612     "return a new scrolling view scrolling an instance of aViewClass.

   613      The subview is created here.

   614      The view will have full scrollbars if the corresponding miniH/miniV

   615      is false, miniscrollers if true."

   616 

   617      ^ self 

   618 	for:aViewClass

   619 	hasHorizontalScrollBar:true

   620 	hasVerticalScrollBar:true

   621 	miniScrollerH:miniH 

   622 	miniScrollerV:miniV

   623 	origin:nil

   624 	corner:nil 

   625 	in:aView

   626 

   627     "Modified: 6.3.1997 / 18:31:02 / cg"

   628 !

   629 

   630 for:aViewClass miniScrollerH:miniH miniScrollerV:miniV origin:org corner:corn in:aView

   631     "return a new scrolling view scrolling an instance of aViewClass.

   632      The subview is created here.

   633      The view will have full scrollbars if the corresponding miniH/miniV

   634      is false, miniscrollers if true."

   635 

   636      ^ self 

   637 	for:aViewClass

   638 	hasHorizontalScrollBar:true

   639 	hasVerticalScrollBar:true

   640 	miniScrollerH:miniH 

   641 	miniScrollerV:miniV

   642 	origin:org

   643 	corner:corn 

   644 	in:aView

   645 

   646     "Modified: 6.3.1997 / 18:31:17 / cg"

   647 !

   648 

   649 for:aViewClass miniScrollerH:miniH origin:org corner:corn in:aView

   650     "return a new scrolling view scrolling an instance of aViewClass.

   651      The subview is created here.

   652      The view will have a full horizontal scrollbar if miniH is false,

   653      a miniscroller if true."

   654 

   655      ^ self 

   656 	for:aViewClass

   657 	hasHorizontalScrollBar:true

   658 	hasVerticalScrollBar:true

   659 	miniScrollerH:miniH 

   660 	miniScrollerV:false

   661 	origin:org

   662 	corner:corn 

   663 	in:aView

   664 

   665     "Modified: 6.3.1997 / 18:31:28 / cg"

   666 !

   667 

   668 for:aViewClass miniScrollerV:miniV origin:org corner:corn in:aView

   669     "return a new scrolling view scrolling an instance of aViewClass.

   670      The subview is created here.

   671      The view will have a full vertical scrollbar if miniV is false,

   672      a miniscroller if true."

   673 

   674      ^ self 

   675 	for:aViewClass

   676 	hasHorizontalScrollBar:true

   677 	hasVerticalScrollBar:true

   678 	miniScrollerH:false 

   679 	miniScrollerV:miniV

   680 	origin:org

   681 	corner:corn 

   682 	in:aView

   683 

   684     "Modified: 6.3.1997 / 18:31:41 / cg"

   685 !

   686 

   687 for:aViewClass origin:org corner:corner in:aView

   688     "return a new scrolling view scrolling an instance of aViewClass.

   689      The subview is created here.

   690      The view will have full scrollbars."

   691 

   692      ^ self 

   693         for:aViewClass

   694         hasHorizontalScrollBar:self defaultHorizontalScrollable

   695         hasVerticalScrollBar:self defaultVerticalScrollable

   696         miniScrollerH:false 

   697         miniScrollerV:false

   698         origin:org

   699         corner:corner 

   700         in:aView

   701 

   702     "Modified: 6.3.1997 / 23:19:05 / cg"

   703 !

   704 

   705 forView:aView

   706     "return a new scrolling view scrolling aView.

   707      The view will have full scrollbars."

   708 

   709      ^ self 

   710         forView:aView

   711         hasHorizontalScrollBar:self defaultHorizontalScrollable

   712         hasVerticalScrollBar:self defaultVerticalScrollable

   713         miniScrollerH:false 

   714         miniScrollerV:false

   715         origin:nil

   716         corner:nil 

   717         in:nil

   718 

   719     "Modified: 6.3.1997 / 23:19:08 / cg"

   720 !

   721 

   722 forView:aScrolledView hasHorizontalScrollBar:hasH hasVerticalScrollBar:hasV miniScrollerH:miniH miniScrollerV:miniV origin:org corner:corn in:aView

   723     "return a new scrolling view scrolling an instance of aViewClass.

   724      The subview is created here.

   725      The view will have full scrollbars if the corresponding miniH/miniV

   726      is false, miniscrollers if true."

   727 

   728     |newView dev|

   729 

   730     aView notNil ifTrue:[

   731         dev := aView graphicsDevice

   732     ] ifFalse:[ 

   733         dev := Screen current

   734     ].

   735     newView := self basicNew device:dev.

   736     newView initialize.

   737     newView setupVertical:hasV mini:miniV horizontal:hasH mini:miniH.

   738 

   739     aScrolledView notNil ifTrue:[

   740         newView scrolledView:aScrolledView.

   741     ].

   742 

   743     org notNil ifTrue:[

   744         newView origin:org

   745     ].

   746     corn notNil ifTrue:[

   747         newView corner:corn

   748     ].

   749 

   750     aView notNil ifTrue:[

   751         aView addSubView:newView

   752     ].

   753     ^ newView

   754 

   755     "

   756      |top scr|

   757 

   758      top := StandardSystemView extent:200@200.

   759      scr := ScrollableView 

   760                  forView:(TextView new)

   761                  hasHorizontalScrollBar:true

   762                  hasVerticalScrollBar:true

   763                  miniScrollerH:false

   764                  miniScrollerV:false

   765                  origin:0.0@0.0

   766                  corner:1.0@1.0

   767                  in:top.

   768      top open

   769     "

   770     "

   771      |top scr|

   772 

   773      top := StandardSystemView extent:200@200.

   774      scr := ScrollableView 

   775                  forView:(TextView new)

   776                  hasHorizontalScrollBar:false

   777                  hasVerticalScrollBar:true

   778                  miniScrollerH:false

   779                  miniScrollerV:false

   780                  origin:0.0@0.0

   781                  corner:1.0@1.0

   782                  in:top.

   783      top open

   784     "

   785 

   786     "Modified: 6.3.1997 / 18:42:40 / cg"

   787     "Modified: 19.3.1997 / 15:32:51 / stefan"

   788 !

   789 

   790 forView:aView in:aSuperView

   791     "return a new scrolling view scrolling aView.

   792      The view will have full scrollbars."

   793 

   794      ^ self 

   795         forView:aView

   796         hasHorizontalScrollBar:self defaultHorizontalScrollable

   797         hasVerticalScrollBar:self defaultVerticalScrollable

   798         miniScrollerH:false 

   799         miniScrollerV:false

   800         origin:nil

   801         corner:nil 

   802         in:aSuperView

   803 

   804     "Modified: 6.3.1997 / 23:19:12 / cg"

   805 !

   806 

   807 forView:aView miniScrollerH:mini

   808     "return a new scrolling view scrolling aView.

   809      The view will have a full vertical scrollbar and a horizontal

   810      miniScroller if mini is true."

   811 

   812      ^ self 

   813 	forView:aView

   814 	hasHorizontalScrollBar:true

   815 	hasVerticalScrollBar:true

   816 	miniScrollerH:mini 

   817 	miniScrollerV:false

   818 	origin:nil

   819 	corner:nil 

   820 	in:nil

   821 

   822     "Modified: 6.3.1997 / 18:32:58 / cg"

   823 !

   824 

   825 forView:scrolledView miniScrollerH:miniH miniScrollerV:miniV in:aView

   826     "return a new scrolling view, scrolling aView.

   827      The view will have full scrollbars if the corresponding miniH/miniV

   828      is false, miniscrollers if true."

   829 

   830      ^ self 

   831 	forView:scrolledView

   832 	hasHorizontalScrollBar:true

   833 	hasVerticalScrollBar:true

   834 	miniScrollerH:miniH 

   835 	miniScrollerV:miniV

   836 	origin:nil

   837 	corner:nil 

   838 	in:aView

   839 

   840     "Modified: 6.3.1997 / 18:33:20 / cg"

   841 !

   842 

   843 in:aView

   844     "return a new scrolling view to be contained in aView.

   845      There is no slave view now - this has to be set later via

   846      the scrolledView: method.

   847      The view will have full scrollbars."

   848 

   849      ^ self 

   850         forView:nil

   851         hasHorizontalScrollBar:self defaultHorizontalScrollable

   852         hasVerticalScrollBar:self defaultVerticalScrollable

   853         miniScrollerH:false 

   854         miniScrollerV:false

   855         origin:nil

   856         corner:nil 

   857         in:aView

   858 

   859     "Modified: 6.3.1997 / 23:19:19 / cg"

   860 !

   861 

   862 miniScroller:mini

   863     "return a new scrolling view. The subview will be created later.

   864      The view will have full scrollbars if mini is false, 

   865      miniscrollers if true."

   866 

   867      ^ self 

   868         forView:nil

   869         hasHorizontalScrollBar:self defaultHorizontalScrollable

   870         hasVerticalScrollBar:self defaultVerticalScrollable

   871         miniScrollerH:mini 

   872         miniScrollerV:mini

   873         origin:nil

   874         corner:nil 

   875         in:nil

   876 

   877     "Modified: 6.3.1997 / 23:19:21 / cg"

   878 !

   879 

   880 miniScrollerH:miniH

   881     "return a new scrolling view. The subview will be created later.

   882      The view will have full scrollbars if miniH is false, 

   883      and a horizontal miniscroller if true."

   884 

   885      ^ self 

   886 	forView:nil

   887 	hasHorizontalScrollBar:true

   888 	hasVerticalScrollBar:true

   889 	miniScrollerH:miniH 

   890 	miniScrollerV:false

   891 	origin:nil

   892 	corner:nil 

   893 	in:nil

   894 

   895     "Modified: 6.3.1997 / 18:34:06 / cg"

   896 !

   897 

   898 miniScrollerH:miniH miniScrollerV:miniV

   899     "return a new scrolling view. The subview will be created later.

   900      The view will have full scrollbars if the corresponding miniH/miniV

   901      is false, miniscrollers if true."

   902 

   903      ^ self 

   904 	forView:nil

   905 	hasHorizontalScrollBar:true

   906 	hasVerticalScrollBar:true

   907 	miniScrollerH:miniH 

   908 	miniScrollerV:miniV

   909 	origin:nil

   910 	corner:nil 

   911 	in:nil

   912 

   913     "Modified: 6.3.1997 / 18:34:16 / cg"

   914 !

   915 

   916 new

   917     "return a new scrolling view.

   918      There is no slave view now - this has to be set later via

   919      the scrolledView: method.

   920      The view will have full scrollbars."

   921 

   922      ^ self in:nil

   923 

   924     "Modified: / 12.11.1998 / 14:55:54 / cg"

   925 ! !

   926 

   927 !ScrollableView class methodsFor:'defaults'!

   928 

   929 defaultHorizontalScrollable

   930     ^ false

   931 !

   932 

   933 defaultScrollBarPosition

   934     "return the default position of the scrollBar.

   935      (max be of interest to panels, to make the handlePosition alike)"

   936 

   937     <resource: #style (#'scrollBar.position')>

   938 

   939     ^ StyleSheet at:#'scrollBar.position' default:#left.

   940 

   941     "

   942      self defaultScrollBarPosition

   943     "

   944 

   945     "Modified: / 31.10.1997 / 12:58:15 / cg"

   946 !

   947 

   948 defaultVerticalScrollable

   949     ^ true

   950 !

   951 

   952 updateStyleCache

   953     "extract values from the styleSheet and cache them in class variables"

   954 

   955     <resource: #style (#'scrolledView.level' #'scrolledView.margin'

   956 		       #'scrolledView.borderWidth'

   957 		       #'scrollBar.spacing' #'scrollBar.level'

   958 		       #'scrollableView.level' #'scrollableView.backgroundColor' )>

   959 

   960     |defLevel defMargin defSpacing|

   961 

   962     StyleSheet is3D ifTrue:[

   963 	defLevel := -1.

   964 	defMargin := ViewSpacing // 2.

   965 	defSpacing := defMargin.

   966     ] ifFalse:[

   967 	defLevel := 0.

   968 	defMargin := 0.

   969 	defSpacing := 0

   970     ].

   971     DefaultScrolledViewLevel := StyleSheet at:#'scrolledView.level' default:defLevel.

   972     DefaultScrolledViewBorderWidth := StyleSheet at:#'scrolledView.borderWidth' default:nil.

   973     DefaultScrolledViewMargin := StyleSheet at:#'scrolledView.margin' default:defMargin.

   974     DefaultScrollBarSpacing := StyleSheet at:#'scrollBar.spacing' default:defSpacing.

   975     DefaultLevel := StyleSheet at:#'scrollableView.level' default:nil.

   976     DefaultScrollBarLevel := StyleSheet at:#'scrollBar.level' default:nil.

   977     MyDefaultViewBackgroundColor := StyleSheet at:#'scrollableView.backgroundColor' default:DefaultViewBackgroundColor.

   978 

   979     "

   980      self updateStyleCache

   981     "

   982 

   983     "Modified: / 31.10.1997 / 20:57:10 / cg"

   984 ! !

   985 

   986 !ScrollableView methodsFor:'accessing-behavior'!

   987 

   988 autoHideHorizontalScrollBar:aBoolean

   989     "set/clear the flag which controls if the horizontal scrollBar should

   990      be made invisible dynamically, if there is nothing to scroll

   991      (and shown if there is). 

   992      This flags setting is normally controlled by the styleSheet."

   993 

   994     hideHScrollBar := aBoolean.

   995 

   996     "Modified: 19.3.1997 / 16:28:42 / cg"

   997     "Created: 19.3.1997 / 17:24:39 / cg"

   998 !

   999 

  1000 autoHideScrollBars:aBoolean

  1001     "set/clear the flag which controls if scrollBars should

  1002      be made invisible dynamically, if there is nothing to scroll

  1003      (and shown if there is). 

  1004      This flags setting is normally controlled by the styleSheet."

  1005 

  1006     hideVScrollBar := hideHScrollBar := aBoolean.

  1007 

  1008     "Modified: 19.3.1997 / 16:28:42 / cg"

  1009     "Created: 19.3.1997 / 17:24:39 / cg"

  1010 !

  1011 

  1012 autoHideVerticalScrollBar:aBoolean

  1013     "set/clear the flag which controls if the vertical scrollBar should

  1014      be made invisible dynamically, if there is nothing to scroll

  1015      (and shown if there is). 

  1016      This flags setting is normally controlled by the styleSheet."

  1017 

  1018     hideVScrollBar := aBoolean.

  1019 

  1020     "Modified: 19.3.1997 / 16:28:42 / cg"

  1021     "Created: 19.3.1997 / 17:24:39 / cg"

  1022 ! !

  1023 

  1024 !ScrollableView methodsFor:'accessing-components'!

  1025 

  1026 horizontalScrollBar

  1027     "return the horizontal scrollbar (or nil, if there is none)"

  1028 

  1029 "/    hScrollBar isNil ifTrue:[

  1030 "/        self horizontalScrollable:true.

  1031 "/    ].

  1032     ^ hScrollBar

  1033 

  1034     "Created: / 6.3.1997 / 18:06:23 / cg"

  1035     "Modified: / 25.5.1998 / 12:53:58 / cg"

  1036 !

  1037 

  1038 removeSubView:aView

  1039     super removeSubView:aView.

  1040     aView == scrolledView ifTrue:[

  1041         scrolledView := nil

  1042     ].

  1043     aView == vScrollBar ifTrue:[

  1044         vScrollBar := nil

  1045     ].

  1046     aView == hScrollBar ifTrue:[

  1047         hScrollBar := nil

  1048     ].

  1049 

  1050 

  1051 

  1052 

  1053 !

  1054 

  1055 scrollBar

  1056     "return the vertical scrollbar (or nil, if there is none)"

  1057 

  1058 "/    vScrollBar isNil ifTrue:[

  1059 "/        self verticalScrollable:true.

  1060 "/    ].

  1061     ^ vScrollBar

  1062 

  1063     "Created: / 6.3.1997 / 18:06:23 / cg"

  1064     "Modified: / 25.5.1998 / 12:54:06 / cg"

  1065 !

  1066 

  1067 scrolledView

  1068     "return the scrolled view (or nil, if there is none)"

  1069 

  1070     ^ scrolledView

  1071 

  1072     "Modified: 6.3.1997 / 16:48:09 / cg"

  1073     "Created: 6.3.1997 / 18:06:23 / cg"

  1074 !

  1075 

  1076 scrolledView:aView

  1077     "set the view to scroll"

  1078 

  1079     scrolledView notNil ifTrue:[

  1080 	scrolledView removeDependent:self.

  1081 	scrolledView destroy.

  1082 	scrolledView := nil.

  1083     ].

  1084 

  1085     scrolledView := aView.

  1086 

  1087     super addSubViewFirst:aView.

  1088     scrolledView notNil ifTrue:[

  1089 	self setScrollActions.

  1090 

  1091 	realized ifTrue:[

  1092 	    self setupDimensionsConfigureScrolledView:true.

  1093 	    self sizeChanged:nil.

  1094 	    scrolledView realize

  1095 	].

  1096     ]

  1097 

  1098     "Modified: / 19.3.1997 / 15:32:37 / stefan"

  1099     "Modified: / 21.5.1998 / 00:48:57 / cg"

  1100 !

  1101 

  1102 verticalScrollBar

  1103     "return the vertical scrollbar (or nil, if there is none)"

  1104 

  1105 "/    vScrollBar isNil ifTrue:[

  1106 "/        self verticalScrollable:true.

  1107 "/    ].

  1108     ^ vScrollBar

  1109 

  1110     "Modified: 6.3.1997 / 16:59:24 / cg"

  1111     "Created: 6.3.1997 / 18:06:23 / cg"

  1112 !

  1113 

  1114 widget

  1115     "for ST80 compatibility (where a wrapper returns its wrapped

  1116      widget), return the scrolledView here"

  1117 

  1118     ^ scrolledView

  1119 

  1120     "Created: 20.6.1997 / 14:45:16 / cg"

  1121 ! !

  1122 

  1123 !ScrollableView methodsFor:'accessing-look'!

  1124 

  1125 horizontalMini:aBoolean

  1126     "control the horizontal scrollBar to be either a miniScroller,

  1127      or a full scrollBar."

  1128 

  1129     horizontalMini ~~ aBoolean ifTrue:[

  1130         horizontalMini := aBoolean.

  1131         (styleSheet at:#'scrollBar.neverMini' default:false) == true ifTrue:[

  1132             horizontalMini := false.

  1133         ].

  1134         self setupViews.

  1135         shown ifTrue:[