"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

StandardSystemView subclass:#FileBrowser

	instanceVariableNames:'labelView filterField fileListView subView currentDirectory

		fileList checkBlock checkDelta timeOfLastCheck showLongList

		showDotFiles myName killButton pauseToggle compressTabs

		lockUpdate previousDirectory currentFileName timeOfFileRead

		tabSpec commandView commandIndex fileEncoding tabRulerView

		scrollView icons listUpdateProcess'

	classVariableNames:'DirectoryHistory DirectoryHistoryWhere HistorySize DefaultIcon

		CommandHistory CommandHistorySize Icons DefaultCommandPerSuffix'

	poolDictionaries:''

	category:'Interface-Browsers'

!

!FileBrowser class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this used to be a very simple demo application,

    but migrated into a quite nice tool, includes all kinds of 

    warning and information boxes, background processes for directory-

    reading and internationalized strings. A good example for beginners,

    on how to do things .... (and maybe how not to do things ;-, since some

    stuff is historic and was implemented at times when better mechanisms

    were not available)

    See additional information in 'doc/misc/fbrowser.doc'.

    WARNING: files edited with FileBrowser will have leading spaces (multiple-8)

	     being replaced by tabs. If tabs are to be preserved at other

	     positions (for example, sendmail-config files) they will be

	     corrupt after being written.

    [instance variables]:

	checkDelta      <Integer>       number of seconds of check interval

					(looks ever so often if shown directory

					 has changed). You may make this number

					higher, if your network-times are

					incorrect and thus, the filebrowser

					checks too often.

	compressTabs    <Boolean>       if true, leading spaces will be

					replaced by tabs when saving text

    some of the defaults (long/short list etc.) can be set by the resource file;

    see FileBrowser>>initialize for more details..

    [author:]

	Claus Gittinger

"

! !

!FileBrowser class methodsFor:'instance creation'!

openOn:aDirectoryPath

    "start a new FileBrowser in a pathname"

    ^ (self new currentDirectory:aDirectoryPath) open

    "

     FileBrowser openOn:'aDirectoryPath'

     FileBrowser openOn:'/etc'

     FileBrowser openOn:'..'

     FileBrowser openOn:'.'

    "

!

openOnFileNamed:aFilename

    "start a new FileBrowser on a file"

    |f browser|

    f := aFilename asFilename.

    f isDirectory ifTrue:[

	^ self openOn:aFilename

    ].

    browser := self new.

    browser currentDirectory:f directoryName.

    browser showFile:f baseName.

    ^ browser open

    "

     FileBrowser openOnFileNamed:'Makefile'

     FileBrowser openOnFileNamed:'../Makefile'

     FileBrowser openOnFileNamed:'/tmp/foo'

    "

    "Modified: 6.4.1997 / 14:57:12 / cg"

! !

!FileBrowser class methodsFor:'class initialization'!

initializeIcons

    |resources|

    resources := self classResources.

    Icons := IdentityDictionary new.

    #(

	(#directory       'ICON_DIRECTORY'        'tiny_yellow_dir.xpm'       )

	(#directoryLocked 'ICON_DIRECTORY_LOCKED' 'tiny_yellow_dir_locked.xpm')

	(#directoryLink   'ICON_DIRECTORY_LINK'   'tiny_yellow_dir_link.xpm'  )

	(#file            'ICON_FILE'             'tiny_file_plain.xpm'       )

	(#fileLink        'ICON_FILE_LINK'        'tiny_file_link.xpm'        )

	(#fileLocked      'ICON_FILE_LOCKED'      'tiny_file_lock.xpm'        )

	(#imageFile       'ICON_IMAGE_FILE'       'tiny_file_pix.xpm'         )

	(#textFile        'ICON_TEXT_FILE'        'tiny_file_text.xpm'         )

     ) do:[:entry |

	|key resource defaultName nm|

	key := entry at:1.

	resource := entry at:2.

	defaultName := entry at:3.

	nm := resources at:resource default:nil.

	nm isNil ifTrue:[

	    nm := 'bitmaps/xpmBitmaps/document_images/' , defaultName

	].

	Icons at:key put:(Image fromFile:nm).

    ]

    "

     self initializeIcons

    "

    "Modified: 28.7.1997 / 09:19:45 / cg"

! !

!FileBrowser class methodsFor:'command history'!

addToCommandHistory:aCommandString for:aFilename

    |cmd suffix|

    (aCommandString notNil and:[aCommandString notEmpty]) ifTrue:[

	CommandHistory notNil ifTrue:[

	    CommandHistory addFirst:aCommandString.

	    CommandHistory size > CommandHistorySize ifTrue:[

		CommandHistory removeLast

	    ]

	].

	aFilename notNil ifTrue:[

	    cmd := aCommandString copyTo:(aCommandString indexOf:Character space ifAbsent:[aCommandString size + 1])-1.

	    DefaultCommandPerSuffix isNil ifTrue:[

		DefaultCommandPerSuffix := Dictionary new.

	    ].

	    suffix := aFilename asFilename suffix.

	    suffix notNil ifTrue:[

		DefaultCommandPerSuffix at:suffix put:cmd.

	    ]

	]

    ]

    "Created: 14.11.1996 / 14:58:13 / cg"

! !

!FileBrowser class methodsFor:'defaults'!

defaultIcon

    "return the file browsers default window icon"

    <resource: #style (#FILEBROWSER_ICON #FILEBROWSER_ICON_FILE)>

    |nm i res|

    (i := DefaultIcon) isNil ifTrue:[

	res := self classResources.

	i := res at:'FILEBROWSER_ICON' default:nil.

	i isNil ifTrue:[

	    nm := res at:'FILEBROWSER_ICON_FILE' default:'FBrowser.xbm'.

	    i := Image fromFile:nm resolution:100.

	    i isNil ifTrue:[

		i := Image fromFile:('bitmaps/' , nm) resolution:100.

		i isNil ifTrue:[

		    i := StandardSystemView defaultIcon

		]

	    ]

	].

	i notNil ifTrue:[

	    DefaultIcon := i := i on:Display

	]

    ].

    ^ i

    "Modified: 19.3.1997 / 20:48:34 / ca"

    "Modified: 15.8.1997 / 15:27:19 / cg"

! !

!FileBrowser methodsFor:'drag & drop'!

canDrop:aCollectionOfDropObjects

    "I accept fileObjects only"

    aCollectionOfDropObjects do:[:aDropObject |

	aDropObject isFileObject ifFalse:[

	    aDropObject isTextObject ifFalse:[^ false].

	]

    ].

    ^ true

    "Modified: 11.4.1997 / 12:41:59 / cg"

!

drop:aCollectionOfDropObjects at:aPoint

    "handle drops"

    aCollectionOfDropObjects do:[:aDropObject |

	self dropSingleObject:aDropObject at:aPoint

    ]

    "Modified: 11.4.1997 / 12:43:36 / cg"

!

dropSingleObject:someObject at:aPoint

    "handle drops; if its a directory, change to it.

     If its a file, change to its directory and select the file.

     If its text, paste it into the codeView."

    |newDir newFile|

    someObject isFileObject ifTrue:[

	someObject isDirectory ifTrue:[

	    newDir := someObject theObject pathName.

	] ifFalse:[

	    newDir := someObject theObject directoryName.

	    newFile := someObject theObject baseName.

	].

	newDir notNil ifTrue:[

	    newDir ~= currentDirectory pathName ifTrue:[

		self changeDirectoryTo:newDir.

	    ]

	].

	newFile notNil ifTrue:[

	    newFile ~= currentFileName ifTrue:[

		fileListView selection:(fileList indexOf:newFile).

		self doFileGet:false.

	    ]

	].

	^ self

    ].

    someObject isTextObject ifTrue:[

	subView paste:someObject theObject.

	^ self

    ].

    "Modified: 6.4.1997 / 14:46:44 / cg"

! !

!FileBrowser methodsFor:'events'!

handlesKeyPress:key inView:view

    "this method is reached via delegation: are we prepared to handle

     a keyPress in some other view ?"

    <resource: #keyboard (#GotoLine #InspectIt #CmdI #Cmdu #DoIt #Delete #BackSpace #Accept)>

    view == fileListView ifTrue:[

	(key == #Delete 

	or:[key == #BackSpace

	or:[key == #Accept

	or:[key == #CmdI

	or:[key == #Cmdu

	or:[key == #InspectIt

	or:[key == #GotoLine

	or:[key == #DoIt]]]]]]]) ifTrue:[^ true].

    ].

    ^ false

    "Created: 28.1.1997 / 14:03:20 / stefan"

    "Modified: 28.1.1997 / 15:03:30 / stefan"

    "Modified: 20.6.1997 / 16:35:01 / cg"

!

keyPress:key x:x y:y view:view

    "this method is reached via delegation from the fileListView"

    <resource: #keyboard (#GotoLine #InspectIt #CmdI #Cmdu #DoIt #Delete #BackSpace #Accept)>

    (key == #Delete or:[key == #BackSpace]) ifTrue:[

	self fileRemove.

	^ self

    ].

    (key == #Accept) ifTrue:[

	self fileFileIn.

	^ self

    ].

    (key == #GotoLine) ifTrue:[

	self fileGet.

	^ self

    ].

    (key == #DoIt) ifTrue:[

	self fileExecute.

	^ self

    ].

    (key == #InspectIt) ifTrue:[

	self fileGetInfo.

	^ self

    ].

    (key == #CmdI) ifTrue:[

	self fileGetLongInfo.

	^ self

    ].

    (key == #Cmdu) ifTrue:[

	self updateCurrentDirectory.

	^ self

    ].

    fileListView keyPress:key x:x y:y

    "Created: 28.1.1997 / 14:03:56 / stefan"

    "Modified: 28.1.1997 / 15:03:56 / stefan"

    "Modified: 20.6.1997 / 16:35:08 / cg"

!

mapped 

    super mapped.

    "

     whant to know about changed history

    "

    self updateCurrentDirectory

!

visibilityChange:how

    |wasVisible|

    wasVisible := shown.

    super visibilityChange:how.

    (wasVisible not and:[shown]) ifTrue:[

	"

	 start checking again

	"

	Processor removeTimedBlock:checkBlock.

	Processor addTimedBlock:checkBlock afterSeconds:checkDelta.

    ]

! !

!FileBrowser methodsFor:'fileList user interaction'!

changeDisplayMode

    "toggle from long to short listing (and vice-versa)"

    showLongList := showLongList not.

    self showOrHideTabView.

    self updateCurrentDirectory

    "Modified: 19.4.1997 / 09:50:14 / cg"

!

changeDotFileVisibility

    "turn on/off visibility of files whose name starts with '.'"

    showDotFiles := showDotFiles not.

    self updateCurrentDirectory

!

fileDoubleClick:lineNr

    "double click on a file - get its contents"

    self fileSelect:lineNr.

    self fileGet:true

!

fileEncoding

    "open a dialog to allow change of the files character encoding.

     Files are converted to internal encoding when read, and converted back

     to this encoding when saved.

     The default encoding is nil, which means that files are already in

     the internal encoding (which is iso8859).

     Notice: currently, not too many encodings are supported by the system."

    |dialog list descr encodings encodingNames idx|

    list := SelectionInList new.

    descr := CharacterArray supportedExternalEncodings.

    encodings := descr at:2.

    encodingNames := descr at:1.

    list list:encodingNames.

    list selectionIndex:(encodings indexOf:fileEncoding ifAbsent:1).

    dialog := Dialog new.

    dialog addTextLabel:(resources string:'ENCODING_MSG') withCRs.

    dialog addVerticalSpace.

    dialog addListBoxOn:list withNumberOfLines:5.

    dialog addAbortButton; addOkButton.

    dialog open.

    dialog accepted ifTrue:[

	idx := list selectionIndex.

	fileEncoding := encodings at:idx.

	subView externalEncoding:fileEncoding.

	self validateFontEncodingFor:fileEncoding ask:true.

    ].

    "Modified: 30.6.1997 / 14:41:12 / cg"

!

fileExecute

    "if text was modified show a queryBox,

     otherwise pop up execute box immediately"

    |action sel fileName|

    "

     this replaces everything by the commands output ...

    "

    action := [:command | 

		self class addToCommandHistory:command for:fileName.

		self doExecuteCommand:command replace:true

	      ].

    (self askIfModified:'contents has not been saved.\\Modifications will be lost when command is executed.'

	      yesButton:'execute') ifFalse:[^ self].

"/    "

"/     this inserts the commands output ...

"/    "

"/    action := [:command| self doExecuteCommand:command replace:false].

"/

    sel := fileListView selection.

    sel size == 1 ifTrue:[

	fileName := fileList at:sel first

    ].

    self askForCommandFor:fileName thenDo:action

    "Modified: 14.11.1996 / 14:59:34 / cg"

!

fileFileIn

    "fileIn the selected file(s)"

    self fileFileInLazy:false 

!

fileFileInLazy

    "fileIn the selected file(s). Do a quick load (no compilation)"

    self fileFileInLazy:true 

!

fileFileInLazy:lazy

    "fileIn the selected file(s)"

    |aStream path oldPath wasLazy bos|

    self selectedFilesDo:[:fileName |

	path := currentDirectory filenameFor:fileName.

	path type == #regular ifTrue:[

	    (ObjectFileLoader notNil

	    and:[ObjectFileLoader hasValidBinaryExtension:fileName]) ifTrue:[

		Object abortSignal catch:[

		    |p|

		    "/

		    "/ look if already loaded ...  then unload first

		    "/