View subclass:#ComboView

	instanceVariableNames:'field pullDownButton list'

	classVariableNames:''

	poolDictionaries:''

	category:'Views-Interactors'

!

!ComboView  class methodsFor:'documentation'!

documentation

"

    A ComboView combines some field (typically an enterField or Label)

    with a drop down list of default inputs;

    ComboView is abstract, providing protocol common to ComboBoxView and

    ComboListView. See documentation & examples there.

"

!

examples

"

     |top b|

     top := StandardSystemView new.

     top extent:(300 @ 200).

     b := ComboBoxView in:top.

     b origin:(0.0 @ 0.0) corner:(1.0 @ 0.0).

     b bottomInset:(b preferredExtent y negated).

     b list:#('hello' 'world' 'this' 'is' 'st/x').

     top open.

  model operation:

     |model top b|

     model := 'foo' asValue.

     top := StandardSystemView new.

     top extent:(300 @ 200).

     b := ComboBoxView in:top.

     b origin:(0.0 @ 0.0) corner:(1.0 @ 0.0).

     b bottomInset:(b preferredExtent y negated).

     b list:#('hello' 'world' 'this' 'is' 'st/x').

     b model:model.

     top openModal.

     Transcript showCR:('comboBox''s value: ' , model value).

  in a dialog:

     |model1 model2 dialog b|

     model1 := 'foo' asValue.

     model2 := 'bar' asValue.

     dialog := Dialog new.

     (dialog addTextLabel:'ComboBox example:') adjust:#left.

     dialog addVerticalSpace.

     (b := dialog addComboBoxOn:model1 tabable:true).

     b list:#('fee' 'foe' 'foo').

     dialog addVerticalSpace.

     (b := dialog addComboBoxOn:model2 tabable:true).

     b list:#('bar' 'baz' 'baloo').

     dialog addVerticalSpace.

     dialog addOkButton.

     dialog open.

     Transcript showCR:('1st comboBox''s value: ' , model1 value).

     Transcript showCR:('2nd comboBox''s value: ' , model2 value).

"

! !

!ComboView  class methodsFor:'defaults'!

buttonForm

    |form|

    form  := Form fromFile:'ComboDn_win.xbm'.

    ^ form on:Display

! !

!ComboView methodsFor:'accessing-components'!

menuButton

    "return the menuButton component"

    ^ pullDownButton

    "Created: 28.2.1996 / 15:03:14 / cg"

! !

!ComboView methodsFor:'accessing-contents'!

contents

    ^ field model value

    "Created: 14.5.1996 / 13:05:16 / cg"

    "Modified: 14.5.1996 / 13:07:02 / cg"

!

contents:something

    |m|

    (m := field model) notNil ifTrue:[

        m value:something

    ]

    "Created: 14.5.1996 / 13:05:33 / cg"

    "Modified: 15.7.1996 / 13:16:24 / cg"

!

list:aList

    list := aList.

    (list notNil and:[list notEmpty]) ifTrue:[

        pullDownButton controller enable

    ] ifFalse:[

        pullDownButton controller disable

    ].

    "Modified: 9.2.1996 / 00:51:56 / cg"

    "Created: 28.2.1996 / 15:03:14 / cg"

! !

!ComboView methodsFor:'accessing-mvc'!

model:aModel

    super model:aModel.

    self getListFromModel.

    self getValueFromModel.

    "Created: 15.7.1996 / 12:23:39 / cg"

    "Modified: 15.7.1996 / 12:26:09 / cg"

!

update:something with:aParameter from:changedObject

    changedObject == model ifTrue:[

        self getListFromModel.

        self getValueFromModel.

    ].

    super update:something with:aParameter from:changedObject

    "Created: 15.7.1996 / 12:26:49 / cg"

! !

!ComboView methodsFor:'initialization'!

initialize

    |ext|

    super initialize.

    self initializeField.

    field origin:0.0@0.0 corner:1.0@1.0.

    pullDownButton := Toggle in:self.

    pullDownButton label:(self class buttonForm).

    pullDownButton showLamp:false.

    pullDownButton activeLevel == pullDownButton passiveLevel ifTrue:[

        pullDownButton activeLevel:0.

    ].

    ext := pullDownButton preferredExtent.

    pullDownButton origin:1.0@0.0 corner:1.0@1.0.

    pullDownButton disable.

    pullDownButton pressAction:[self pullMenu].

    self height:field preferredExtent y + ViewSpacing.

    "

     |b|

     b := ComboBoxView new.

     b list:#('hello' 'world' 'this' 'is' 'st/x').

     b open

    "

    "Created: 28.2.1996 / 15:03:17 / cg"

! !

!ComboView methodsFor:'message delegation'!

doesNotUnderstand:aMessage

    (field respondsTo:aMessage selector) ifTrue:[

        ^ aMessage sendTo:field

    ].

    ^ super doesNotUnderstand:aMessage

    "Created: 28.2.1996 / 15:03:17 / cg"

    "Modified: 28.2.1996 / 15:06:09 / cg"

!

respondsTo:aSymbol

    ^ (field respondsTo:aSymbol) or:[super respondsTo:aSymbol]

    "Created: 2.5.1996 / 16:57:34 / stefan"

! !

!ComboView methodsFor:'private'!

getListFromModel

    model notNil ifTrue:[

        (model respondsTo:#list) ifTrue:[

            self list:(model list)

        ]

    ].

    "Created: 15.7.1996 / 12:22:56 / cg"

    "Modified: 15.7.1996 / 12:24:58 / cg"

!

getValueFromModel

    "Modified: 15.7.1996 / 12:28:59 / cg"

! !

!ComboView methodsFor:'queries'!

preferredExtent

    |pref1 pref2 m mPrefX|

    list isNil ifTrue:[

        mPrefX := 0

    ] ifFalse:[

        m := MenuView labels:list.

        mPrefX := m preferredExtent x.

    ].

    pref1 := field preferredExtent.

    pref2 := pullDownButton preferredExtent.

    ^ ((pref1 x + pref2 x) max:mPrefX) @ (pref1 y max:pref2 y)

    "Created: 28.2.1996 / 15:03:17 / cg"

    "Modified: 28.2.1996 / 15:06:15 / cg"

! !

!ComboView methodsFor:'user interaction'!

entryChanged:what

    field contents:what.

    field accept.

    pullDownButton turnOff.

    "Created: 28.2.1996 / 15:03:17 / cg"

    "Modified: 28.2.1996 / 15:06:24 / cg"

!

pullMenu

    |m org|

    self getListFromModel.

    (list notNil and:[list notEmpty]) ifTrue:[

        m := PopUpMenu

                    labels:list

                    selectors:#entryChanged:

                    args:list

                    receiver:self.

        m menuView resize.

        m menuView width:(self width).

        m menuView sizeFixed:true.

        m hideOnRelease:false.

        org := device translatePoint:(0 @ self height) 

                                from:(self id)

                                  to:(device rootView id).

        m showAt:org.

    ].

    pullDownButton turnOff.

    "Created: 28.2.1996 / 15:03:18 / cg"

    "Modified: 15.7.1996 / 12:23:06 / cg"

! !

!ComboView  class methodsFor:'documentation'!

version

! !