"

 COPYRIGHT (c) 1989 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

SimpleView subclass:#InspectorView

	instanceVariableNames:'listView labelView workspace inspectedObject selectedLine nShown

		hasMore monitorProcess hideReceiver integerDisplayRadix

		inspectHistory allowFollow isStandaloneInspector selectionIndex

		object inspectedObjectHolder displayStringMessage

		suppressPseudoSlots dereferenceValueHolders suppressHeadline

		headLineLabel'

	classVariableNames:'DefaultIcon IdDictionary NextSequentialID LastExtent

	poolDictionaries:''

	category:'Interface-Inspector'

!

!InspectorView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class implements a graphical inspector.

    Inspecting can be done on an object -

    (where its instvarnames/values are inspected)

    or a list of objects (where a nameArray/valuesArray is inspected).

    The later is used by the debugger to inspect method variables/args.

    The system calls the inspector through the global variable 'Inspector'

    which is bound to this class (but could be redefined - it actually is

    set to MiniInspector in a smalltalk without graphical user interface,

    or to NewInspector if that is wanted).

    Also notice, that there are two methods to inspect an object:

    sending #basicInspect to any object, will open this kind of inspector on 

    it (showing instance variables which are physically present).

    Sending it #inspect, will - depending on the object - sometimes invoke a

    specialized inspector. 

    (see OrderedCollectionInspectorView, ImageInspectorView, 

     ColorInspectorView etc. as examples).

    You can also open a monitoring inspector, which displays some instance

    variable in regular intervals. See #openOn:monitor:.

    examples:

            #(1 2 3 4) asOrderedCollection inspect

            #(1 2 3 4) asOrderedCollection basicInspect

            (Array new:10000) inspect

            (Image fromFile:'bitmaps/claus.gif') inspect

            (Image fromFile:'bitmaps/claus.gif') basicInspect

            (Image fromFile:'bitmaps/SBrowser.xbm') inspect

            (Image fromFile:'bitmaps/SBrowser.xbm') basicInspect

            InspectorView openOn:Display

            InspectorView openOn:Display monitor:'shiftDown'

    The InspectorView can also be used as a subComponent within another view.

    In this case, the isStandAlone flag should be cleared, to prevent the

    inspector from changing the topViews window label.

    Notice:

        the instvars 'inspectedObject' and 'selectedLine' have been 

        renamed to 'object' and 'selectionIndex' for squeak compatibility;

        however, the old vars are kept (in sync) for a while, to allow for

        smooth migration.

  Controlling the contents from the inspected object.

    By redefining inspectorExtraAttributes or inspectorExtraNamedFields, the inspected

    object can add items to the list of fields as ashown in the left list-view of the inspector.

    These methods are meant to return a sequencable Collection of Associations, which represent

    of pseudo slot-name, slot-value pairs.

    In the list, extra attributes are shown with a dash (-), extra named fields are marked with a tick (`).

    These are added (read only) to the list.

    [author:]

        Claus Gittinger

"

! !

!InspectorView class methodsFor:'instance creation'!

for:anObject

    "create and launch a new inspector for anObject.

     This protocol is a historic leftover - this method will vanish."

    ^ self openOn:anObject

!

inspect:anObject

    "create and launch a new inspector for anObject.

     This protocol is a historic leftover - this method will vanish."

    ^ self openOn:anObject

!

openOn:anObject

    "create and launch a new inspector for anObject"

    ^ self openOn:anObject monitor:nil

    "

     InspectorView openOn:(5 @ 7)

     InspectorView openOn:(Array new:400)

     DictionaryInspectorView openOn:(IdentityDictionary new)

    "

    "Modified: 1.3.1996 / 19:31:03 / cg"

!

openOn:anObject monitor:anInstVarNameOrNil

    "create and launch a new inspector for anObject.

     If anInstVarNameOrNil is nonNil, let the inspector monitor it

     (use an integer-printString as name, for indexed instVars)."

    |topView inspectorView|

    topView := StandardSystemView new.

    topView

        icon:self defaultIcon;

        label:'Inspector';

        iconLabel:'Inspector';  

        extent:self defaultTopViewExtent;

        objectAttributeAt:#rememberExtent put:true.

    inspectorView := self origin:(0.0 @ 0.0)

                          corner:(1.0 @ 1.0)

                             in:topView.

    "kludge: must realize first, to be able to set menu again"

    topView openAndWait.

    topView windowGroup 

        focusSequence:(Array 

                            with:inspectorView listView

                            with:inspectorView workspace).

    inspectorView 

        allowFollow:true;

        isStandaloneInspector:true;

        inspect:anObject.

    anInstVarNameOrNil notNil ifTrue:[

        inspectorView monitor:anInstVarNameOrNil

    ].

    ^ inspectorView

    "

     |m|

     m := 1 asValue.

     InspectorView openOn:m monitor:'value'.

     2 to:10 do:[:i |

         Delay waitForSeconds:1.

         m value:i

     ]

    "

    "

     |o|

     o := Array with:1 with:2 with:3.

     InspectorView openOn:o monitor:'2'.

     Delay waitForSeconds:1.

     o at:2 put:20

    "

    "Created: / 01-03-1996 / 19:30:50 / cg"

    "Modified: / 23-10-2007 / 19:08:21 / cg"

!

openOn:anObject withEvalPane:withEvalPane

    ^ self openOn:anObject

!

openOn:anObject withEvalPane:withEvalPane withLabel:aLabel

    ^ self openOn:anObject

! !

!InspectorView class methodsFor:'common label support'!

commonLabelFor:anObject

    "return the windowLabel to use in my topView, when inspecting anObject.

     Identical objects are labelled with the same id, which makes it easy to

     see if two objects are identical (and is very useful, indeed).

     WARNING: used by both Inspector and Inspector2 !!!!!!"

    |lbl id|

    lbl := ''.

    (anObject isImmediate

    or:[anObject isBoolean]) ifFalse:[

        lbl := '<%2> ' 

    ].

    lbl := lbl , '%1'.

    IdDictionary isNil ifTrue:[

        IdDictionary := WeakIdentityDictionary new.

    ].

    [    

        id := IdDictionary 

                    at:anObject 

                    ifAbsentPut:[ 

                        |nextID|

                        nextID := NextSequentialID ? 0.

                        NextSequentialID := nextID + 1.

                        nextID

                    ].

    ] valueUninterruptably.

    ^ self classResources 

        string:lbl 

        with:(self labelNameFor:anObject)

        with:id

    "Created: / 15-07-2011 / 16:21:44 / cg"

!

labelNameFor:anObject

    "return the iconLabel to use in my topView, when inspecting anObject.

     Simply returns the className or name of anObjects class"

    |s|

    anObject isClass ifTrue:[

        s := anObject displayString

    ] ifFalse:[

        (anObject isImmediate

         or:[anObject isBoolean]) ifTrue:[

            s := anObject printString , ', ' , anObject classNameWithArticle

        ] ifFalse:[

            s := anObject classNameWithArticle

        ].

    ].

    s isNil ifTrue:[

        anObject isBehavior ifTrue:[

            ^ 'someBehavior'

        ].

        ^ 'something'

    ].

    ^ s

    "Created: / 15-07-2011 / 16:20:06 / cg"

! !

!InspectorView class methodsFor:'defaults'!

defaultExtent

    ^ (Screen current usableExtent // 3)

    "Created: / 7.9.1998 / 13:47:45 / cg"

    "Modified: / 7.9.1998 / 14:15:38 / cg"

!

defaultIcon

    "return the browsers default window icon"

    <resource: #programImage>

    <resource: #style (#INSPECTOR_ICON #INSPECTOR_ICON_FILE)>

    |nm i resources|

    (i := DefaultIcon) isNil ifTrue:[

        resources := self classResources.

        i := resources at:#INSPECTOR_ICON default:nil.

        i isNil ifTrue:[

            nm := resources at:#INSPECTOR_ICON_FILE default:'Inspector.xbm'.

            i := Smalltalk imageFromFileNamed:nm forClass:self.

            i isNil ifTrue:[

                i := StandardSystemView defaultIcon

            ]

        ].

        i notNil ifTrue:[

            DefaultIcon := i := i onDevice:Display

        ]

    ].

    ^ i

    "

       DefaultIcon := nil

    "

    "Modified: / 17-09-2007 / 11:36:17 / cg"

!

defaultTopViewExtent

    |def|

    def := LastExtent ? self defaultExtent.

    ^ def min:(Screen current usableExtent)

    "Created: / 23-10-2007 / 19:04:13 / cg"

!

rememberLastExtent:anExtent

    LastExtent := anExtent

    "Created: / 23-10-2007 / 19:10:02 / cg"

! !

!InspectorView class methodsFor:'queries-plugin'!

aspectSelectors

    ^ #( inspectedObjectHolder )

    "Modified: / 10.2.2000 / 12:25:28 / cg"

! !

!InspectorView methodsFor:'accessing'!

allowFollow:aBoolean

    "enable/disable the follow menu item;

     This is disabled for inspectors which are embedded in the debugger"

    allowFollow := aBoolean

!

dereferenceValueHolders:aBoolean

    dereferenceValueHolders := aBoolean

!

fieldListLabel:aString

    labelView label:aString

    "Created: 28.6.1996 / 15:30:26 / cg"

!

headLineLabel:aString

    "an alternative headline label (if used as embedded inspector)"

    headLineLabel := aString.

    labelView notNil ifTrue:[

        labelView label:headLineLabel.

    ].

    "Modified: / 25-11-2010 / 17:16:45 / cg"

!

headLineLabelView

    "provides access to the headline"

    ^ labelView

    "Created: / 21-01-2011 / 12:07:13 / cg"

!

hideReceiver:aBoolean

    "hide/show the self-entry for the inspected object;

     This is hidden for context inspectors in the debugger"

    hideReceiver := aBoolean

    "Created: 28.6.1996 / 15:08:32 / cg"

!

inspect:anObject

    "set/update the object to be inspected"

    |aList sameObject sameClass oldSelectedField idx|

    "/ (anObject isNil and:[object isNil]) ifTrue:[^ self].

    sameObject := (anObject == object) and:[object notNil].

    "/ JV@2011-08-06: Be carefull here, classes may be variable-lenght,

    "/ so instances of same class may have different number of slots!!

    "/ (caused problems expecially when stack inspector is shown in debugger).

    "/ To fix, I've added ------------------------v

    sameClass := (anObject class == object class) and:[anObject class isVariable not].

    selectionIndex notNil ifTrue:[

        oldSelectedField := (listView list ? #()) at:selectionIndex ifAbsent:nil.

    ].

    inspectedObject := object := anObject.

    ((sameObject | sameClass) and:[listView list notEmptyOrNil]) ifTrue:[

"/        listView setContents:aList.

    ] ifFalse:[

        hasMore := false.

        aList := self fieldList.                               

        hasMore ifTrue:[

            aList add:' ... '

        ].

        listView contents:aList.

        workspace contents:nil.

        self setDoItAction.

    ].

    sameClass ifFalse:[

        selectionIndex := selectedLine := nil.

    ].

    isStandaloneInspector ifTrue:[

        "/ not embedded (as in the debugger)

        self topView 

            label:(self labelFor:anObject);

            iconLabel:(self class labelNameFor:anObject).

    ].

    (sameObject | sameClass) ifFalse:[

        idx := (listView list ? #()) indexOf:oldSelectedField.

        idx ~~ 0 ifTrue:[

            listView selection:idx

        ] ifFalse:[

            self setInitialSelection.

        ]

    ].

    self showSelection:((selectedLine ? 1) min: listView list size)

    "Modified: / 15-07-2011 / 16:20:32 / cg"

    "Modified (comment): / 06-08-2011 / 13:41:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isStandaloneInspector:aBoolean

    "obsolete now"

    isStandaloneInspector := aBoolean

    "Modified: / 12.2.1999 / 16:01:44 / cg"

!

label:aString

    "set the fieldListLabel - obsolete; collides with inherited label-functionality"

    <resource:#obsolete>

    self obsoleteMethodWarning:'use fieldListLabel:'.

    self fieldListLabel:aString.

    super label:aString.

    "Created: 28.6.1996 / 15:30:26 / cg"

!

listView

    ^ listView

!

reinspect

    "update display for a changed inspectedObject"

    |aList|

    hasMore := false.