"

 COPYRIGHT (c) 1997 by Claus Gittinger / eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

Object subclass:#DataSetColumn

	instanceVariableNames:'columnNumber dataSet width description buttonExtent shownValue

		rendererType backgroundColor rowSeparatorSelector

		showColSeparator showRowSeparator foregroundColor fgSelector

		bgSelector columnAlignment label readSelector containsText

		numArgsToReadSelector numArgsToFgSelector numArgsToBgSelector

		columnAdaptor descWidth descMinWidth

		numberOfRowsProbedForColumnSize'

	classVariableNames:''

	poolDictionaries:''

	category:'Views-DataSet'

!

!DataSetColumn class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by Claus Gittinger / eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    represent one single column description of a DataSetView

    [Instance variables:]

        columnNumber    <Integer>               sequence number (into list of columns)

        dataSet         <DSVColumnView>         the view it belongs to

        width           <Integer>               width of column

        description     <DataSetColumnSpec>     the column description

        buttonExtent    <Point>                 extent of drawable form

        rendererType    <Type>                  renderer type (cached value from

                                                the column specification).

        backgroundColor <Color or nil>          background color of all cells or nil

                                                (nil: use default background color).

        foregroundColor <Color or nil>          foreground color of all cells or nil

                                                (nil: use default foreground color).

        fgSelector      <Selector or nil>       access specific foreground color for

                                                a cell

        bgSelector      <Selector or nil>       access specific background color for

                                                a cell

        columnAlignment <Symbol>                align text/icon #left #right or #center

                                                in row (on default: #left).

        label           <label/icon or nil>     label resolved by the builder shown

                                                in the column description field.

        readSelector    <Symbol>                cached readSelector (from the spec)

        numArgsToReadSelector <Integer>         number of arguments to the readSelector

        columnAdaptor   <nil or any>            if non-nil, that one is asked (via

                                                read-writeSelectors to extract a column

                                                from a row object.

                                                If nil, the row object is used itself.

        showColSeparator <Boolean>              true: vertical separators are enabled;

                                                separator between columns

        showRowSeparator <Boolean>              true: horizontal separators are enabled;

                                                separator between rows

        rowSeparatorSelector <Selector or nil>  access specific showRowSeparator state

                                                for a cell

        numberOfRowsProbedForColumnSize         the number of rows which are queries

                                <Integer>       in order to compute the columns width.

                                                (for scrollBar/col width computation)

                                                Notice, if its expensive to fetch rows

                                                (dataBase apps), this should be small.

                                                Default:15

    [author:]

        Claus Atzkern

    [see also:]

        DataSetColumnSpec

        DSVColumnView

        DataSetView

"

! !

!DataSetColumn methodsFor:'accessing'!

at:aRowNr

    "get the value of the raw at an index, aRowNr

    "

    ^ self extractColFromRow:(dataSet at:aRowNr).

!

at:aRowNr put:something

    "set the value of the raw at an index, aRowNr

    "

    |row newRow|

    row := dataSet at:aRowNr.

    newRow := self storeCol:something inRow:row.

    newRow ~~ row ifTrue:[

        dataSet listAt:aRowNr put:newRow.

    ]

    "Modified: / 7.8.1998 / 22:17:27 / cg"

!

columnAdaptor

    ^ columnAdaptor

!

columnAdaptor:anAdapter

    columnAdaptor := anAdapter.

!

description

    "returns the column description

    "

    ^ description

!

label

    "get the label assigned to the column

    "

    ^ label

!

rendererType

    "returns my renderer type

    "

    ^ rendererType

! !

!DataSetColumn methodsFor:'accessing-colors'!

backgroundColor

    "returns the background color or nil

    "

    ^ backgroundColor == dataSet backgroundColor ifTrue:[nil]

                                                ifFalse:[backgroundColor]

!

backgroundColorAt:aRowNr

    "returns the background color for a row at list index a rowNr

    "

    bgSelector notNil ifTrue:[

        ^ self backgroundColorFor:(dataSet at:aRowNr) at:aRowNr

    ].

    ^ backgroundColor

!

backgroundColorFor:aRow at:aRowNr

    "returns the background color for a row at list index a rowNr

    "

    |bg|

    bgSelector notNil ifTrue:[

        columnAdaptor notNil ifTrue:[

            numArgsToBgSelector == 3 ifTrue:[

                bg := columnAdaptor perform:bgSelector with:aRow with:aRowNr with:columnNumber

            ] ifFalse:[

                numArgsToBgSelector == 2 ifTrue:[

                    bg := columnAdaptor perform:bgSelector with:aRow with:aRowNr

                ] ifFalse:[

                    bg := columnAdaptor perform:bgSelector with:aRow

                ]

            ].

        ] ifFalse:[

            numArgsToBgSelector == 0 ifTrue:[

                bg := aRow perform:bgSelector

            ] ifFalse:[

                bg := aRow perform:bgSelector with:aRowNr

            ].

        ].

        bg notNil ifTrue:[

            (bg isColor or:[bg isImageOrForm]) ifTrue:[

                ^ bg

            ].

            self halt:'unexpected bg (not color or image)'.

        ]

    ].

    ^ backgroundColor

!

foregroundColor

    "returns the foreground color or nil

    "

    ^ foregroundColor == dataSet foregroundColor ifTrue:[nil]

                                                ifFalse:[foregroundColor]

!

foregroundColorFor:aRow at:aRowNr

    "returns the foreground color for a row at list index a rowNr

    "

    |fg|

    fgSelector notNil ifTrue:[

        columnAdaptor notNil ifTrue:[

            numArgsToFgSelector == 3 ifTrue:[

                fg := columnAdaptor perform:fgSelector with:aRow with:aRowNr with:columnNumber

            ] ifFalse:[

                numArgsToFgSelector == 2 ifTrue:[

                    fg := columnAdaptor perform:fgSelector with:aRow with:aRowNr

                ] ifFalse:[

                    fg := columnAdaptor perform:fgSelector with:aRow

                ]

            ].

        ] ifFalse:[

            numArgsToFgSelector == 0 ifTrue:[

                fg := aRow perform:fgSelector

            ] ifFalse:[

                fg := aRow perform:fgSelector with:aRowNr

            ].

        ].

        fg notNil ifTrue:[

            (fg isColor or:[fg isImageOrForm]) ifTrue:[

                ^ fg

            ].

            self halt:'unexpected fg (not color or image)'.

        ]

    ].

    ^ foregroundColor

! !

!DataSetColumn methodsFor:'accessing-dimension'!

minWidth

    "get the minimum width required by the column

    "

    descMinWidth notNil ifTrue:[

        ^ descMinWidth

    ].

    width := nil.

  ^ self width

!

minimumRequiredWidth

    "returns the minimum required width

    "

    |minWidth|

    descMinWidth notNil ifTrue:[

        minWidth := DSVLabelView tabSpacing max:2.

      ^ minWidth // 2 + minWidth

    ].

    minWidth := dataSet separatorSize + (2 * dataSet horizontalSpacing).

  ^ minWidth + label preferredWidth.

!

setDescWidth:aWidth

    "set a fixed width

    "

    descMinWidth := 1.

    descMinWidth := width := descWidth := self minimumRequiredWidth max:aWidth.

!

width

    "returns the width in pixels

     Warning: 

        only the first numberOfRowsProbedForColumnSize are probed,

        in case the access is expensive (dataBase apps)

     If the descriptor defines a width, that is used, and the items

     are not probed at all."

    |max  "{ Class:SmallInteger }"

     lsz  "{ Class:SmallInteger }"|

    width notNil ifTrue:[^ width].              "/ already computed

    descMinWidth notNil ifTrue:[

        width := descMinWidth.

      ^ width

    ].

    (descWidth ~~ 0 and:[descWidth isLimitedPrecisionReal not]) ifTrue:[

        width := descMinWidth := descWidth.

      ^ width

    ].

    width := description minWidth max:(label preferredWidth).

    descWidth isLimitedPrecisionReal ifTrue:[

        width := width max:(descWidth * dataSet width) rounded.

      ^ width

    ].

    containsText ifTrue:[

        "/ take maximum numberOfRowsProbedForColumnSize entries to calculate the width;

        "/ can be resized later if neccessary

        lsz := dataSet size.

        max := lsz min:numberOfRowsProbedForColumnSize.

        max ~~ 0 ifTrue:[

            1 to:max do:[:i|

                width := width max:(self widthOfLabel:(shownValue value:(dataSet at:i)))

            ].

            width := width max:(self widthOfLabel:(shownValue value:(dataSet at:lsz)))

        ].

        description editorType ~~ #None ifTrue:[

            width := width + (dataSet font widthOn:dataSet device)

        ].

    ] ifFalse:[

        max := 1

    ].

    width := width + buttonExtent x + dataSet separatorSize + (2 * dataSet horizontalSpacing).

    max ~~ 0 ifTrue:[

        descMinWidth := width.

        description usePreferredWidth ifTrue:[

            descWidth := width

        ]

    ].

  ^ width

    "Modified: / 25.2.2000 / 14:29:16 / cg"

! !

!DataSetColumn methodsFor:'drawing'!

drawLabel:aLabel atX:xLeft y:yTop

    "redraw label

    "

    |x space prevClip mustUndoClip|

    space := dataSet horizontalSpacing.

    columnAlignment == #left ifTrue:[

        x  := xLeft + space.

    ] ifFalse:[

        x := width - (aLabel widthOn:dataSet).

        columnAlignment == #right ifTrue:[x := x - space]

                                 ifFalse:[x := x // 2].

"/ cg: old code (did not right-align if string is larger than width

"/        x := xLeft + (x max:0).

        "/ new code: always right-align.

        x := xLeft + x.

        "/ must clip left, if string is too large

        x < xLeft ifTrue:[

            "/ must clip ...

            prevClip := dataSet clippingRectangleOrNil.

            mustUndoClip := true.

            dataSet clippingRectangle:(Rectangle 

                                left:xLeft top:yTop 

                                width:width height:(aLabel heightOn:dataSet)).

        ].

    ].

    aLabel isImageOrForm ifTrue:[

        aLabel displayOn:dataSet x:x y:yTop.

    ] ifFalse:[

        aLabel displayOn:dataSet x:x y:(yTop + dataSet rowFontAscent)

    ].

    mustUndoClip == true ifTrue:[

        dataSet clippingRectangle:prevClip    

    ].

!

drawLabelsAtX:xLeft y:yTop h:h from:start to:stop

    "redraw labels from start to stop

    "

    |fg bg label row isSel

     y       "{ Class:SmallInteger }"

     yT      "{ Class:SmallInteger }"

     x       "{ Class:SmallInteger }"

     hspace  "{ Class:SmallInteger }"

     ascent  "{ Class:SmallInteger }"

     lblHg   "{ Class:SmallInteger }"

    |

    yT := yTop.

    ascent := dataSet rowFontAscent.

    hspace := dataSet horizontalSpacing.

    start to:stop do:[:anIndex|

        row := dataSet at:anIndex.

        y := yT.

        x := xLeft.

     "/ GET BACKGROUND AND FOREGROUND-COLOR

     "/ ===================================

        isSel := dataSet isSelected:anIndex inColumn:columnNumber.

        isSel ifTrue:[

            (      description editorType ~~ #None

              and:[dataSet selectedColIndex == columnNumber]

            ) ifTrue:[

                isSel := false

            ]

        ].

        (isSel and:[description showSelectionHighLighted]) ifTrue:[

            "/ SHOW SELECTED( MUST REDRAW BACKGROUND )

            "/ =======================================

            fg := dataSet hgLgFgColor.

            bg := dataSet hgLgBgColor.

            dataSet paint:bg.

            dataSet fillRectangleX:x y:y width:width height:h.

        ] ifFalse:[

            bgSelector notNil ifTrue:[

                "/ MUST REDRAW BACKGROUND

                "/ ======================

                bg := self backgroundColorFor:row at:anIndex.

                bg ~~ backgroundColor ifTrue:[

                    bg := dataSet colorOnDevice:bg

                ].

                dataSet paint:bg.

                dataSet fillRectangleX:x y:y width:width height:h.

            ] ifFalse:[

                bg := backgroundColor

            ].

            fg := self foregroundColorFor:row at:anIndex.

            fg ~~ foregroundColor ifTrue:[

                fg := dataSet colorOnDevice:fg

            ].

        ].

     "/ GET AND DRAW LABEL

     "/ ==================

        rendererType == #rowSelector ifTrue:[

            isSel ifTrue:[

                label := dataSet rowSelectorForm.

                x  := x + hspace.

            ] ifFalse:[

                label := nil

            ]

        ] ifFalse:[

            (isSel and:[dataSet hasOpenEditor]) ifTrue:[

                label := nil

            ]  ifFalse:[

                label := shownValue value:row

            ]

        ].

        label notNil ifTrue:[

            "/ care for a dark-colored label,

            "/ with a dark selection-bg color