Object subclass:#Java

	instanceVariableNames:''

	classVariableNames:'Classes UnresolvedClassRefs ClassPath SourceDirectories

		Java_lang_String Java_lang_Class PrettyPrintStyle'

	poolDictionaries:''

	category:'Java-Support'

!

!Java class methodsFor:'accessing'!

classForName:aString

    "return a javaClass - either existing or loaded"

    |cls|

    cls := self at:aString.

    cls isNil ifTrue:[

        cls := JavaClassReader loadClass:aString.

    ].

    ^ cls

    "Created: 18.3.1997 / 16:45:57 / cg"

!

classNamed:aString

    ^ self at:aString

!

classPath

    ^ ClassPath

    "Created: 7.2.1997 / 19:23:45 / cg"

    "Modified: 7.2.1997 / 19:23:55 / cg"

!

classPath:aCollectionOfPaths

    ClassPath := aCollectionOfPaths asOrderedCollection

    "Created: 7.2.1997 / 19:23:45 / cg"

!

java_lang_Class

    Java_lang_Class isNil ifTrue:[

        Java_lang_Class := self at:'java.lang.Class'

    ].

    ^ Java_lang_Class

    "Created: 26.3.1997 / 13:42:59 / cg"

    "Modified: 26.3.1997 / 13:46:24 / cg"

!

java_lang_String

    Java_lang_String isNil ifTrue:[

        Java_lang_String := self at:'java.lang.String'

    ].

    ^ Java_lang_String

    "Created: 26.3.1997 / 13:43:17 / cg"

    "Modified: 26.3.1997 / 13:50:21 / cg"

!

prettyPrintStyle

    ^ PrettyPrintStyle

    "Created: 1.8.1997 / 10:37:57 / cg"

!

sourceDirectories

    ^ SourceDirectories

!

sourceDirectories:aCollectionOfPaths

    SourceDirectories := aCollectionOfPaths asOrderedCollection

    "

     Java

        sourceDirectories:#(

                            '/phys/ibm3/java/src'

                           )

    "

! !

!Java class methodsFor:'class initialization'!

initAllClasses

     |system|

     self initAllStaticFields.

     system := self at:'java.lang.System'.

     system isInitialized ifFalse:[

         system classInit.

         self initSystemClass.

     ].

     self allClassesDo:[:cls |

        cls isInitialized ifFalse:[

            cls classInit

        ]

     ]

    "Modified: 18.3.1997 / 14:53:46 / cg"

!

initAllStaticFields

     self allClassesDo:[:cls |

        cls initializeStaticFields

     ]

!

initSystemClass

     (Java at:'java.lang.System') invoke:#initializeSystemClass

    "

     Java initSystemClass

    "

    "Modified: 30.7.1997 / 14:08:31 / cg"

!

initialize

    self classPath:#(

                        '/home2/java/jdk1.13/java/lib/classes'

"/                        '/home2/java/jdk1.02/java/lib/classes'

"/                        '/home2/java/JDK/classes'

                    ).

    self

        sourceDirectories:#(

                        '/home2/java/jdk1.13/java/src'

"/                        '/home2/java/jdk1.02/java/src'

"/                        '/home2/java/JDK/src'

                          ).

    self initializePrettyPrintStyle.

     "

      Java initialize

     "

    "Modified: 1.8.1997 / 11:08:52 / cg"

!

initializePrettyPrintStyle

    PrettyPrintStyle := IdentityDictionary new.

    PrettyPrintStyle  at:#accessAttribute put:(#color -> (Color red:0 green:0 blue:25)).

    PrettyPrintStyle  at:#className       put:(Array with:(#color -> Color black) with:#bold).

    PrettyPrintStyle  at:#methodName      put:(Array with:(#color -> Color black) with:#bold).

    PrettyPrintStyle  at:#code            put:(#color -> Color black).

     "

      Java initializePrettyPrintStyle

     "

    "Created: 1.8.1997 / 11:08:43 / cg"

    "Modified: 1.8.1997 / 11:09:58 / cg"

!

reinitAllClasses

     self markAllClassesUninitialized.

     self initAllClasses

! !

!Java class methodsFor:'enumerating'!

allClasses

    ^ Classes

!

allClassesDo:aBlock

    Classes notNil ifTrue:[

        Classes do:aBlock

    ]

! !

!Java class methodsFor:'queries'!

smalltalkClassFor:typeRef

self halt.

"/    (typeString startsWith:'[[') ifTrue:[

"/        ^ Array

"/    ].

"/    (typeString startsWith:'[F') ifTrue:[

"/        ^ FloatArray

"/    ].

    self halt.

    "Modified: 7.4.1997 / 13:33:46 / cg"

!

smalltalkDerefType:typeString

    (typeString startsWith:'[') ifTrue:[

        ^ typeString copyFrom:2

    ].

    self halt.

    "Modified: 7.4.1997 / 13:13:24 / cg"

! !

!Java class methodsFor:'registering java classes'!

at:aJavaName

    "search & return for a class by name;

     if there is no such class, return nil.

     The argument, aJavaName may be either an internal name

     (sep'd by slashes) or an external name (sep'd by periods).

     The 'java/lang' standard packages prefix may be ommitted."

    |sym nm cls|

    Classes isNil ifTrue:[^ nil].

    sym := aJavaName asSymbolIfInterned.

    sym notNil ifTrue:[

        cls := Classes at:sym ifAbsent:nil.

        cls notNil ifTrue:[^ cls].

    ].

    nm := aJavaName.

    (nm includes:$.) ifTrue:[

        nm := (nm asString copy replaceAll:$. by:$/).

        sym := nm asSymbolIfInterned.

        sym notNil ifTrue:[

            cls := Classes at:sym ifAbsent:nil.

            cls notNil ifTrue:[^ cls].

        ].

    ].

    (nm includes:$/) ifFalse:[

        "/

        "/ try java.lang.Foo

        "/

        nm := 'java/lang/' , nm.

        sym := nm asSymbolIfInterned.

        sym notNil ifTrue:[

            cls := Classes at:sym ifAbsent:nil.

            cls notNil ifTrue:[^ cls].

        ].

    ].

    ^ nil

    "

     Java at:'java/lang/String' 

     Java at:'java.lang.String'

     Java at:'String'          

     Java at:'System'            

     Java at:'Foo'               

    "

!

at:aJavaName put:aJavaClass

    |nameSymbol|

    Classes isNil ifTrue:[

        Classes := IdentityDictionary new.

    ].

    nameSymbol := aJavaName asSymbol.

    (Classes includesKey:nameSymbol) ifTrue:[

        ('JAVA: class ' , aJavaName , ' is already loaded') infoPrintCR.

        self updateClassRefsFrom:(Classes at:nameSymbol) to:aJavaClass

    ].

    Classes at:nameSymbol put:aJavaClass.

    nameSymbol == #'java/lang/String' ifTrue:[

        Java_lang_String := aJavaClass

    ].

"/    UnresolvedClassRefs notNil ifTrue:[

"/        UnresolvedClassRefs do:[:toResolve |

"/        ]

"/    ].

    self changed:#classes

    "Created: 17.4.1996 / 23:29:31 / cg"

    "Modified: 26.3.1997 / 13:48:15 / cg"

!

flushAllJavaResources

    self flushClasses.

    ObjectMemory allObjectsDo:[:someObject |

        someObject isBehavior ifTrue:[

            someObject isJavaClass ifTrue:[

                someObject setConstantPool:nil.

                someObject setInterfaces:nil.

                someObject setMethodDictionary:(MethodDictionary new).

someObject fullName printCR.

            ]

        ].

        (someObject isMemberOf:JavaMethod) ifTrue:[

            someObject setJavaClass:nil.

            someObject setExceptionTable:nil.

        ].

        (someObject isMemberOf:JavaUnresolvedClassConstant) ifTrue:[

            someObject constantPool:nil

        ].

    ].

    self flushClasses

    "

     Java flushAllJavaResources

    "

    "Modified: 7.4.1997 / 16:49:23 / cg"

!

flushClasses

    Classes := UnresolvedClassRefs := nil.

    Smalltalk keys copy do:[:aKey | 

        (aKey startsWith:'JAVA::') ifTrue:[ Smalltalk removeKey:aKey ]

    ].

    Java_lang_String := Java_lang_Class := nil.

    JavaInterpreter releaseAllJavaResources.

    JavaUnresolvedConstant flushPatchLists.

    "

     Java flushClasses

    "

    "Modified: 7.4.1997 / 15:25:46 / cg"

!

markAllClassesUninitialized

    self allClassesDo:[:aJavaClass |

        aJavaClass markUninitialized

    ].

    "

     Java markAllClassesUninitialized

    "

!

rememberUnresolved:anUnresolvedClassRef

    ('JAVA: remember unresolved class: ' , anUnresolvedClassRef fullName) infoPrintCR.

    UnresolvedClassRefs isNil ifTrue:[

        UnresolvedClassRefs := Set new.

    ].

    UnresolvedClassRefs add:anUnresolvedClassRef

    "Created: 18.4.1996 / 00:05:31 / cg"

    "Modified: 18.4.1996 / 00:05:41 / cg"

!

removeClass:aJavaClass

    "/ remove it from myself

    |javaName sym nm cls |

    javaName := aJavaClass fullName.

    sym := javaName asSymbolIfInterned.

    sym notNil ifTrue:[

        cls := Classes at:sym ifAbsent:nil.

    ].

    cls isNil ifTrue:[

        nm := javaName.

        (nm includes:$.) ifTrue:[

            "/

            "/ try pckg/.../name

            "/

            nm := (nm asString copy replaceAll:$. by:$/).

            sym := nm asSymbolIfInterned.

            sym notNil ifTrue:[

                cls := Classes at:sym ifAbsent:nil.

            ].

        ].

    ].

    cls notNil ifTrue:[

        Classes removeKey:sym

    ].

"/

    self halt.

    Classes  at:sym put:aJavaClass.

    "Created: 22.3.1997 / 13:44:54 / cg"

    "Modified: 22.3.1997 / 13:48:14 / cg"

!

unresolvedClassRefFor:aClassName

    UnresolvedClassRefs isNil ifTrue:[^ nil].

    ^ UnresolvedClassRefs at:aClassName ifAbsent:nil.

!

updateClassRefsFrom:oldClass to:newClass

    "update all references to oldClass to now refer to newClass.

     sent, when a class is reloaded"

    self halt.

    "Created: 26.3.1997 / 13:49:20 / cg"

! !

!Java class methodsFor:'source management'!

classSourceOf:aClass

    |package dirName binary sourceFileName sourceFile dirHolder fileName path|

    aClass isNil ifTrue:[

        ^ nil

    ].

    package := aClass package.

    "/ first, look in the directory, where the binary

    "/ was loaded from.

    binary := aClass binaryFile asFilename.

    sourceFileName := binary withSuffix:'java'.

    sourceFile := sourceFileName asFilename.

    sourceFile exists ifFalse:[

        sourceFileName := binary withSuffix:'jav'.

        sourceFile := sourceFileName asFilename.

        sourceFile exists ifFalse:[

            sourceFileName := binary withSuffix:'JAV'.

            sourceFile := sourceFileName asFilename.

            sourceFile exists ifFalse:[

                sourceFileName := binary withSuffix:'JAVA'.

                sourceFile := sourceFileName asFilename.

            ].

        ].

    ].

    "/ special case: there were multiple classes in a single

    "/ source file.

    binary withoutSuffix baseName ~= aClass sourceFile asFilename withoutSuffix baseName ifTrue:[

        'JAVA: trouble extracting fileName: ' print.

        binary withoutSuffix baseName print. ' vs. ' print.

        aClass sourceFile asFilename withoutSuffix baseName printCR.

    ].

    "/ if that fails, look in standard places

    sourceFile exists ifFalse:[

        sourceFileName := aClass sourceFile.

        sourceFile := sourceFileName asFilename.

        sourceFile exists ifFalse:[

            "/

            "/ mhmh - look for its directory

            "/

            dirName := sourceFile directoryName.

            fileName := sourceFile baseName.

            (dirName asFilename exists 

            and:[(dirName asFilename construct:(package , '/' , fileName)) exists])

            ifFalse:[

                (dirName asFilename exists 

                and:[(dirName asFilename construct:(fileName)) exists])

                ifFalse:[

                    dirName := self findSourceDirOf:fileName inPackage:package.

    "/                [dirName isNil] whileTrue:[

    "/                    dirName := Dialog requestDirectoryName:'top directory for ' , package , '/' , fileName.

    "/                    (dirName isNil or:[dirName isEmpty]) ifTrue:[^ self].

    "/                ].

                ].

            ].

            (dirName notNil and:[dirName asFilename exists]) ifTrue:[

                path := (dirName asFilename construct:(package , '/' , fileName)) asFilename.

                path exists ifFalse:[

                    path := (dirName asFilename construct:(fileName)) asFilename.

                ].

            ].

            (path notNil and:[path exists]) ifFalse:[

                ^ nil

            ].

            sourceFile := path asFilename.

        ].

    ].

    ^ (sourceFile contentsOfEntireFile).

    "Modified: 30.7.1997 / 14:28:55 / cg"

!