"

 COPYRIGHT (c) 1997 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

Object subclass:#DataSetLabel

	instanceVariableNames:'label selector argument adjust font fgColor bgColor

		preferredHeight preferredWidth'

	classVariableNames:''

	poolDictionaries:''

	category:'Views-DataSet'

!

!DataSetLabel class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

! !

!DataSetLabel methodsFor:'accessing-colors'!

backgroundColor

    "returns the background color or nil

    "

    ^ bgColor

!

backgroundColor:aColor

    "set the background color or nil

    "

    bgColor := aColor

!

foregroundColor

    "returns the foreground color or nil

    "

    ^ fgColor

!

foregroundColor:aColor

    "set the foreground color or nil

    "

    fgColor := aColor

! !

!DataSetLabel methodsFor:'accessing-dimensions'!

preferredHeight

    "returns my preferred height

    "

    ^ preferredHeight

!

preferredWidth

    "returns my preferred width

    "

    ^ preferredWidth

! !

!DataSetLabel methodsFor:'actions'!

sendClickMsgTo:aReceiver

    "inform the receiver of a button release notification

    "

    (aReceiver notNil and:[selector notNil]) ifTrue:[

        aReceiver perform:selector withOptionalArgument:argument

    ]

! !

!DataSetLabel methodsFor:'drawing'!

redrawX:xLeft w:width h:height inset:inset on:aGC

    "redraw the label; the background is cleared and the paint is set

    "

    |y0 x y ascent gcFont labelWidth 

     shownLabel prevClip mustUndoClip

     netWidth|

    label isNil ifTrue:[ ^ self ].

    gcFont := aGC font.

    font notNil ifTrue:[

        aGC font:font.

        ascent := font ascent

    ] ifFalse:[

        ascent := gcFont ascent

    ].

    y0 := height - preferredHeight // 2.

    netWidth := width-inset-inset.

    label do:[:aLabel|

        shownLabel := aLabel.

        mustUndoClip := false.

        labelWidth := shownLabel widthOn:aGC.

        labelWidth > netWidth ifTrue:[

            shownLabel := DataSetColumn shortenedStringFor:aLabel on:aGC maxWidth:netWidth.

            labelWidth := shownLabel widthOn:aGC.

        ].

        adjust == #left ifTrue:[

            x := xLeft + inset.

        ] ifFalse:[

            x := width - labelWidth.

            adjust == #right ifTrue:[x := x - inset]

                            ifFalse:[x := x // 2].

            x := xLeft + x.

           "/ cg: must clip left, if string is too large

            x < xLeft ifTrue:[

                "/ must clip ...

                prevClip := aGC clippingRectangleOrNil.

                mustUndoClip := true.

                aGC clippingRectangle:(Rectangle 

                                    left:xLeft top:y0 

                                    width:width height:height).

            ].

        ].

        "/ y := shownLabel isImageOrForm ifTrue:[y0] ifFalse:[y0 + ascent].

        "/ y := shownLabel isString ifTrue:[y0 + ascent] ifFalse:[y0].

        shownLabel displayOn:aGC x:x y:y0 + (shownLabel ascentOn:aGC).

        y0 := y0 + (shownLabel heightOn:aGC).

        mustUndoClip == true ifTrue:[

            aGC clippingRectangle:prevClip

        ].

    ].

    font notNil ifTrue:[

        aGC font:gcFont     "/ restore font

    ].       

! !

!DataSetLabel methodsFor:'instance creation'!

description:aDescription builder:aBuilder on:aGC

    |device gcFont|

    label           := self resolveLabelFromDescription:aDescription withBuilder:aBuilder.

    selector        := aDescription  labelActionSelector.

    argument        := (aDescription labelActionArgument) ? label.

    adjust          := (aDescription labelAlignment) ? #left.

    device          := aGC device.

    fgColor         := aDescription labelForegroundColor.

    bgColor         := aDescription labelBackgroundColor.

    fgColor notNil ifTrue:[ fgColor := fgColor onDevice:device ].

    bgColor notNil ifTrue:[ bgColor := bgColor onDevice:device ].

    preferredHeight := preferredWidth := 0.

    (label isNil or:[label perform:#isEmpty ifNotUnderstood:false]) ifTrue:[

        label := nil.

      ^ self

    ].

    (font := aDescription labelFont) notNil ifTrue:[

        (gcFont := aGC font) = font ifTrue:[

            font := nil

        ] ifFalse:[

            aGC font:(font := font onDevice:device)

        ]

    ].

    (label isSequenceable and:[label isString not]) ifFalse:[

        label := Array with:label

    ].

    label := label collect:[:el||lbl|

        lbl := self label:el on:device.

        preferredWidth  := (lbl widthOn:aGC) max:preferredWidth.

        preferredHeight := preferredHeight + (lbl heightOn:aGC).

        lbl

    ].

    font notNil ifTrue:[aGC font:gcFont].       "/ restore font

! !

!DataSetLabel methodsFor:'private'!

label:aLabel on:aDevice

    "returns registered label on a device

    "

    |lbl img|

    aLabel isNil ifTrue:[^ ''].

    aLabel isString ifFalse:[

        aLabel isImageOrForm ifTrue:[

            aLabel device ~~ aDevice ifTrue:[

                lbl := aLabel copy onDevice:aDevice

            ] ifFalse:[

                lbl := aLabel

            ].

            lbl isImage ifTrue:[

                lbl clearMaskedPixels

            ].

            ^ lbl

        ].

        aLabel class == LabelAndIcon ifTrue:[

            lbl := aLabel onDevice:aDevice.

            (img := lbl image) isImage ifTrue:[img clearMaskedPixels].

            (img := lbl icon)  isImage ifTrue:[img clearMaskedPixels].

            ^ lbl

        ]

    ].

    ^ aLabel

!

resolveLabelFromDescription:aDescription withBuilder:aBuilder

    |label appl size lbl|

    aBuilder isNil ifTrue:[

        ^ aDescription rawLabel        

    ].

    label := aDescription label.

    label isString ifTrue:[

        aDescription labelIsImage ifTrue:[

            (    aBuilder isEditing

             or:[(label := aBuilder labelFor:(label asSymbol)) isNil]

            ) ifTrue:[

                ^ aDescription class defaultIcon

            ].

            ^ label

        ].

        aDescription translateLabel == true ifTrue:[

            (    aBuilder isEditing

             or:[(appl := aBuilder application) isNil]

            ) ifTrue:[

                ^ label

            ].

"/ cg: the old code below did it in the wrong order ...

            (    (lbl := aBuilder aspectAt:(label asSymbol)) notNil

             or:[ (lbl := appl resources string:label) notNil]

            ) ifTrue:

"/            (    (lbl := appl resources string:label) isNil

"/             or:[(lbl := aBuilder aspectAt:(label asSymbol)) isNil]

"/            ) 

"/            ifFalse:

            [

                label := lbl

            ]

        ]

    ].

    label isSequenceable ifTrue:[

        (size := label size) == 0 ifTrue:[              "/ empty label

            ^ nil

        ].

        (size == 1 and:[label isString not]) ifTrue:[   "/ collection with one entry

            ^ label at:1                                "/ not a string object

        ].

    ].

    ^ label

! !

!DataSetLabel methodsFor:'queries'!

hasSeparator

    |l|

    label size == 1 ifTrue:[

"/        ^ (label at:1) ~= 'Alarm'

        ^ (label at:1) ~= 'Area'

    ].

    ^ true

!

isSelectable

    "returns true if the item is selectable; a valid selector

     to notify the receiver for a release button event exists

    "

    ^ selector notNil

! !

!DataSetLabel class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libwidg2/DataSetLabel.st,v 1.17 2004-04-07 08:39:01 werner Exp $'

! !