Object subclass:#DataSetLabel

	instanceVariableNames:'label selector argument adjust font fgColor bgColor

	classVariableNames:''

	poolDictionaries:''

	category:'Views-DataSet'

!

!DataSetLabel methodsFor:'accessing colors'!

backgroundColor

    "returns the background color or nil

    "

    ^ bgColor

!

foregroundColor

    "returns the foreground color or nil

    "

    ^ fgColor

! !

!DataSetLabel methodsFor:'accessing dimensions'!

preferredHeight

    "returns my preferred height

    "

    ^ preferredHeight

!

preferredWidth

    "returns my preferred width

    "

    ^ preferredWidth

! !

!DataSetLabel methodsFor:'actions'!

sendClickMsgTo:aReceiver

    "inform the receiver of a button release notification

    "

    (aReceiver notNil and:[selector notNil]) ifTrue:[

        selector numArgs ~~ 0 ifTrue:[

            aReceiver perform:selector with:argument

        ] ifFalse:[

            aReceiver perform:selector

        ]

    ]

! !

!DataSetLabel methodsFor:'drawing'!

redrawX:xLeft w:width h:height inset:inset on:aGC

    "redraw the label; the background is cleared and the paint is set

    "

    |y0 margin x y ascent gcFont|

    label isNil ifTrue:[ ^ self ].

    gcFont := aGC font.

    font notNil ifTrue:[

        aGC font:font.

        ascent := font ascent

    ] ifFalse:[

        ascent := gcFont ascent

    ].

    y0 := height - preferredHeight // 2.

    label do:[:aLabel|

        adjust == #left ifTrue:[

            x := xLeft + inset.

        ] ifFalse:[

            x := width - (aLabel widthOn:aGC).

            adjust == #right ifTrue:[x := x - inset]

                            ifFalse:[x := x // 2].

            x := xLeft + x.

        ].

        y := aLabel isImageOrForm ifTrue:[y0] ifFalse:[y0 + ascent].

        aLabel displayOn:aGC x:x y:y.

        y0 := y0 + (aLabel heightOn:aGC)

    ].

    font notNil ifTrue:[aGC font:gcFont].       "/ restore font

! !

!DataSetLabel methodsFor:'instance creation'!

description:aDescription builder:aBuilder on:aGC

    |device gcFont|

    label    := self resolveLabelFromDescription:aDescription withBuilder:aBuilder.

    selector := aDescription labelActionSelector.

    argument := (aDescription labelActionArgument) ? label.

    adjust   := (aDescription labelAlignment) ? #left.

    device   := aGC device.

    fgColor  := aDescription labelForegroundColor.

    bgColor  := aDescription labelBackgroundColor.

    fgColor notNil ifTrue:[ fgColor := fgColor onDevice:device ].

    bgColor notNil ifTrue:[ bgColor := bgColor onDevice:device ].

    preferredHeight := preferredWidth := 0.

    (label isNil or:[label perform:#isEmpty ifNotUnderstood:false]) ifTrue:[

        label := nil.

      ^ self

    ].

    (font := aDescription labelFont) notNil ifTrue:[

        (gcFont := aGC font) = font ifTrue:[

            font := nil

        ] ifFalse:[

            aGC font:(font := font onDevice:device)

        ]

    ].

    (label isSequenceable and:[label isString not]) ifFalse:[

        label := Array with:label

    ].

    label := label collect:[:el||lbl|

        lbl := self label:el on:device.

        preferredWidth  := (lbl widthOn:aGC) max:preferredWidth.

        preferredHeight := preferredHeight + (lbl heightOn:aGC).

        lbl

    ].

    font notNil ifTrue:[aGC font:gcFont].       "/ restore font

! !

!DataSetLabel methodsFor:'private'!

label:aLabel on:aDevice

    "returns registered label on a device

    "

    |lbl img|

    aLabel isNil ifTrue:[^ ''].

    aLabel isString ifFalse:[

        aLabel isImageOrForm ifTrue:[

            aLabel device ~~ aDevice ifTrue:[lbl := aLabel copy on:aDevice]

                                    ifFalse:[lbl := aLabel].

            lbl isImage ifTrue:[

                lbl clearMaskedPixels

            ].

            ^ lbl

        ].

        aLabel class == LabelAndIcon ifTrue:[

            lbl := aLabel on:aDevice.

            (img := lbl image) isImage ifTrue:[img clearMaskedPixels].

            (img := lbl icon)  isImage ifTrue:[img clearMaskedPixels].

            ^ lbl

        ]

    ].

    ^ aLabel

!

resolveLabelFromDescription:aDescription withBuilder:aBuilder

    |label appl size lbl|

    aBuilder isNil ifTrue:[

        ^ aDescription rawLabel        

    ].

    label := aDescription label.

    label isString ifTrue:[

        aDescription labelIsImage ifTrue:[

            (    aBuilder isEditing

             or:[(label := aBuilder labelFor:(label asSymbol)) isNil]

            ) ifTrue:[

                ^ aDescription class defaultIcon

            ].

            ^ label

        ].

        aDescription translateLabel == true ifTrue:[

            (    aBuilder isEditing

             or:[(appl := aBuilder application) isNil]

            ) ifTrue:[

                ^ label

            ].

            (    (lbl := appl resources string:label) isNil

             or:[(lbl := aBuilder aspectAt:(label asSymbol)) isNil]

            ) ifFalse:[

                label := lbl

            ]

        ]

    ].

    label isSequenceable ifTrue:[

        (size := label size) == 0 ifTrue:[              "/ empty label

            ^ nil

        ].

        (size == 1 and:[label isString not]) ifTrue:[   "/ collection with one entry

            ^ label at:1                                "/ not a string object

        ].

    ].

    ^ label

! !

!DataSetLabel methodsFor:'queries'!

isSelectable

    "returns true if the item is selectable; a valid selector

     to notify the receiver for a release button event exists

    "

    ^ selector notNil

! !

!DataSetLabel class methodsFor:'documentation'!

version

! !