"

 COPYRIGHT (c) 1997 by Claus Gittinger / eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

View subclass:#DSVColumnView

	instanceVariableNames:'editValue editView multipleSelectOk selectedColIndex

		selectedRowIndex rowHeight columnDescriptors viewOrigin colorMap

		lockRowIndex rowIfAbsentBlock columnHolder registererImages list

		fgColor canFit separatorSize listSizeChanged sizeOfListChanged

		beDependentOfRows bgColor hgLgFgColor hgLgBgColor actionBlock

		doubleClickActionBlock separatorLightColor separatorDarkColor

		verticalSpacing horizontalSpacing toggleOnButton toggleOffButton

		rowSelectorButton comboViewButton clickPosition'

	classVariableNames:'DefaultForegroundColor DefaultBackgroundColor

		DefaultHilightForegroundColor DefaultHilightBackgroundColor

		DefaultSeparatorDarkColor DefaultSeparatorLightColor

		DefaultRowSelectorForm'

	poolDictionaries:''

	category:'Views-DataSet'

!

!DSVColumnView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by Claus Gittinger / eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    implements a scrollable selection view based on rows and columns

    [Instance variables:]

        editValue               <Model>                 current editing model

        editView                <View>                  current editing component

        selectedColIndex        <Integer>               selected column index or 0

        selectedRowIndex        <Integer>               selected row index or 0

        rowHeight               <Integer>               maximum height of any row

        columnDescriptors       <SequancableCollection> list of column descriptors

        list                    <SequancableCollection> list of rows

        fgColor                 <Color>                 foreground color

        registererImages        <IdentityDictionary>    list of images registered on the device

        beDependentOfRows       <Coolean>               keep rows dependent; on default is disabled.

                                                        in case of enabled a row can raise a change

                                                        notification whithout a parameter which

                                                        will force a redraw of the row or the

                                                        readSelector of the column which will

                                                        redraw the cell in the row only.

    [author:]

        Claus Atzkern

    [see also:]

        DataSetColumnSpec

        DataSetColumn

        DataSetView

"

! !

!DSVColumnView class methodsFor:'defaults'!

defaultRowSelectorForm

    DefaultRowSelectorForm isNil ifTrue:[

        DefaultRowSelectorForm := Form

                          width:8

                         height:11

                      fromArray:#[2r01000000

                                  2r01100000

                                  2r01110000

                                  2r01111000

                                  2r01111100

                                  2r01111110

                                  2r01111100

                                  2r01111000

                                  2r01110000

                                  2r01100000

                                  2r01000000]

                             on:Display.

        DefaultRowSelectorForm := DefaultRowSelectorForm asImage.

    ].

    ^ DefaultRowSelectorForm

!

horizontalSpacing

    ^ 4

!

updateStyleCache

    "extract values from the styleSheet and cache them in class variables

    "

    <resource: #style (#textForegroundColor #'scrollableView.backgroundColor'

                       #'selection.hilightForegroundColor'

                       #'selection.hilightBackgroundColor'   )>

    DefaultForegroundColor        := StyleSheet colorAt:'textForegroundColor' default:(Color black).

    DefaultBackgroundColor        := StyleSheet at:'scrollableView.backgroundColor' default:DefaultViewBackgroundColor.

    DefaultHilightForegroundColor := StyleSheet colorAt:'selection.hilightForegroundColor' default:DefaultForegroundColor.

    DefaultHilightBackgroundColor := StyleSheet colorAt:'selection.hilightBackgroundColor' default:(Color veryLightGrey).

    DefaultSeparatorDarkColor     := DefaultShadowColor ? (Color grayPercent:40).

    DefaultSeparatorLightColor    := DefaultLightColor  ? (Color grayPercent:75).

"

self updateStyleCache.

"

    "Modified: / 26.10.1997 / 17:09:07 / cg"

!

verticalSpacing

    ^ 2

! !

!DSVColumnView methodsFor:'accessing'!

action:aOneArgAction

    "set the action block to be performed on select

    "

    actionBlock := aOneArgAction

!

beDependentOfRows

    "make myself dependent of any row; in this case any change notification

     raised by a row is catched and the cell identified by the 'readSelector'

     is redrawn. In case of a nil readSelector, the whole raw is redrawn.

        -> row changed:'what'

     On default the attribute is set to true (enabled).

    "

    ^ beDependentOfRows

!

beDependentOfRows:aBool

    "make myself dependent of any row; in this case any change notification

     raised by a row is catched and the cell identified by the 'readSelector'

     is redrawn. In case of a nil readSelector, the whole raw is redrawn.

        -> row changed:'what'

     On default the attribute is set to true (enabled).

    "

    aBool ~~ beDependentOfRows ifTrue:[

        beDependentOfRows := aBool.

        self size ~~ 0 ifTrue:[

            list do:[:aRow| aRow notNil ifTrue:[

                beDependentOfRows ifTrue:[aRow addDependent:self]

                                 ifFalse:[aRow removeDependent:self]

                ]

            ]

        ]

    ]

!

doubleClickAction:aOneArgAction

    "set the action block to be performed on doubleclick

    "

    doubleClickActionBlock := aOneArgAction

!

multipleSelectOk

    "allow/disallow multiple row selections; the default is false

    "

    ^ multipleSelectOk

!

multipleSelectOk:aState

    "allow/disallow multiple row selections; the default is false

    "

    aState == multipleSelectOk ifFalse:[

        multipleSelectOk := aState.

        self deselect

    ]

!

rowIfAbsent:aOneArgAction

    "set the action block to be performed on each 'nil' entry into the

     list. The argument to the block is the index into the list. The

     block returns the row which is put to the list

    "

    rowIfAbsentBlock := aOneArgAction

! !

!DSVColumnView methodsFor:'accessing buttons'!

comboViewButton

    "returns the bitmap of a comboView button

    "

    comboViewButton isNil ifTrue:[

        comboViewButton := (Image fromFile:'dsv_comboList.xpm') on:device.

        comboViewButton clearMaskedPixels.

    ].

    ^ comboViewButton

!

rowSelectorButton

    "returns the bitmap of a selected row

    "

    rowSelectorButton isNil ifTrue:[

        rowSelectorButton := (self class defaultRowSelectorForm) on:device

    ].

    ^ rowSelectorButton

!

toggleOffButton

    "returns the bitmap of a disabled toggle

    "

    toggleOffButton isNil ifTrue:[

        toggleOffButton := (Image fromFile:'dsv_checkTgOff.xpm') on:device.

        toggleOffButton clearMaskedPixels.

    ].

    ^ toggleOffButton

!

toggleOnButton

    "returns the bitmap of an enabled toggle

    "

    toggleOnButton isNil ifTrue:[

        toggleOnButton := (Image fromFile:'dsv_checkTgOn.xpm') on:device.

        toggleOnButton clearMaskedPixels.

    ].

    ^ toggleOnButton

! !

!DSVColumnView methodsFor:'accessing columns'!

columnAt:anIndex

    "returns the column at an index

    "

    ^ columnDescriptors at:anIndex

!

columnDescriptors:colDesc

    "set the columnDescriptors

    "

    |id sz|

    sz := colDesc size.

    (sz == 0 or:[selectedColIndex ~~ 0]) ifTrue:[       "/ cell selected

        self deselect                                   "/ remove selection

    ].

    sz ~~ 0 ifTrue:[

        id := 0.

        columnDescriptors := colDesc collect:[:aCol|

            id := id + 1.

            DataSetColumn new on:self description:aCol columnNumber:id.

        ]

    ] ifFalse:[

        columnDescriptors := #()

    ].

    canFit := (columnDescriptors findFirst:[:aCol|aCol canResize]) ~~ 0.

    preferredExtent := nil.

    sizeOfListChanged := true.

    self preferredExtentChanged.

    shown ifTrue:[

        self fitColumns ifFalse:[

            self invalidate.

            self contentsChanged.

        ]

    ].

    sizeOfListChanged := false.

    self changed:#sizeOfColumns.

!

firstColumn

    "returns the first column

    "

    ^ columnDescriptors at:1

!

lastColumn

    "returns the last column

    "

    ^ columnDescriptors last

! !

!DSVColumnView methodsFor:'accessing mvc'!

columnHolder

    ^ columnHolder

!

columnHolder:aValueHolder

    |columns|

    columnHolder notNil ifTrue:[

        columnHolder removeDependent:self

    ].

    (columnHolder := aValueHolder) notNil ifTrue:[

        columnHolder addDependent:self.

        columns := columnHolder value.

        columns notNil ifTrue:[

            self columnDescriptors:columns

        ]

    ].

! !

!DSVColumnView methodsFor:'accessing rows'!

at:aRowNr

    "return the row at an index, aRowNr

    "

    |row|

    (row := list at:aRowNr) isNil ifTrue:[

        lockRowIndex := aRowNr.

        (row := rowIfAbsentBlock value:aRowNr) notNil ifTrue:[

            list at:aRowNr put:row.

            beDependentOfRows ifTrue:[row addDependent:self].

        ].

        lockRowIndex := 0

    ].

    ^ row

!

at:aRowNr ifAbsent:exceptionBlock

    "return the row at a aRowNr. If the index is invalid, return the

     result of evaluating the exceptionblock

    "

    (aRowNr between:1 and:self size) ifTrue:[

        ^ self at:aRowNr

    ].

    ^ exceptionBlock value

!

at:aRowNr put:aRow

    "change the row at an index. The added row is returned

    "

    |row|

    lockRowIndex == aRowNr ifTrue:[

        ^ self

    ].

    row := list at:aRowNr.

    row == aRow ifTrue:[

        ^ self

    ].

    beDependentOfRows ifTrue:[

        (row := list at:aRowNr) notNil ifTrue:[

            row removeDependent:self

        ]

    ].

    list at:aRowNr put:aRow.

    aRow notNil ifTrue:[                "/ free list

        beDependentOfRows ifTrue:[

            aRow addDependent:self

        ].

        self redrawRowAt:aRowNr

    ].

    ^ aRow.

!

first

    "return the first row

    "

    ^ self at:1

!

identityIndexOfRow:aRow

    "returns index of a row or 0

    "

    (list size ~~ 0 and:[aRow notNil]) ifTrue:[

        ^ list identityIndexOf:aRow

    ].

    ^ 0

!

last

    "return the last row

    "

    ^ self at:(self size)

!

list

    "get the list of rows

    "

    ^ list

!

list:aList

    "set the list of rows

    "

    "/ remove selection without redraw

    editValue notNil ifTrue:[

        editValue removeDependent:self.

        editValue := nil

    ].

    editView notNil ifTrue:[

        editView destroy.

        editView := nil.

    ].

    selectedColIndex := 0.

    selectedRowIndex := multipleSelectOk ifTrue:[nil] ifFalse:[0].

    shown ifFalse:[

        preferredExtent := nil

    ] ifTrue:[

        aList size ~~ 0 ifTrue:[  "/ otherwise keep old values

            self columnsDo:[:aCol| aCol invalidate ].

            preferredExtent := nil.

        ]

    ].

    beDependentOfRows ifTrue:[ self beDependentOfRows:false ].

    aList size ~~ 0 ifTrue:[

        list := OrderedCollection new:(aList size).

        beDependentOfRows ifTrue:[self beDependentOfRows:true].

    ] ifFalse:[

        list := nil

    ].

    shown ifTrue:[

        self recomputeHeightOfContents.

        list size ~~ 0 ifTrue:[

            self fitColumns ifTrue:[^ self ].

        ].

        self invalidate.

        sizeOfListChanged := true.

        self contentsChanged.

        sizeOfListChanged := false.

    ].

! !

!DSVColumnView methodsFor:'accessing visibility'!

backgroundColor

    "get the background color of the rows

    "

    ^ bgColor

!

backgroundColor:aColor

    "set the background color of the rows

    "