"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

Object subclass:#ProjectDefinition

	instanceVariableNames:''

	classVariableNames:'LibraryType GUIApplicationType NonGUIApplicationType'

	poolDictionaries:''

	category:'System-Support-Projects'

!

ProjectDefinition class instanceVariableNames:'safeForOverwrittenMethods extensionOverwriteInfo projectIsLoaded'

"

 No other class instance variables are inherited by this class.

"

!

!ProjectDefinition class methodsFor:'documentation'!

buildingMakefiles

"

    You can define additional rules and flag settings for use in the makeFile generation:

    redefinable build-file attributes:

        stcOptimizationOptions  -> STCLOCALOPT

        stcWarningOptions       -> STCLOCALOPT

        localIncludes_unix      -> LOCALINCLUDES (Make.proto)

        localIncludes_win32     -> LOCALINCLUDES (bc.mak)

    for applications:    

        startupClassName

        startupSelector

    for libraries:    

"

!

copyright

"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    As ST/X is (still) very tightly bound with stc, we keep the package and project information

    in a class-object (instead of some Project-object). This has the advantage, that it can be

    compiled and included in a compiled class library just like any other class.

    Every package includes an subclass of me (an instance of my meta), which provides useful

    information about the versioning and packaging. Me myself, I know how to generate dependency

    information and can generate makefiles and other build-support files for compilation.

    Some special notes about extension methods:

    if a package is loaded (Smalltalk loadPackage:'foo:bar/baz'), any already loaded package of which

    methods are overwritten by an extension of this package, the other package is asked to safe those

    methods in its safe(ForOverwrittenMethods). Thus, if the other package or any of its classes is asked

    to file itself out, it can do so using the safe (otherwise, you'D not be able to checkin a class while

    it has an overriding extension loaded).

    Also, the information about which other package was in charge when a method is overwritten is recorded in

    extensionOverwriteInfo. This is used to correctly reinstall an overwritten method, whenever a package is

    unloaded.

"

! !

!ProjectDefinition class methodsFor:'instance creation'!

definitionClassForMonticelloPackage:aMonicelloPackagename

    ^ self definitionClassForMonticelloPackage:aMonicelloPackagename createIfAbsent:false

    "

     self definitionClassForMonticelloPackage:'foobar'

    "

!

definitionClassForMonticelloPackage:aMonicelloPackagename createIfAbsent:createIfAbsent

    ^ self allSubclasses 

        detect:[:eachProjectDefinition |

            eachProjectDefinition monticelloPackageName = aMonicelloPackagename ]

        ifNone:[

            |dfn squeakPackageInfo|

            createIfAbsent ifTrue:[

                dfn := ApplicationDefinition 

                    definitionClassForPackage:'mc:',aMonicelloPackagename createIfAbsent:true projectType:GUIApplicationType.

                "/ if the squeak-stuff is loaded, use it.

                squeakPackageInfo := PackageInfo allSubclasses 

                                            detect:[:pi | pi new packageName = aMonicelloPackagename] ifNone:nil.

                squeakPackageInfo notNil ifTrue:[

                    dfn classNames:(squeakPackageInfo new classes collect:[:each | each name]).

                ].

            ] ifFalse:[

                nil

            ]

        ]

    "

     self definitionClassForMonticelloPackage:'foobar'

     self definitionClassForMonticelloPackage:'foobar' createIfAbsent:true

    "

!

definitionClassForPackage:aPackageID

    ^ self definitionClassForPackage:aPackageID createIfAbsent:false

    "Modified: / 17-08-2006 / 14:33:35 / cg"

!

definitionClassForPackage:aPackageID createIfAbsent:doCreateIfAbsent

    ^ self definitionClassForPackage:aPackageID createIfAbsent:doCreateIfAbsent projectType:nil

    "Modified: / 23-08-2006 / 14:29:15 / cg"

!

definitionClassForPackage: aPackageID createIfAbsent: doCreateIfAbsent projectType:typeOrNil

    |packageDefinitionClassName class|

    packageDefinitionClassName := ProjectDefinition initialClassNameForDefinitionOf:aPackageID.

    class := Smalltalk classNamed:packageDefinitionClassName.

    class isNil ifTrue:[

        doCreateIfAbsent ifTrue:[

            class := self newForPackage:aPackageID.

            "setup before prerequisites are defined"

            class setupForType:typeOrNil.

            "/ look what is there and include it; is this ok ?

            class compileDescriptionMethods 

        ].

    ] ifFalse:[

        typeOrNil notNil ifTrue:[

            class projectType == typeOrNil ifFalse: [

                class setupForType:typeOrNil.

            ].

        ].

    ].

    ^ class

    "Created: / 23-08-2006 / 14:29:21 / cg"

    "Modified: / 23-08-2006 / 15:35:26 / cg"

!

definitionClassForPackage:newProjectID projectType:typeOrNil createIfAbsent:createIfAbsent

    ^ (self definitionClassForType:typeOrNil)

            definitionClassForPackage:newProjectID 

            createIfAbsent:createIfAbsent

            projectType:typeOrNil

    "Created: / 23-08-2006 / 14:28:53 / cg"

!

definitionClassForType: type

    "answer the class that describes a give project type"

    (type = LibraryType) ifTrue:[ ^ LibraryDefinition ].

    (type = GUIApplicationType) ifTrue:[ ^ ApplicationDefinition ].

    (type = NonGUIApplicationType) ifTrue:[ ^ ApplicationDefinition ].

    (type = 'Application') ifTrue:[ ^ ApplicationDefinition ].     "/ temporary - for backward compat.

    self error:'unknown project type'.

    "Created: / 17-08-2006 / 14:46:28 / cg"

    "Modified: / 23-08-2006 / 13:49:27 / cg"

!

newForPackage:packageID

    ^ self 

        newNamed:(self initialClassNameForDefinitionOf:packageID) 

        package:packageID.

    "Created: / 11-08-2006 / 14:27:19 / cg"

!

newNamed:newName package:packageID

    |newClass|

    "/ for now, we are strict.

    self assert:(self initialClassNameForDefinitionOf:packageID) = newName.

    self assert:(self ~~ ProjectDefinition).  "ProjectDefinition is abstract"

    newClass := self

                    subclass:(newName asSymbol)

                    instanceVariableNames:''

                    classVariableNames:''

                    poolDictionaries:''

                    category:(self defaultCategory).

    newClass package:packageID asSymbol.

    ^ newClass

    "Created: / 09-08-2006 / 17:57:37 / fm"

    "Modified: / 09-08-2006 / 19:27:53 / fm"

    "Modified: / 17-08-2006 / 17:24:23 / cg"

! !

!ProjectDefinition class methodsFor:'accessing'!

allPreRequisites

    "answer all (recursive) prerequisite project ids of myself - in random order.

     If we exclude a project, but one of our prerequisite projects depends on it, "

    |setOfAllPreRequisites toAdd|

    setOfAllPreRequisites := Set new.

    toAdd := Set new.

    toAdd addAll:self effectivePreRequisites.

    "is a subproject really a prerequisite??

     No, it works the other way: parent projects are prerequisites of sub projects,

     so the following line has been deleted.

     Unfortunately the meaning of 'subproject' has never been well defined. SV."

"/    toAdd addAll:self effectiveSubProjects.

    [toAdd notEmpty] whileTrue:[

        |aPreRequisiteProjectID def|

        aPreRequisiteProjectID := toAdd removeFirst.

        (setOfAllPreRequisites includes:aPreRequisiteProjectID) ifFalse:[

            setOfAllPreRequisites add:aPreRequisiteProjectID.

            def := self definitionClassForPackage:aPreRequisiteProjectID.

            def isNil ifTrue:[

                Transcript showCR:'ProjectDefinition ', aPreRequisiteProjectID, ' is missing - cannot find its preRequisites.'.

            ] ifFalse:[

                def effectivePreRequisites 

                    select:[:eachSubPreRequisite | (setOfAllPreRequisites includes:eachSubPreRequisite) not]

                    thenDo:[:eachSubPreRequisite | 

                                Transcript showCR:(aPreRequisiteProjectID, ' requires ', eachSubPreRequisite).

                                toAdd add:eachSubPreRequisite ].

                "but subprojects of our prerequisites are also prerequisites"

                def effectiveSubProjects 

                    select:[:eachSubSubRequisite | (setOfAllPreRequisites includes:eachSubSubRequisite) not]

                    thenDo:[:eachSubSubRequisite | 

                                Transcript showCR:(aPreRequisiteProjectID, ' hasSub ', eachSubSubRequisite).

                                toAdd add:eachSubSubRequisite ].

            ].

        ]        

    ].

    ^ setOfAllPreRequisites.

    "

     stx_libbasic allPreRequisites

     stx_libbasic2 allPreRequisites

     stx_libview2 allPreRequisites

     ubs_application allPreRequisites   

     ubs_application allPreRequisitesSorted   

     exept_expeccoNET_application allPreRequisites   

     alspa_batch_application allPreRequisites

    "

!

allPreRequisitesSorted

    "answer all the prerequisites of this projects sorted in

     the order they are needed.

     Use this to e.g. compile packages in the dependency order"

    |allPreRequisites orderedTuples effective|

    orderedTuples := OrderedCollection new.

    allPreRequisites := self allPreRequisites.

    allPreRequisites do:[:eachPackageID |

        |def|

        def := self definitionClassForPackage:eachPackageID.

        def isNil ifTrue:[

            Transcript showCR:'Warning: no definition class for package: ', eachPackageID.

            orderedTuples add:(Array with:eachPackageID).

        ] ifFalse:[

            effective := def effectivePreRequisites.

            effective isEmptyOrNil ifTrue:[

                orderedTuples add:(Array with:eachPackageID).

            ] ifFalse:[

                effective do:[:eachPrerequisitePackageID|

                    orderedTuples add:(Array with:eachPrerequisitePackageID with:eachPackageID).

                ].

            ].

        ].

    ].

    ^ orderedTuples topologicalSort.

    "

     stx_libbasic allPreRequisitesSorted

     stx_libbasic2 allPreRequisitesSorted

     stx_libwidg2 allPreRequisitesSorted

     exept_expecco_application allPreRequisitesSorted

     alspa_batch_application allPreRequisitesSorted

     ubs_application allPreRequisitesSorted

    "

!

initialClassNameForDefinitionOf:aPackageId

    "given a package-ID, return an appropriate class name for this package"

    |s|

    s := aPackageId asString copy replaceAny:':/' with:$_.

    (s endsWith:$_) ifTrue:[

        s := s copyWithoutLast:1

    ].

    ^ s

    "

     DapasXProject initialClassNameForDefinitionOf:'bosch:dapasx/interactiver_editor' 

     DapasXProject initialClassNameForDefinitionOf:'stx:libbasic' 

     DapasXProject initialClassNameForDefinitionOf:'stx:goodies/xml' 

    "

    "Created: / 09-08-2006 / 17:44:47 / fm"

    "Modified: / 11-08-2006 / 14:00:05 / cg"

!

libraryName

    ^ self package asPackageId libraryName

    "

     bosch_dapasx_datenbasis libraryName

     stx_libbasic3 libraryName

    "

    "Modified: / 09-08-2006 / 18:20:29 / fm"

    "Modified: / 18-08-2006 / 12:36:45 / cg"

!

libraryNameFor:aProjectID 

    ^ aProjectID asPackageId libraryName

    "

     bosch_dapasx_datenbasis libraryName

     stx_libbasic3 libraryNameFor:'stx:libbasic'

     stx_libbasic3 libraryNameFor:'bosch:dapasx/datenbasis' 

    "

    "Modified: / 09-08-2006 / 18:20:29 / fm"

    "Modified: / 18-08-2006 / 12:37:02 / cg"

!

module

    ^ self moduleOfClass:self

    "

       bosch_dapasx_datenbasis_Definition module

       DapasX_Datenbasis module

       stx_libbasic3 module

    "

    "Created: / 08-08-2006 / 20:24:53 / fm"

    "Modified: / 09-08-2006 / 16:16:37 / fm"

    "Modified: / 17-08-2006 / 20:50:46 / cg"

!

moduleDirectory

    ^ (PackageId from:self package) directory

    "

     bosch_dapasx_datenbasis_Definition moduleDirectory

     bosch_dapasx_parameter_system_Definition moduleDirectory

     stx_libbasic3 moduleDirectory    

    "

    "Created: / 08-08-2006 / 20:25:39 / fm"

    "Modified: / 18-08-2006 / 12:18:33 / cg"

!

moduleDirectoryFor:aProjectID 

    ^ (aProjectID subStrings:$:) last

    "

        bosch_dapasx_datenbasis_Definition moduleDirectory

        bosch_dapasx_parameter_system_Definition moduleDirectory

    "

    "Created: / 08-08-2006 / 20:25:39 / fm"

    "Modified: / 17-08-2006 / 14:13:41 / cg"

!

moduleDirectory_win32

    ^ (PackageId from:self package) directory copy replaceAll:$/ with:$\

    "

     bosch_dapasx_datenbasis moduleDirectory_win32

     bosch_dapasx_parameter_system moduleDirectory_win32

     stx_libbasic3 moduleDirectory_win32    

    "

    "Created: / 14-09-2006 / 20:19:17 / cg"

!

moduleDirectory_win32For: projectID

    ^(self moduleDirectoryFor:projectID) copy replaceAll:$/ with:$\

    "

     self moduleDirectory_win32For: #'bosch:dapasx/pav_vergleich'

     self moduleDirectory_win32For: #'stx:goodies/xml/stx'

     self moduleDirectory_win32For: #'stx:libbasic2'

    "

!

moduleFor:aProjectID 

    ^ (aProjectID subStrings:$:) first

    "

       DapasXProject module

       DapasX_Datenbasis module

    "

    "Created: / 09-08-2006 / 16:16:16 / fm"

    "Modified: / 17-08-2006 / 14:13:46 / cg"

!

moduleOfClass:aClass 

    ^ self moduleFor:aClass package

    "

       DapasXProject module

       DapasX_Datenbasis module

    "

    "Created: / 09-08-2006 / 16:16:16 / fm"

    "Modified: / 17-08-2006 / 14:13:51 / cg"

!

monticelloPackageName

    "hook for packages which have been loaded from monticello"

    ^ nil

!

msdosPathToPackage:toPackageID from:fromPackageID

    "Returns the path to the package defined by aPackageID relative to my path"

    |parts1 parts2 common up down|

    parts1 := fromPackageID asCollectionOfSubstringsSeparatedByAny:':/'.

    parts2 := toPackageID asCollectionOfSubstringsSeparatedByAny:':/'.

    common := parts1 commonPrefixWith:parts2.

    up := ((1 to:parts1 size - common size) collect:[:p | '..']) asStringWith:'\'.

    down := (parts2 copyFrom:common size+1) asStringWith:'\'.

    up isEmpty ifTrue:[

       down isEmpty ifTrue:[^ '.'].

        ^ down.

    ].

    down isEmpty ifTrue:[

        ^ up.

    ].

    ^ up, '\', down   

    "

     self msdosPathToPackage:'bosch:dapasx/kernel' from:'bosch:dapasx/application'

     self msdosPathToPackage:'stx:libbasic' from:'bosch:dapasx/application'   

     self msdosPathToPackage:'bosch:dapasx/application' from:'stx:libbasic'   

     self msdosPathToPackage:'exept:expecco' from:'exept:expecco/application'   

     self msdosPathToPackage:'exept:expecco/application' from:'exept:expecco'   

    "

    "Created: / 17-08-2006 / 14:26:39 / cg"

    "Modified: / 14-09-2006 / 22:04:56 / cg"

!

msdosPathToTopFor:aProjectID

    "Returns the path to stx counting the number of $/ and $: in the package name and adding for each one '../' to get the ST/X top directory"

    |parts|

    parts := aProjectID asCollectionOfSubstringsSeparatedByAny:':/'.

    aProjectID asPackageId module = 'stx' ifTrue:[

        parts size == 1 ifTrue:[^ '.'].

        ^ (((2 to:parts size-1) collect:[:p | '..\']) asStringWith:'') , '..'   

    ].