"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

ImageView subclass:#ImageEditView

	instanceVariableNames:'magnification colors magnifiedImage colorPanel pathName enhance

		antiAlias'

	classVariableNames:''

	poolDictionaries:''

	category:'Views-Misc'

!

!ImageEditView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This View will eventually be able to edit bitmap images.

    For now, it is not.

    [author:]

        Claus Gittinger

    [see also:]

        Image Form

    [start with:]

        ImageEditView openOn:'bitmaps/gifImages/garfield.gif'

        ImageEditView openOnImage:(Image fromFile:'bitmaps/gifImages/garfield.gif')

"

! !

!ImageEditView class methodsFor:'startup'!

openOn:aFileName

    "startup an image editor on an image read from a file"

    |editView fn dir|

    editView := super openOn:aFileName.

    dir := (fn := aFileName asFilename) directory.

    dir exists ifTrue:[

        editView pathName:(fn pathName).

    ].

    ^ editView

    "

     ImageEditView openOn:'bitmaps/gifImages/garfield.gif'

     ImageEditView openOn:'bitmaps/xpmBitmaps/BOOK.xpm'

    "

    "Modified: / 31.10.1997 / 16:19:23 / cg"

! !

!ImageEditView methodsFor:'accessing'!

image:anImage

    |oldMag|

    oldMag := magnification.

    magnification := 1@1.

    magnifiedImage := nil.

    super image:anImage.

    self magnification:oldMag

    "Modified: 20.2.1997 / 18:29:13 / cg"

!

magnification:aMagnificationPoint

    |nPixel savedImage oldBounds newBounds rects|

    magnification ~= aMagnificationPoint ifTrue:[

        "show wait cursor; although magnification is fast, dithering may take a while"

        self withWaitCursorDo:[

            magnifiedImage isNil ifTrue:[

                oldBounds := image bounds.

            ] ifFalse:[

                oldBounds := magnifiedImage bounds

            ].

            (device visualType == #PseudoColor) ifTrue:[

                "release kept colors"

                colors := IdentitySet new.

            ].

            magnification := aMagnificationPoint asPoint.

            "use a magnified image, if its size wont be too big"

            magnifiedImage := nil.

            "avoid slow scroll"

            savedImage := image.

            image := nil.

            self scrollToTopLeft.

            image := savedImage.

            magnification ~= (1@1) ifTrue:[

                nPixel := image width * image height * magnification x * magnification y.

                nPixel <= (2000 * 2000) ifTrue:[

                    Transcript showCR:'magnifying ..'; endEntry.

                    antiAlias ifTrue:[

                        magnifiedImage := image hardAntiAliasedMagnifiedBy:magnification

                    ] ifFalse:[

                        magnifiedImage := image magnifiedBy:magnification

                    ]

                ].

            ].

            self contentsChanged.

            magnifiedImage isNil ifTrue:[

                newBounds := image bounds.

            ] ifFalse:[

                newBounds := magnifiedImage bounds

            ].

            (rects := oldBounds areasOutside:newBounds) notNil ifTrue:[

                rects do:[:rect |

                    self clearRectangle:rect+(1@1).

                ]

            ]

        ].

        self invalidate.

    ]

    "Modified: 4.6.1997 / 13:38:16 / cg"

!

pathName:aPathName

    "set the pathName of the edited image.

     This is used as a default in the save-dialog"

    pathName := aPathName

    "Created: 10.4.1997 / 17:31:54 / cg"

! !

!ImageEditView methodsFor:'drawing'!

redrawX:x y:y width:w height:h

    |area ih iw dotW dotH minX maxX minY maxY color last lastY runW x0 oldClip|

    image isNil ifTrue:[^ self].

    (magnification = (1@1)) ifTrue:[

        super redrawX:x y:y width:w height:h.

        ^ self

    ].

    magnifiedImage notNil ifTrue:[

        self function:#copy.

        self paint:Black.

        magnifiedImage device ~~ device ifTrue:[

            "/ this may take some time (allocating colors & dithering

            self 

                displayRectangleX:margin y:margin 

                width:magnifiedImage width height:magnifiedImage height.

            self withWaitCursorDo:[

                magnifiedImage := magnifiedImage on:device.

            ]

        ].

        self withWaitCursorDo:[

            magnifiedImage depth == 1 ifTrue:[

                self paint:(magnifiedImage colorFromValue:1)

                        on:(magnifiedImage colorFromValue:0).

            ] ifFalse:[

                self paint:Black on:White.

            ].

            (magnifiedImage depth ~~ 1

            and:[magnifiedImage mask notNil]) ifTrue:[

                self clearRectangleX:x y:y width:w height:h.

                self displayForm:magnifiedImage x:margin y:margin 

            ] ifFalse:[

                self displayOpaqueForm:magnifiedImage x:margin y:margin 

            ].

            "/ right of image ?

            (x + w - 1) > magnifiedImage width ifTrue:[

                self clearRectangleX:(magnifiedImage width)

                                   y:y

                               width:(x + w - 1 - magnifiedImage width)

                              height:h  

            ].

            "/ below of image ?

            (y + h - 1) > magnifiedImage height ifTrue:[

                self clearRectangleX:margin

                                   y:(magnifiedImage height)

                               width:w

                              height:(y + h - 1 - magnifiedImage height)  

            ].

        ].

        ^ self

    ].

    ih := image height.

    iw := image width.

    dotW := magnification x.

    dotH := magnification y.

    minX := x // dotW.

    minY := y // dotW.

    maxX := (x + w) // dotW + 1.

    maxX > iw ifTrue:[

        maxX := iw

    ].

    maxY := (y + h) // dotH + 1.

    maxY > ih ifTrue:[

        maxY := ih

    ].

    lastY := -1.

    x0 := minX.

    runW := 0.

    image colorsFromX:minX y:minY toX:maxX-1 y:maxY-1 do:[:x :y :color |

        y ~~ lastY ifTrue:[

            runW ~~ 0 ifTrue:[

                self fillRectangleX:(x0 * dotW + margin)

                                  y:(lastY * dotH + margin)

                              width:runW height:dotH.

                runW := 0.

            ].

            x0 := x.

            lastY := y.

        ].

        color ~~ last ifTrue:[

            runW ~~ 0 ifTrue:[

                self fillRectangleX:(x0 * dotW + margin)

                                  y:(y * dotH + margin)

                              width:runW height:dotH.

                runW := 0.

            ].

            "/ keep colors - otherwise they might get collected & changed

            colors notNil ifTrue:[colors add:color].

            self paint:color.

            last := color.

            runW := 0.

            x0 := x.

        ].

        runW := runW + dotW

    ].

    runW ~~ 0 ifTrue:[

        self fillRectangleX:(x0 * dotW + margin)

                          y:(lastY * dotH + margin)

                      width:runW height:dotH.

        runW := 0.

    ].

    "Modified: 23.6.1997 / 21:24:40 / cg"

! !

!ImageEditView methodsFor:'event handling'!

buttonMotion:state x:x y:y

    self showColorAtX:x y:y.

!

buttonMultiPress:button x:x y:y

    button == 1 ifTrue:[

        |clr|

        clr := self getColorAtX:x y:y.

        clr inspect.

    ].

    super buttonMultiPress:button x:x y:y

    "Created: 8.5.1996 / 00:18:06 / stefan"

!

buttonPress:button x:x y:y

    button == 1 ifTrue:[

	self showColorAtX:x y:y.

	^ self

    ].

    super buttonPress:button x:x y:y

!

getColorAtX:x y:y

    |pi|

    pi := (x @ y) - margin.

    pi := pi // magnification.

    ((0@0 corner:image extent) containsPoint:pi) ifTrue:[

        ^ image at:pi.

    ].

    ^ nil

    "Created: 8.5.1996 / 00:15:55 / stefan"

!

showColorAtX:x y:y

    |clr|

    clr := self getColorAtX:x y:y.

    clr notNil ifTrue:[

        colorPanel notNil ifTrue:[

            colorPanel setColor:clr.

        ] ifFalse:[

            Transcript showCR:clr displayString

        ]

    ]

    "Modified: 8.5.1996 / 00:20:45 / stefan"

! !

!ImageEditView methodsFor:'image conversion'!

convertToColor24

    (Depth24Image fromImage:image) inspect

    "Modified: 3.6.1997 / 18:34:34 / cg"

!

convertToColor4

    (Depth4Image fromImage:image) inspect

    "Modified: 3.6.1997 / 18:34:45 / cg"

!

convertToColor8

    (Depth8Image fromImage:image) inspect

    "Created: 3.6.1997 / 18:34:08 / cg"

    "Modified: 3.6.1997 / 18:34:51 / cg"

!

convertToGray2

    (image asFloydSteinbergDitheredGrayImageDepth:2) inspect

    "Created: 3.6.1997 / 18:34:02 / cg"

    "Modified: 3.6.1997 / 18:39:23 / cg"

!

convertToGray4

    (image asFloydSteinbergDitheredGrayImageDepth:4) inspect

    "Created: 3.6.1997 / 18:34:04 / cg"

    "Modified: 3.6.1997 / 18:39:20 / cg"

!

convertToGray8

    (image asFloydSteinbergDitheredGrayImageDepth:8) inspect

    "Created: 3.6.1997 / 18:34:05 / cg"

    "Modified: 3.6.1997 / 18:39:16 / cg"

!

convertToMono

    (image asFloydSteinbergDitheredGrayImageDepth:1) inspect

    "Created: 3.6.1997 / 18:33:42 / cg"

    "Modified: 3.6.1997 / 18:39:26 / cg"

! !

!ImageEditView methodsFor:'image processing'!

blurr

    self performImageOperation:#blurr withArguments:nil

!

flipHorizontal

    self performImageOperation:#flipHorizontal withArguments:nil

!

flipVertical

    self performImageOperation:#flipVertical withArguments:nil

!

negative

    self performImageOperation:#negative withArguments:nil

    "Modified: 20.6.1997 / 13:14:45 / cg"

!

performImageOperation:operation withArguments:args

    |oldMag newImage|

    windowGroup withCursor:Cursor wait do:[

        oldMag := magnification.

        magnifiedImage := nil.

        magnification := 1@1.

        newImage := image perform:operation withArguments:args.

        newImage isNil ifTrue:[

            self information:'conversion failed - revert to original'.

            ^ self

        ].

        image := newImage.

        self clear.

        (oldMag isNil or:[oldMag = magnification]) ifTrue:[

            self invalidate

        ] ifFalse:[

            self magnification:oldMag.

        ]

    ]

    "Modified: 23.6.1997 / 09:49:26 / cg"

!

resizeImage

    |b newSize newImage wNew hNew bits|

    b := EnterBox new.

    b title:'new size (x @ y) contents will be located at top-left'.

    b okText:'apply'.

    b abortText:'abort'.

    b action:[:string | newSize := Object readFromString:string onError:nil].

    b initialText:(image extent printString).

    b showAtPointer.

    newSize notNil ifTrue:[

        wNew := image width min:newSize x.

        hNew := image height min:newSize y.

        newImage := Image width:(newSize x) height:(newSize y) depth:(image depth).

        newImage photometric:image photometric.

        newImage colorMap:image colorMap copy.

        newImage bits:(ByteArray new:(newImage bytesPerRow * newSize y)).

        newImage copyFrom:image x:0 y:0 toX:0 y:0 width:wNew height:hNew.

        newImage inspect

    ].

    "Created: 31.7.1997 / 11:41:14 / cg"

    "Modified: 31.7.1997 / 13:45:47 / cg"

!

rotateCCW

    self performImageOperation:#rotated: withArguments:#(270)

    "Created: 17.3.1997 / 11:56:42 / cg"

!

rotateCW

    self performImageOperation:#rotated: withArguments:#(90)

    "Created: 17.3.1997 / 11:56:36 / cg"

! !

!ImageEditView methodsFor:'initialization'!

initialize

    super initialize.

    magnification := 1@1.

    antiAlias := false.

    colors := nil.

    self menuHolder:self; menuPerformer:self; menuMessage:#imageMenu.

    "Modified: 2.6.1997 / 15:49:00 / cg"

! !

!ImageEditView methodsFor:'menu'!

imageMenu

    |m convertMenu labels selectors|

    image mask notNil ifTrue:[

        labels := #(

                        'save as ...'