"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

"{ NameSpace: Smalltalk }"

TextCollector subclass:#TerminalView

	instanceVariableNames:'inStream outStream readerProcess shellPid kbdSequences

		escapeSequenceTree currentSequence kbdMap escapeLeadingChars

		numberOfColumns numberOfLines shellTerminateAction rangeStartLine

		rangeEndLine state savedCursor shellCommand shellDirectory

		filterStream recorderStream localEcho translateNLToCRNL

		inputTranslateCRToNL inputTranslateCRToCRNL

		inputTranslateBackspaceToDelete autoWrapFlag masterWindow

		alternateKeypadMode noColors sizeOfOutstandingInputToBeProcessed

		lineEditMode lineBuffer lineBufferCursorPosition

		lineBufferHistory lineBufferHistoryPosition

		lineBufferHistoryChanged maxHistorySize doUTF ignoreOutput

		sendControlKeys lastSelectedLineBufferHistoryPosition inputIsUTF8

		outputIsUTF8 signalControlKeys filterOnly'

	classVariableNames:'Debug DebugKeyboard DefaultMaxHistorySize'

	poolDictionaries:''

	category:'Views-TerminalViews'

!

!TerminalView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    I provide terminal functionality, by interpreting data

    arriving from some stream (typically connected to a command interpreter 

    via a pty, or another system via a modem) and sending my keyboard data to it.

    I am abstract providing general functionality -

    concrete terminal characteristics (i.e. escape sequences) are defined 

    by concrete subclasses (see VT52TerminalView, VT100TerminalView).

    Concrete applications are: 

        consoles (VT100TerminalView),

        telnet-views (see TelnetTool)

        editor wrappers (if you like emacs/vi)

        gdb terminal subviews (see GDBApplication)

    Although my class protocol includes common startup protocol

    (to open a terminalView with a shell or on the output of a command),

    I can be used as a widget within an application (modem software).

    Implementation notice: 

        some of my pty functionality and handling is being extracted to

        the separate TerminalSession class (which allows communicating with a

        program without having its output displayed).   

        So currently, some ugly code duplication is present.

        Once stable, code will be refactored.   

        For now, as terminalView is being used in

        some of our critical applications, this refactoring has not yet been done.

    Line Editing mode:

     Cursor keys allow for th user to navigate through previously entered input (as in cmd.exe and bash).

     Special: <SHIFT>-cursor up goes back to the previously selected history line.

     (not to the previous line).

     For example, if the user types:

        a <RETURN>

        b <RETURN>

        c <RETURN>

        <CURSOR-UP> -> shows 'c'

        <CURSOR-UP> -> shows 'b'

        <CURSOR-UP> -> shows 'a'

        123 <RETURN> -> resends 'a123'

        <SHIFT-CURSOR-UP> -> shows 'a' again which is the previously selected history line(not a123)

        <CURSOR-DOWN> -> shows 'b'

        <RETURN> -> sends 'b'

    [author:]

        Claus Gittinger

    [instance variables:]

        inStream                stream where keyboard input is

                                sent to (connected to shells or commands input)

        outStream               stream where the output of the

                                shell or command arrives

                                (read here and displayed in the view)

        readerProcess           process which reads commands    

                                output and sends it to the view

        lineEditMode            if on, do readLine-alike input history and editing

        signalControlKeys       if on, CTRL-C sends an interrupt (for Windows)

    [class variables]:

        Debug := true           trace incoming characters

        Debug := false           

        DebugKeyboard := true   trace outgoing characters

        DebugKeyboard := false 

    [start with:]

        VT52TerminalView open

        VT100TerminalView open

        VT52TerminalView openShell

        VT100TerminalView openShell

        VT100TerminalView openOnCommand:'ls -l'

        VT100TerminalView openOnCommand:'dir'

    [see also:]

        TelNetTool

"

!

examples

"

  start a shell in the current directory:

                                                                [exBegin]

    TerminalView openShell

                                                                [exEnd]

  start a shell in a given directory:

                                                                [exBegin]

    TerminalView openShellIn:(OperatingSystem getHomeDirectory)

                                                                [exEnd]

  start another program current directory:

                                                                [exBegin]

    TerminalView openOnCommand:'ls -l'

                                                                [exEnd]

  start another program in some given directory:

                                                                [exBegin]

    TerminalView openOnCommand:'ls' in:'/etc'

                                                                [exEnd]

  specify how to react when the shell terminates:

                                                                [exBegin]

    TerminalView openOnCommand:'ls' in:'/etc' onExit:[:vt | vt topView destroy]

    TerminalView openOnCommand:'ls' in:'/etc' onExit:[:vt | Dialog information:'finished'. vt topView destroy]

                                                                [exEnd]

  special low level usage: no shell command, interact with the user myself

  (i.e. read the user's input, and intepret it myself):

                                                                [exBegin]

    |terminal in out inputLine|

    in := InternalPipeStream new.

    out := InternalPipeStream new.

    terminal := TerminalView openOnInput:in output:out.

    terminal localEcho:true.

    terminal inputTranslateCRToNL:true.

    terminal translateNLToCRNL:true.

    out nextPutLine:'Hello world - please type at me:'.

    [

        inputLine := in nextLine asString.

        inputLine ~= '#exit' ifTrue:[

            out nextPutLine:(Compiler evaluate:inputLine) printString.

        ].

        (inputLine = '#exit') or:[ terminal isOpen not ]

    ] whileFalse.

    terminal topView destroy.

                                                                [exEnd]

"

! !

!TerminalView class methodsFor:'initialization'!

initialize

    Debug := DebugKeyboard := false.

    DefaultMaxHistorySize := 1000.

    "

     self initialize

    "

! !

!TerminalView class methodsFor:'defaults'!

defaultIcon

    "This resource specification was automatically generated

     by the ImageEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the ImageEditor may not be able to read the specification."

    "

     self defaultIcon inspect

     ImageEditor openOnClass:self andSelector:#defaultIcon

     Icon flushCachedIcons

    "

    <resource: #image>

    ^Icon

        constantNamed:'TerminalView defaultIcon'

        ifAbsentPut:[(Depth4Image new) width:48; height:36; bits:(ByteArray fromPackedString:'

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@CL3L3L3L3L3L3L3L3L0@@@@@@@@@@@@@5UUUUUUUUUUUUUUUUUS@@@@@@@@@@@@MUUUUUUUUUUUUUUUUUUU

DP@@@@@@@@@@MUQDQDQDQDQDQDQDQEUUDP@@@@@@@@@@MUQDQDQDQDQDQDQDQDUUDQ@@@@@@@@@@MUQBIBQBP"H$P$QDQDUUDQ@@@@@@@@@@MUQDQDQDQDQD

QDQDQDUUDQD@@@@@@@@@MUQBH"P"P"IDQDQDQDUUDQD@@@@@@@@@MUQDQDQDQDQDQDQDQDUUDQDP@@@@@@@@MUQBH"H"H"P"H"QDQDUUDQDP@@@@@@@@MUQD

QDQDQDQDQDQDQDUUDQDP@@@@@@@@MUQBH$H"IBIDH"QDQDUUDQDP@@@@@@@@MUQDQDQDQDQDQDQDQDUUDQDP@@@@@@@@MUQBQDQDQDQDQDQDQDUUDQDP@@@@

@@@@MUQDQDQDQDQDQDQDQDUUDQDP@@@@@@@@MUQBH"P$H"P$QDQDQDUUDQDP@@@@@@@@MUQDQDQDQDQDQDQDQDUUDQDP@@@@@@@@MUQBP"H$QDQDQDQDQDUU

DQDP@@@@@@@@MUUDQDQDQDQDQDQDQEUUDQD@@@@@@@@@MUUUUUUUUUUUUUUUUUUUDQ@@@@@@@@@@@5UUUUUUUUUUUUUUUUUQDP@@@@@@@@@@@@@QDQDQDQDQ

DQDQDQDSL1D@@@@@@@@@@@@CL3L3L3L3L3L3L3L3LQD@@@@@@@@@@@@QDQDQDQDQDQDQDQDQDQD@@@@@@@@@@AUUUUUUUUUUUUUUUUUUDQD3@3@@@@@@@AUU

UUUUUUUUUU@@@@AUDQD@L@L@@@@@DQDQDQDQDQDQDQDQDQUUDQ@@@C@@@@@AUUUUUUUUUUUUUUUUUQDQD@@@@0@@@@@UUUUUUUUUUUUUUUUUTQ@@@@DQDQ@@

@@@UT"H"H"H"H"H"H%UUTQ@@DQDSL1@@@@EUUUUUUUUUUUUUUUUUDP@AEUTQL1@@@AURH"H"H"H"H"H"IUUQD@@AUUUSLP@@@UUUUUUUUUUUUUUUUUTQ@@@A

L3L1D@@@@QDQDQDQDQDQDQDQDQDP@@@ADQDQ@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@') ; colorMapFromArray:#[0 0 0 80 78 80 255 255 255 140 140 140 40 58 10 196 194 190]; mask:((ImageMask new) width:48; height:36; bits:(ByteArray fromPackedString:'

@@@@@@@@@O???>@@@_????@@@?????0@@?????0@@?????8@@?????8@@?????<@@?????<@@?????>@@?????>@@?????>@@?????>@@?????>@@?????>@

@?????>@@?????>@@?????>@@?????>@@?????<@@?????8@@_????0@@C????<@@A????<@@C????<@@O?????X@O????<$@?????8HA????? PC????8G8

C????8?8G????1?8O????!!?0_????A? _???>A?@@@@@@@@@') ; yourself); yourself]

!

defaultNumberOfColumns

    ^ 80

    "Created: / 4.8.1998 / 17:48:18 / cg"

    "Modified: / 4.8.1998 / 17:48:31 / cg"

!

defaultNumberOfLines

    ^ 25

    "Created: / 4.8.1998 / 17:48:18 / cg"

    "Modified: / 4.8.1998 / 17:48:31 / cg"

! !

!TerminalView class methodsFor:'opening'!

open

    ^ self openShell

    "

     VT100TerminalView open

     VT52TerminalView open

     TerminalView open

    "

    "Created: / 10.6.1998 / 15:47:25 / cg"

    "Modified: / 9.7.1998 / 17:55:37 / cg"

!

openDummy

    "for testing purposes only - opens a dummy tty-view, which simply

     echoes whatever is typed in"

    |in vt52|

    ForwardingStream isNil ifTrue:[ Smalltalk loadPackage:'stx:goodies' ].

    vt52 := self new.

    in := ForwardingStream on:''.

    in fwdStream:vt52.

    vt52 inStream:in.

    vt52 outStream:in.

    vt52 open

    "

     self openDummy

    "

!

openOnCommand:aCommandString

    "start a command on a pseudo-TTY, open a terminalView on it

     (i.e. this is kind of an xterm)"

    ^ self openOnCommand:aCommandString onExit:[]

    "

     VT100TerminalView openOnCommand:'ls -l'

    "

    "Created: / 9.7.1998 / 17:50:53 / cg"

    "Modified: / 9.7.1998 / 17:57:41 / cg"

!

openOnCommand:aCommand in:aDirectory

    "start a shell on a pseudo-TTY, open a terminalView on it

     (i.e. this is kind of an xterm)"

    ^ self openOnCommand:aCommand in:aDirectory onExit:[]

    "

     TerminalView openOnCommand:'ls'

     TerminalView openOnCommand:'ls' in:'/etc'

    "

!

openOnCommand:aCommandString in:aDirectory onExit:exitBlockOrNil

    "start a command on a pseudo-TTY, open a terminalView on its output

     (i.e. this is kind of an xterm).

     When the command finishes, evaluate aBlock."

    ^ self 

        openWithAction: [:vt | vt startCommand:aCommandString in:aDirectory ]

        onExit: exitBlockOrNil.

    "

     VT100TerminalView openOnCommand:'ls -l' in:'/etc' onExit:[]

     VT100TerminalView openOnCommand:'ls -l' in:'/etc' onExit:[:vt | vt topView destroy]

     VT100TerminalView openOnCommand:'ls -l' in:'/etc' onExit:[:vt | Dialog information:'Shell terminated'. vt topView destroy ]

    "

    "Created: / 9.7.1998 / 17:54:34 / cg"

    "Modified: / 4.8.1998 / 17:49:02 / cg"

!

openOnCommand:aCommandString onExit:aBlock

    "start a command on a pseudo-TTY, open a terminalView on its output

     (i.e. this is kind of an xterm).

     When the command finishes, evaluate aBlock."

    ^ self openOnCommand:aCommandString in:nil onExit:aBlock

    "

     VT100TerminalView 

        openOnCommand:'ls -lR' 

        onExit:[:vt | 

            Dialog information:'Press OK to close'.

            vt topView close.

        ].

    "

!

openOnInput:inStream output:outStream

    "open a terminalView on the given streams (which are typically some

     kind of socket or pty). 

     Keys pressed are sent to inStream, text appearing

     from outStream is displayed in the terminal view.

     This can be used to implement things like rlogin

     or telnet views (if connected to a modem, a com-program can also be

     implemented this way)."

    |top vt|

    top := StandardSystemView new.

    vt := self openOnInput:inStream output:outStream in:top.

    vt masterWindow:top.

    top extent:(vt preferredExtent).

    top label:'shell'.

    top iconLabel:'shell'.

    top icon:(self defaultIcon).

    top open.

    ^ vt

    "Modified: / 5.5.1999 / 17:25:59 / cg"

!

openOnInput:inStream output:outStream in:aView

    "open a terminalView on the given streams 

     (which are typically some kind of socket or pty). 

     Keys pressed are sent to inStream, text appearing

     from outStream is displayed in the terminal view.

     This can be used to implement things like rlogin

     or telnet views (if connected to a modem, a com-program can also be

     implemented this way)."

    |scr vt|

    scr := ScrollableView for:self in:aView.

    scr origin:0.0@0.0 corner:1.0@1.0.

    vt := scr scrolledView.

    vt inStream:inStream.

    vt outStream:outStream.

    vt startReaderProcessWhenVisible.

    ^ scr

    "Modified: / 5.5.1999 / 17:25:59 / cg"

!

openShell

    "start a shell on a pseudo-TTY, open a terminalView on it

     (i.e. this is kind of an xterm)"

    ^ self openShellIn:nil

    "

     VT100TerminalView openShell

    "

    "Modified: / 21.7.1998 / 18:24:55 / cg"

!

openShellIn:aDirectory

    "start a shell on a pseudo-TTY, open a terminalView on it

     (i.e. this is kind of an xterm)"

    ^ self openWithAction:[:vt | vt startShellIn:aDirectory]

    "

     TerminalView openShellIn:'/etc'

     VT52TerminalView openShellIn:'/etc'

     VT100TerminalView openShellIn:'/etc'

    "

    "Created: / 20.7.1998 / 18:28:15 / cg"

    "Modified: / 5.5.1999 / 17:27:10 / cg"

!

openShellIn:aDirectory onExit:exitAction

    "start a shell on a pseudo-TTY, open a terminalView on it

     (i.e. this is kind of an xterm)"

    ^ self openWithAction:[:vt | vt startShellIn:aDirectory] onExit:exitAction

    "

     TerminalView openShellIn:'/etc' onExit:[ Dialog information:'Shell terminated' ]

    "

!

openWithAction:setupAction

    "open a terminalView, let it start its command via setupAction, 

     which gets the instantiated terminalView as argument."

    ^ self openWithAction:setupAction onExit:[:vt | vt topView destroy]

    "

     TerminalView openWithAction:[:vt | vt startShellIn:'/etc']

     TerminalView openWithAction:[:vt | vt startCommand:'ls -l' in:'/etc'.  vt shellTerminateAction:[].]

    "

!

openWithAction:setupAction onExit:exitBlockOrNil

    "open a terminalView, let it start its command via setupAction, 

     which gets the instantiated terminalView as argument.

     The default exitAction is to destroy the topView."

    | top scr vt lbl|

    lbl := OperatingSystem isUNIXlike ifTrue:['shell'] ifFalse:['dos'].

    top := StandardSystemView new.

    scr := HVScrollableView for:self in:top.

    scr origin:0.0@0.0 corner:1.0@1.0.

    vt := scr scrolledView.

    exitBlockOrNil isNil ifTrue:[

        vt shellTerminateAction:[ top destroy ]

    ] ifFalse:[        

        vt shellTerminateAction:[

            top label:(lbl,' - terminated').

            exitBlockOrNil valueWithOptionalArgument:vt.

        ].

    ].

    vt masterWindow: top.

    top extent:(scr preferredExtent).

    top label:lbl.

    top iconLabel:lbl.

    top icon:(self defaultIcon).

    top open.

    setupAction value:vt.

    ^ vt

    "

     TerminalView openWithAction:[:vt | vt startShellIn:'/etc']

     TerminalView openWithAction:[:vt | vt startCommand:'ls -l' in:'/etc'.  vt shellTerminateAction:[].]