"

 COPYRIGHT (c) 1995 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic3' }"

"{ NameSpace: Smalltalk }"

Object subclass:#AbstractSourceCodeManager

	instanceVariableNames:''

	classVariableNames:'DefaultManager CachingSources CacheDirectoryName UseWorkTree

		WorkTreeDirectoryName ManagerPerModule Verbose

		ManagerForPackageCache'

	poolDictionaries:''

	category:'System-SourceCodeManagement'

!

Object subclass:#PackageAndManager

	instanceVariableNames:'package managerTypeName'

	classVariableNames:''

	poolDictionaries:''

	privateIn:AbstractSourceCodeManager

!

!AbstractSourceCodeManager class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Abstract superclass for sourceCodeManagers.

    Concrete subclasses provide access to a source repository.

    Most protocol here traps into subclassResponsbility errors.

    Please read more documentation in concrete subclasses 

    (especially: CVSSourceCodeManager) for how to use this manager and

    what to redefine in another repository manager if required.

    [author:]

        Claus Gittinger

"

! !

!AbstractSourceCodeManager class methodsFor:'initialization'!

forgetDisabledModules

    ^ self

!

initCacheDirPath

    "initialize the name of the cacheDirectory.

     This is:

        <tempDir>/stx_sourceCache (non-UNIX)

        ~/.smalltalk/source-cache (UNIX, as <tempDir> is pruned upon each reboot)

    "

    "JV@2012-03-14: Changed to use .smalltalk/source-cache on UNIX machines"

    OperatingSystem isUNIXlike ifTrue:[

        CacheDirectoryName := '~/.smalltalk/sourceCache'.

        ^self

    ].

    CacheDirectoryName := (Filename defaultTempDirectory constructString:'stx_sourceCache').

    "

     self initCacheDirPath     

    "

    "Modified: / 12-07-1999 / 10:01:31 / cg"

    "Modified (comment): / 19-07-2012 / 14:03:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

initialize

    "setup for no caching and no workTree"

    CachingSources isNil ifTrue:[CachingSources := false].

    UseWorkTree    isNil ifTrue:[UseWorkTree := false].

    ManagerForPackageCache := Dictionary new.

    self validateCacheDirPath.

    Smalltalk addDependent:self

    "Modified: / 02-03-2012 / 17:00:11 / cg"

    "Modified: / 01-10-2015 / 06:07:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

update:something with:aParameter from:changedObject

    "flush resources on language changes"

    something == #returnFromSnapshot ifTrue:[

        self validateCacheDirPath

    ]

!

validateCacheDirPath

    (CacheDirectoryName isNil 

    or:[CacheDirectoryName asFilename exists not]) ifTrue:[

        self initCacheDirPath   

    ].

!

validateWorkingCopy: path

    "Return true, if given path is a valid working 

     copy of this manager; false otherwise."

    "/ JV@2015-10-02: Following is certainly a kludge, but defined

    "/ here tp avoid forking stx:libsvn..."

    self name == #SVNSourceCodeManager ifTrue:[

        ^ (path asFilename / '.svn') isDirectory

    ].

    ^ false

    "Created: / 02-10-2015 / 09:52:07 / jv"

! !

!AbstractSourceCodeManager class methodsFor:'accessing'!

availableManagers

    ^ AbstractSourceCodeManager allSubclasses 

        reject:[:cls | (cls isAbstract) or:[cls isExperimental ]].

    "

     self availableManagers   

    "

!

cacheDirectoryName

    "return the name of the cache directory, where checked out class

     sources are kept for faster access. The default is '/tmp/stx_sourceCache'.

     This cache is shared among all ST/X users on a system."

    ^ CacheDirectoryName

    "Modified: 12.9.1996 / 02:20:45 / cg"

!

cacheDirectoryName:aStringOrFilename

    "set the name of the cache directory, where checked out class

     sources are kept for faster access. The default is '/tmp/stx_sourceCache'.

     This cache is shared among all ST/X users on a system.

     The directory is typically set via the launchers setting menu, or

     from a startup rc-file."

    CacheDirectoryName := aStringOrFilename.

    "HACK, HACK, since ManagerPerModule is lazy-initialize before

     preferences are read, sigh. We need a better system..."

    ManagerPerModule := nil.

    "Created: / 16-12-1995 / 15:18:43 / cg"

    "Modified: / 12-09-1996 / 02:21:35 / cg"

    "Modified (comment): / 09-07-2011 / 16:02:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

cachingSources

    "return true, if source caching is enabled.

     (see cacheDirectoryName for what that means)"

    ^ CachingSources

    "Created: 16.12.1995 / 15:17:50 / cg"

    "Modified: 12.9.1996 / 02:22:19 / cg"

!

cachingSources:aBoolean

    "enable/disable the caching of source files.

     (see cacheDirectoryName for what that means)"

    CachingSources := aBoolean

    "Created: 16.12.1995 / 15:18:13 / cg"

    "Modified: 12.9.1996 / 02:22:42 / cg"

!

defaultManager

    "return the default sourceCodeManager class"

    ^ DefaultManager

    "Created: 7.12.1995 / 17:14:22 / cg"

    "Modified: 12.9.1996 / 02:22:56 / cg"

!

enabledManagers

    "Return list of source code managers that are enabled"

    "If source code management is disabled, return #(). Following code

     is hack since  there is no global boolean flag, sigh"

    ^(Smalltalk at:#SourceCodeManager) isNil ifTrue:[

        #()

    ] ifFalse:[

        self availableManagers select:[:manager|manager enabled].  

    ]

    "

     self enabledManagers   

    "

    "Created: / 23-01-2012 / 19:13:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerForMatchingModule:aPackageIDMatchString put:aSourceCodeManagerClass

    "update the per-module manager definitions, adding a manager class for a matchString"

    ManagerPerModule isNil ifTrue:[

        ManagerPerModule := UserPreferences current managerPerMatchingModuleDefinitions.

    ].

    ManagerPerModule do:[:each |

        |packageMatch|

        packageMatch := each package.

        (packageMatch = aPackageIDMatchString) ifTrue:[

            each manager:aSourceCodeManagerClass.

            ^ self

        ].

    ].

    ManagerPerModule add:

        (PackageAndManager 

            package: aPackageIDMatchString 

            manager: aSourceCodeManagerClass).

    ManagerForPackageCache := Dictionary new. 

    "

     self managerForModule:'stx:libbasic2' put:SVNSourceCodeManager

     self managerForModule:'stx:libbasic2' put:CVSSourceCodeManager

     self managerForModule:'stx:libbasic2'

     self managerForModule:'exept:expecco' 

    "

    "Created: / 18-04-2011 / 19:48:19 / cg"

    "Modified: / 01-10-2015 / 06:04:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerForPackage: aSymbol

    "return the sourceCodeManager for a aPackageID, nil if unspecified in the manager per package list"

    | prjsym prjdef prjdir parentPrjId manager |

    prjsym := aSymbol asSymbol.

    "JV@2012-01-23: If source code management is disabled, return nil. Following code

     is hack since  there is no global boolean flag, sigh"

    (Smalltalk at:#SourceCodeManager) isNil ifTrue:[ ^nil ].

    "First, search the cache..."

    ManagerForPackageCache at: prjsym ifPresent:[ :manager | ^ manager ].

    "If not found in the cache, search configured managers"

    self managerPerMatchingModuleDefinitions do:[:each |

        (each match:prjsym) ifTrue:[

            ManagerForPackageCache at: prjsym put: each manager.

            ^ each manager

        ].

    ].

    "If there's no configuration for given package, try to use the same

     that was used when package was compiled"

    prjdef := ProjectDefinition definitionClassForPackage: prjsym.

    (prjdef notNil and:[prjdef binaryRevisionString notNil]) ifTrue:[ 

        manager := prjdef sourceCodeManagerFromBinaryRevision.

        (manager notNil and:[manager enabled and:[manager isResponsibleForPackage: prjsym]]) ifTrue:[ 

            ManagerForPackageCache at: prjsym put: manager.

            ^manager

        ].

    ].

    "Still no luck, try to auto-configure."

    prjdef notNil ifTrue:[

        prjdir := prjdef packageDirectory.

        (prjdir notNil and:[prjdir isDirectory]) ifTrue:[

            | managers |

            managers := self availableManagers select:[:mgr |

                mgr enabled

                    and:[(mgr isResponsibleForPackage: prjsym)

                    and:[mgr validateWorkingCopy: prjdir] ] .    

            ].

            managers size == 1 ifTrue:[

                manager := managers anElement.

                ManagerForPackageCache at: prjsym put: manager.

                ^manager

            ]

        ].

    ].

    parentPrjId := prjsym asPackageId parentPackage.

    parentPrjId notNil ifTrue:[ 

        ^ self managerForPackage: parentPrjId asSymbol  

    ].

    ^ DefaultManager

    "

     self managerForPackage:'stx:libbasic' 

     self managerForPackage:'stx:libbasic2'

     self managerForPackage:'exept:expecco'  

    "

    "Created: / 18-04-2011 / 19:39:19 / cg"

    "Created: / 10-10-2011 / 14:50:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-10-2011 / 16:45:38 / cg"

    "Modified: / 02-10-2015 / 10:24:41 / jv"

    "Modified: / 04-03-2016 / 15:33:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerPerMatchingModuleDefinitions

    "return the sourceCodeManager definitions"

    ManagerPerModule isNil ifTrue:[

        ManagerPerModule := UserPreferences current managerPerMatchingModuleDefinitions

    ].

    ^ ManagerPerModule

    "Created: / 18-04-2011 / 20:09:16 / cg"

    "Modified: / 09-07-2011 / 13:36:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

managerPerMatchingModuleDefinitions:aCollection

    "set the sourceCodeManager definitions; must be an orderedCollection of packageMatchString -> manager

     associations 

     (not a dictionary, because order is relevant in the matching process, where the first match counts)"

    ManagerPerModule := aCollection.

    UserPreferences current managerPerMatchingModuleDefinitions:aCollection.

    ManagerForPackageCache := Dictionary new.

    "Created: / 18-04-2011 / 20:09:21 / cg"

    "Modified: / 01-10-2015 / 06:04:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

named: managerTypeName

    ^self availableManagers 

        detect:[:each|each managerTypeName = managerTypeName]

        ifNone:[nil]

    "

        AbstractSourceCodeManager named: 'CVS'

        AbstractSourceCodeManager named: 'Perforce'        

    "

    "Created: / 09-07-2011 / 13:51:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

repositoryInfoPerModule

    "return the dictionary, which associates CVSRoots to module names.

     If no entry is contained in this dictionary for some module,

     the default cvsRoot (CVSRoot) will be used."

    ^ #()

    "Created: / 09-11-2006 / 15:25:17 / cg"

!

repositoryInfoPerModule:info

    "/ ignore here

!

repositoryName

    "return the name of the repository.

     Since this is an abstract class, return nil (i.e. none)"

    ^ nil

    "Modified: 12.9.1996 / 02:20:45 / cg"

    "Created: 14.9.1996 / 13:21:37 / cg"

!

repositoryNameForPackage:packageId 

    "Return the repository ULR for the given package. 

     Used for testing/debugging source code management configuration"

    ^ self subclassResponsibility

    "Created: / 10-10-2011 / 19:44:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 21-12-2011 / 23:03:00 / cg"

!

shownInBrowserMenus

    "can be redefined in subclasses which can be suppressed in the browser's menus"

    ^ UserPreferences current at:(self nameWithoutPrefix,'.enabled') ifAbsent:false.

    "Created: / 08-01-2012 / 19:56:22 / cg"

!

shownInBrowserMenus:aBoolean

    "can be redefined in subclasses which can be suppressed in the browser's menus"

    ManagerForPackageCache := Dictionary new.

    ^ UserPreferences current at:(self nameWithoutPrefix,'.enabled') put:aBoolean.

    "Created: / 15-01-2012 / 14:09:21 / cg"

    "Modified: / 01-10-2015 / 06:07:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

useWorkTree

    "return the setting of useWorkTree, which (eventually)

     controls if an up-to-date view of a CVS working tree should be

     kept in sync. This is not yet implemented."

    ^ UseWorkTree

    "Created: 16.12.1995 / 15:36:48 / cg"

    "Modified: 12.9.1996 / 02:24:01 / cg"

!

useWorkTree:aBoolean

    "enable/disable the useWorkTree feature, which (eventually)

     controls if an up-to-date view of a CVS working tree should be

     kept in sync. This is not yet implemented."

    UseWorkTree := aBoolean

    "Created: 16.12.1995 / 15:37:29 / cg"

    "Modified: 12.9.1996 / 02:24:38 / cg"

!

utilities

    "Returns a 'utilities' object that can be used by tools. 

     By default, it returns an instance of

     SourceCodeManagerUtilities with receiver as its

     manager, but individual managers may override this

     method and supply its own, customized utilities."

    ^ (self isContainerBased

            ifTrue: [ SourceCodeManagerUtilitiesForContainerBasedManagers ]

            ifFalse: [ SourceCodeManagerUtilitiesForWorkspaceBasedManagers ]

      ) forManager: self

    "

     SourceCodeManager defaultManager

     SourceCodeManager defaultManager utilities

    "

    "Created: / 10-10-2011 / 15:10:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 25-07-2012 / 17:08:05 / cg"

!

workTreeDirectoryName

    "return the name of the workTree, which is kept in sync

     with the current class versions. This is not yet implemented"

    ^ WorkTreeDirectoryName

    "Created: 16.12.1995 / 15:35:21 / cg"

    "Modified: 12.9.1996 / 02:25:13 / cg"

!

workTreeDirectoryName:aStringOrFilename

    "set the name of the workTree, which is kept in sync

     with the current class versions. This is not yet implemented"

    WorkTreeDirectoryName := aStringOrFilename

    "Created: 16.12.1995 / 15:35:34 / cg"

    "Modified: 12.9.1996 / 02:25:19 / cg"

! !

!AbstractSourceCodeManager class methodsFor:'basic access'!

checkinClass:aClass fileName:classFileName directory:packageDir module:moduleDir source:sourceFile logMessage:logMessage force:force

    "checkin of a class into the source repository.

     Return true if ok, false if not."

    ^ self subclassResponsibility.