"

 COPYRIGHT (c) 1994 by AEG Industry Automation

 COPYRIGHT (c) 1994 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

SelectionInListView subclass:#SelectionInHierarchyView

	 instanceVariableNames:'itemList showConnectingLines'

	 classVariableNames:''

	 poolDictionaries:''

	 category:'Views-Text'

!

!SelectionInHierarchyView class methodsFor:'documentation'!

copyright 

"

 COPYRIGHT (c) 1994 by AEG Industry Automation

 COPYRIGHT (c) 1994 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

version

!

documentation

"

    somewhat like a SelectionInListView; but specialized for hierarchical (i.e. tree-like)

    lists and adds the functions to show/hide subtrees. 

    Requires SelectionInHierarchy as model and HierarchyNode (or compatible) list entries.

    See examples.

"

!

examples

"

    shows the tree of smalltalk classes:

      |top hierarchy hierarchyV scroller|

      hierarchy := SelectionInHierarchy new.

      hierarchy root:(HierarchyNode newAsTreeFromSmalltalkClass:Object).

      hierarchy setHideToChildren:true startingAt:hierarchy root.

      top := StandardSystemView new.

      top extent:300@300.

      hierarchyV := SelectionInHierarchyView new.

      hierarchyV model: hierarchy.

      top add:(ScrollableView forView:hierarchyV)

	  in:((0.0 @ 0.0 ) corner:( 1.0 @ 1.0)).

      top open.

    same, with nice connecting links:

      |top hierarchy hierarchyV scroller|

      hierarchy := SelectionInHierarchy new.

      hierarchy root:(HierarchyNode newAsTreeFromSmalltalkClass:Object).

      hierarchy setHideToChildren:true startingAt:hierarchy root.

      top := StandardSystemView new.

      top extent:300@300.

      hierarchyV := SelectionInHierarchyView new.

      hierarchyV showConnectingLines:true.

      hierarchyV model: hierarchy.

      top add:(ScrollableView forView:hierarchyV)

	  in:((0.0 @ 0.0 ) corner:( 1.0 @ 1.0)).

      top open.

"

! !

!SelectionInHierarchyView methodsFor:'event handling'!

buttonPress:button x:x y:y

    |oldSelection listLineNr|

    ((button == 1) or:[button == #select]) ifTrue:[

	enabled ifTrue:[

	    oldSelection := selection.

	    listLineNr := self visibleLineToListLine:(self visibleLineOfY:y).

	    (selectConditionBlock isNil or:[selectConditionBlock value:listLineNr]) ifTrue:[

		listLineNr notNil ifTrue: [

		    self selectWithoutScroll:listLineNr

		].

		((ignoreReselect not and:[selection notNil])

		 or:[selection ~= oldSelection]) ifTrue:[

		    "actionBlock notNil ifTrue:[actionBlock value:selection]."

		    "the ST-80 way of doing things"

		    model notNil ifTrue:[

			model perform:#selection: with:(selection)

		    ]

		].

		clickLine := listLineNr

	    ]

	]

    ] ifFalse:[

	super buttonPress:button x:x y:y

    ]

	"Modified: 10.10.94 / 17:13:38 / W.Olberding"

	"Modified: 08.11.94 / 15:38:43 / R.Sailer"!

selection: anIndex

	"Pass the selection along to the model."

	super selection:  anIndex.

	model selection:  anIndex.

	"Modified: 10.10.94 / 16:13:38 / W.Olberding"!

keyPress:key x:x y:y

    "a key was pressed - handle [-][+][*] here"

    (key == $-)    ifTrue: [^ model collapse]. 

    (key == $+)    ifTrue: [^ model expand]. 

    (key == $*)    ifTrue: [^ model expandAll]. 

    (key == $.)    ifTrue: [^ model collapseAll]. 

    super keyPress:key x:x y:y

	"Modified: 10.10.94 / 16:13:38 / W.Olberding"! !

!SelectionInHierarchyView methodsFor:'model access'!

model:aModel

    super model:aModel.

    self setNewList

!

getSelectionFromModel

      "Get the current list selection from model. "

    ^  model selection

	"Modified: 10.10.94 / 16:13:39 / W.Olberding"!

getListFromModel

      "Get list entries from model.

       Answer them as idented Text."

      | listOfNodes textList textLine treeLevels isLastOnLevel oldLevel |

	listOfNodes := model list.

	listOfNodes isNil ifTrue:[^ #()].

	showConnectingLines ifFalse:[

	    textList := listOfNodes collect: [ :aNode |

		textLine := ReadWriteStream on: String new.

		aNode level timesRepeat: [

		    textLine space; space.

		].

		textLine nextPutAll: aNode name.

		aNode isExpandable ifTrue: [

		    textLine nextPutAll: ' ...'.

		].

		textLine contents.

	    ].

	] ifTrue:[

	    isLastOnLevel:=Set new.

	    treeLevels:=Set new.

	    oldLevel:=0.

	    listOfNodes reverseDo: [ :aNode |

		(treeLevels includes:(aNode level)) ifFalse:[

		    isLastOnLevel add:aNode.

		    treeLevels add:(aNode level).

		].

		aNode level < oldLevel ifTrue:[

		    treeLevels remove:oldLevel.

		].

		oldLevel:=aNode level.

	    ].

	    treeLevels:=Set new.

	    oldLevel:=0.

	    textList := listOfNodes collect: [ :aNode |

		textLine := ReadWriteStream on: String new.

		1 to:((aNode level)-1) do: [ :l |

		    (treeLevels includes:l) ifTrue:[

			textLine space; nextPutAll:((Character value:25)printString); space.

		    ]ifFalse:[

			textLine space; space; space.

		    ]

		].

		treeLevels add:(aNode level).

		oldLevel:=aNode level.

		(aNode = (listOfNodes first)) ifFalse:[

		    textLine space.

		    (isLastOnLevel includes:aNode)ifTrue:[

			 textLine nextPutAll:((Character value:14)printString).

			 treeLevels remove:(aNode level).

		    ]ifFalse:[

			textLine nextPutAll:((Character value:21)printString).

		    ].

		    textLine nextPutAll:((Character value:18)printString).

		].

		aNode isExpandable ifTrue: [

		    textLine nextPutAll: '[+]'.

		]ifFalse:[

		    aNode isCollapsable ifTrue: [

		       textLine nextPutAll: '[-]'.

		   ]ifFalse:[textLine nextPutAll:((Character value:18)printString).].

		].

		textLine nextPutAll:' ', aNode name.

		textLine contents.

	    ].

	].

       ^textList

	"Modified: 10.10.94 / 16:13:39 / W.Olberding"

!

getListAttributes

      "get list attributes (selectable, disabled ...) from model)"

       ^Array new: 0.

	"Modified: 10.10.94 / 16:13:38 / W.Olberding"! !

!SelectionInHierarchyView methodsFor:'updating'!

update: aSymbol with:aParameter from:changedObject

      "Change my apperance according to the occurred change."

     aSymbol==#list 

	ifTrue: [^self setNewList].

     aSymbol==#selection 

	ifTrue: [^self selection: self getSelectionFromModel].

     aSymbol==#attributes 

	ifTrue: [].

	"Modified: 10.10.94 / 16:13:38 / W.Olberding"! !

!SelectionInHierarchyView methodsFor:'private'!

setNewList

	"Build a completely new hierarchy list."

       self setList: (self getListFromModel).

"/       self attributes: (self getListAttributes).

       self selection: (self getSelectionFromModel).

	"Modified: 10.10.94 / 17:13:38 / W.Olberding"

	"Modified: 08.11.94 / 15:28:03 / R.Sailer"! !

!SelectionInHierarchyView methodsFor:'initialization'!

initialize

    super initialize.

    showConnectingLines := true.

    self  doubleClickAction: 

	  [:selection | model doubleClickSelection: selection ].

	  "this will usualy initiate a hide/show operation"

	"Modified: 10.10.94 / 16:13:39 / W.Olberding"

!

showConnectingLines:aBoolean

    showConnectingLines := aBoolean

! !

!SelectionInHierarchyView methodsFor:'accessing'!

selectElement:anObject

    "select the element with same printString as the argument, anObject"

    |index|

    index:= 1.

    list notNil ifTrue:[

	list do:[:each|

	  ((each withoutSpaces) = (anObject printString)) ifTrue:[

	      self selection: index.

	      ^index

	  ].

	  index:= index + 1.

	]. 

    ].

    ^index

	"Modified: 10.10.94 / 16:13:39 / W.Olberding"! !