"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1995 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic3' }"

"{ NameSpace: Smalltalk }"

Object subclass:#AbstractSourceCodeManager

	instanceVariableNames:''

	classVariableNames:'CacheDirectoryName CachingSources DefaultManager ManagerPerModule

		PackagesWithoutExtensionMethodConfirmation

		SuppressExtensionMethodConfirmation UseWorkTree Verbose

		WorkTreeDirectoryName'

	poolDictionaries:''

	category:'System-SourceCodeManagement'

!

Object subclass:#PackageAndManager

	instanceVariableNames:'package managerTypeName'

	classVariableNames:''

	poolDictionaries:''

	privateIn:AbstractSourceCodeManager

!

!AbstractSourceCodeManager class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Abstract superclass for sourceCodeManagers.

    Concrete subclasses provide access to a source repository.

    Most protocol here traps into subclassResponsbility errors.

    Please read more documentation in concrete subclasses 

    (especially: CVSSourceCodeManager) for how to use this manager and

    what to redefine in another repository manager if required.

    [author:]

        Claus Gittinger

"

! !

!AbstractSourceCodeManager class methodsFor:'initialization'!

forgetDisabledModules

    "intentionally left blank"

    ^ self

    "Modified (comment): / 18-05-2018 / 12:37:57 / Stefan Vogel"

!

initCacheDirPath

    "initialize the name of the cacheDirectory.

     This is:

        <tempDir>/stx_sourceCache (non-UNIX)

        ~/.smalltalk/source-cache (UNIX, as <tempDir> is pruned upon each reboot)

    "

    "JV@2012-03-14: Changed to use .smalltalk/source-cache on UNIX machines"

    "CG: why only on unix machines???"

    |dir|

    CachingSources isNil ifTrue:[

        CachingSources := true.

    ].

    dir := Filename homeDirectory / '.smalltalk/sourceCache'. 

    dir isWritableDirectory ifFalse:[

        dir := Filename defaultTempDirectory / 'stx_sourceCache'.

    ].  

    CacheDirectoryName := dir pathName.

"/    OperatingSystem isUNIXlike ifTrue:[

"/        CacheDirectoryName := '~/.smalltalk/sourceCache'.

"/    ] ifFalse:[

"/        CacheDirectoryName := (Filename defaultTempDirectory constructString:'stx_sourceCache').

"/    ].

    "

     self initCacheDirPath     

    "

    "Modified: / 12-07-1999 / 10:01:31 / cg"

    "Modified (comment): / 19-07-2012 / 14:03:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

initialize

    "setup for caching and no workTree"

    CachingSources isNil ifTrue:[CachingSources := true].

    UseWorkTree    isNil ifTrue:[UseWorkTree := false].

    SuppressExtensionMethodConfirmation 

                   isNil ifTrue:[SuppressExtensionMethodConfirmation := false].

    CachingSources ifTrue:[

        self validateCacheDirPath.

    ].

    Smalltalk addDependent:self

    "Modified: / 02-03-2012 / 17:00:11 / cg"

    "Modified: / 18-05-2018 / 12:40:59 / Stefan Vogel"

!

update:something with:aParameter from:changedObject

    "flush resources on language changes"

    something == #returnFromSnapshot ifTrue:[

        self validateCacheDirPath

    ]

!

validateCacheDirPath

    (CacheDirectoryName isNil 

    or:[CacheDirectoryName asFilename exists not]) ifTrue:[

        self initCacheDirPath   

    ].

! !

!AbstractSourceCodeManager class methodsFor:'* uncategorized *'!

repositoryTopDirectoryFromSCMRoot

    "return the top of the repository."

    ^ self subclassResponsibility

    "Created: / 18-05-2018 / 12:30:23 / Stefan Vogel"

! !

!AbstractSourceCodeManager class methodsFor:'accessing'!

availableManagers

    ^ AbstractSourceCodeManager 

        allSubclasses 

            reject:[:cls | (cls isAbstract) or:[cls isExperimental]].

    "

     self availableManagers   

    "

    "Modified (format): / 18-05-2018 / 12:19:48 / Stefan Vogel"

!

branchStartTagFor:branchName

    "this tag is used to tag the original starting point of a branch;

     i.e. the head version from which the branch was created.

     Here, we use <branchTagPrefix><branchName>_0"

    ^ (self branchTagFor:branchName),'_0'

    "Created: / 07-12-2017 / 10:23:13 / cg"

!

branchTagFor:branchName

    "this tag is used to tag the current branch-head of a branch (or the branch as such);

     i.e. the last version checked onto the branch.

     Here, we use <branchTagPrefix><branchName>"

    ^ (self branchTagPrefix),branchName

    "Created: / 07-12-2017 / 10:24:03 / cg"

!

branchTagPrefix

    ^ 'branch_'

    "Created: / 05-12-2017 / 19:19:39 / cg"

!

cacheDirectoryName

    "return the name of the cache directory, where checked out class

     sources are kept for faster access. The default is '/tmp/stx_sourceCache'.

     This cache is shared among all ST/X users on a system."

    self cachingSources ifTrue:[

        (CacheDirectoryName isNil) ifTrue:[

            self initCacheDirPath   

        ].

    ].

    ^ CacheDirectoryName

    "Modified: 12.9.1996 / 02:20:45 / cg"

!

cacheDirectoryName:aStringOrFilename

    "set the name of the cache directory, where checked out class

     sources are kept for faster access. The default is '/tmp/stx_sourceCache'.

     This cache is shared among all ST/X users on a system.

     The directory is typically set via the launcher's setting menu, 

     or from a startup rc-file."

    CacheDirectoryName := aStringOrFilename.

    "HACK, HACK, since ManagerPerModule is lazy-initialize before

     preferences are read, sigh. We need a better system..."

    ManagerPerModule := nil.

    "Created: / 16-12-1995 / 15:18:43 / cg"

    "Modified: / 12-09-1996 / 02:21:35 / cg"

    "Modified (comment): / 09-07-2011 / 16:02:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

cachingSources

    "return true, if source caching is enabled.

     (see cacheDirectoryName for what that means)"

    ^ CachingSources ? false

    "Created: 16.12.1995 / 15:17:50 / cg"

    "Modified: 12.9.1996 / 02:22:19 / cg"

!

cachingSources:aBoolean

    "enable/disable the caching of source files.

     (see cacheDirectoryName for what that means)"

    CachingSources := aBoolean.

    aBoolean ifTrue:[

        CacheDirectoryName isNil ifTrue:[

            self validateCacheDirPath

        ].    

    ].    

    "

     AbstractSourceCodeManager cachingSources:true

    "

    "Created: 16.12.1995 / 15:18:13 / cg"

    "Modified: 12.9.1996 / 02:22:42 / cg"

!

defaultManager

    "return the default sourceCodeManager class"

    ^ DefaultManager

    "Created: 7.12.1995 / 17:14:22 / cg"

    "Modified: 12.9.1996 / 02:22:56 / cg"

!

enabledManagers

    "Return list of source code managers that are enabled"

    "If source code management is disabled, return #(). Following code

     is hack since  there is no global boolean flag, sigh"

    (Smalltalk at:#SourceCodeManager) isNil ifTrue:[

        ^ #()

    ].

    ^ self availableManagers select:[:manager | manager enabled].  

    "

     self enabledManagers   

    "

    "Created: / 23-01-2012 / 19:13:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerForMatchingModule:aPackageIDMatchString put:aSourceCodeManagerClass

    "update the per-module manager definitions, adding a manager class for a matchString"

    ManagerPerModule isNil ifTrue:[

        ManagerPerModule := UserPreferences current managerPerMatchingModuleDefinitions.

    ].

    ManagerPerModule do:[:each |

        |packageMatch|

        packageMatch := each package.

        (packageMatch = aPackageIDMatchString) ifTrue:[

            each manager:aSourceCodeManagerClass.

            ^ self

        ].

    ].

    ManagerPerModule add:

        (PackageAndManager 

            package: aPackageIDMatchString 

            manager: aSourceCodeManagerClass)

    "

     self managerForModule:'stx:libbasic2' put:SVNSourceCodeManager

     self managerForModule:'stx:libbasic2' put:CVSSourceCodeManager

     self managerForModule:'stx:libbasic2'

     self managerForModule:'exept:expecco' 

    "

    "Created: / 18-04-2011 / 19:48:19 / cg"

    "Modified: / 07-07-2013 / 10:40:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerForPackage:aPackageID

    "return the sourceCodeManager for a aPackageID, nil if unspecified in the manager per package list"

    "JV@2012-01-23: If source code management is disabled, return nil. Following code

     is hack since  there is no global boolean flag, sigh"

    (Smalltalk at:#SourceCodeManager) isNil ifTrue:[ ^nil ].

    "JV@2012-01-23: HACK: Q: Shouldn't it filter configured manager through

     'enabled' managers?"         

    self managerPerMatchingModuleDefinitions do:[:each |

        (each match:aPackageID) ifTrue:[^ each manager].

    ].

    ^ DefaultManager

    "

     self managerForPackage:'stx:libbasic' 

     self managerForPackage:'stx:libbasic2'

     self managerForPackage:'exept:expecco'  

    "

    "Created: / 18-04-2011 / 19:39:19 / cg"

    "Created: / 10-10-2011 / 14:50:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-10-2011 / 16:45:38 / cg"

    "Modified (comment): / 23-01-2012 / 19:46:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerPerMatchingModuleDefinitions

    "return the sourceCodeManager definitions"

    ManagerPerModule isNil ifTrue:[

        ManagerPerModule := UserPreferences current managerPerMatchingModuleDefinitions

    ].

    ^ ManagerPerModule

    "Created: / 18-04-2011 / 20:09:16 / cg"

    "Modified: / 09-07-2011 / 13:36:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerPerMatchingModuleDefinitions:aCollection

    "set the sourceCodeManager definitions; must be an orderedCollection of packageMatchString -> manager

     associations 

     (not a dictionary, because order is relevant in the matching process, where the first match counts)"

    ManagerPerModule := aCollection.

    UserPreferences current managerPerMatchingModuleDefinitions:aCollection

    "Created: / 18-04-2011 / 20:09:21 / cg"

    "Modified: / 09-07-2011 / 13:36:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

named: managerTypeName

    ^self availableManagers 

        detect:[:each|each managerTypeName = managerTypeName]

        ifNone:[nil]

    "

        AbstractSourceCodeManager named: 'CVS'

        AbstractSourceCodeManager named: 'Perforce'        

    "

    "Created: / 09-07-2011 / 13:51:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

repositoryInfoPerModule

    "return the dictionary, which associates CVSRoots to module names.

     If no entry is contained in this dictionary for some module,

     the default cvsRoot (CVSRoot) will be used."

    ^ #()

    "Created: / 09-11-2006 / 15:25:17 / cg"

!

repositoryInfoPerModule:info

    "/ ignore here

!

repositoryName

    "return the name of the repository.

     Since this is an abstract class, return nil (i.e. none)"

    ^ nil

    "Modified: 12.9.1996 / 02:20:45 / cg"

    "Created: 14.9.1996 / 13:21:37 / cg"

!

repositoryNameForPackage:packageId 

    "Return the repository URL for the given package. 

     Used for testing/debugging source code management configuration"

    ^ self subclassResponsibility

    "Created: / 10-10-2011 / 19:44:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 05-12-2017 / 17:41:57 / cg"

!

shownInBrowserMenus

    "can be redefined in subclasses which can be suppressed in the browser's menus"

    ^ UserPreferences current at:(self nameWithoutPrefix,'.enabled') ifAbsent:false.

    "Created: / 08-01-2012 / 19:56:22 / cg"

!

shownInBrowserMenus:aBoolean

    "can be redefined in subclasses which can be suppressed in the browser's menus"

    ^ UserPreferences current at:(self nameWithoutPrefix,'.enabled') put:aBoolean.

    "Created: / 15-01-2012 / 14:09:21 / cg"

!

useWorkTree

    "return the setting of useWorkTree, which (eventually)

     controls if an up-to-date view of a CVS working tree should be

     kept in sync. This is not yet implemented."

    ^ UseWorkTree

    "Created: 16.12.1995 / 15:36:48 / cg"

    "Modified: 12.9.1996 / 02:24:01 / cg"

!

useWorkTree:aBoolean

    "enable/disable the useWorkTree feature, which (eventually)

     controls if an up-to-date view of a CVS working tree should be

     kept in sync. This is not yet implemented."

    UseWorkTree := aBoolean

    "Created: 16.12.1995 / 15:37:29 / cg"

    "Modified: 12.9.1996 / 02:24:38 / cg"

!

utilities

    "Returns a 'utilities' object that can be used by tools. 

     By default, it returns an instance of

     SourceCodeManagerUtilities with receiver as its

     manager, but individual managers may override this

     method and supply its own, customized utilities."

    ^ (self isContainerBased

            ifTrue: [ SourceCodeManagerUtilitiesForContainerBasedManagers ]

            ifFalse: [ SourceCodeManagerUtilitiesForWorkspaceBasedManagers ]

      ) forManager: self

    "

     SourceCodeManager defaultManager

     SourceCodeManager defaultManager utilities

    "

    "Created: / 10-10-2011 / 15:10:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 25-07-2012 / 17:08:05 / cg"

!

workTreeDirectoryName

    "return the name of the workTree, which is kept in sync

     with the current class versions. This is not yet implemented"

    ^ WorkTreeDirectoryName

    "Created: 16.12.1995 / 15:35:21 / cg"

    "Modified: 12.9.1996 / 02:25:13 / cg"

!

workTreeDirectoryName:aStringOrFilename

    "set the name of the workTree, which is kept in sync

     with the current class versions. This is not yet implemented"