"

 COPYRIGHT (c) 1991 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

StandardSystemView subclass:#FileBrowser

	instanceVariableNames:'menuPanel labelView filterField fileListView subView

		currentDirectory fileList checkBlock checkDelta timeOfLastCheck

		myName killButton pauseToggle compressTabs lockUpdate

		previousDirectory currentFileName timeOfFileRead tabSpec

		commandView commandIndex fileEncoding tabRulerView scrollView

		icons matchedIcons listUpdateProcess currentFileInFileName

		lastFileDiffDirectory sortByWhat sortCaseless showingDetails

		showingTimeAndDate showingHiddenFiles showingBigImagePreview

		imagePreviewView imageRenderProcess dosEOLMode doAutoUpdate

		doNotShowFontDialog lastEnforcedNameSpace'

	classVariableNames:'DirectoryBookmarks HistorySize DefaultIcon CommandHistory

		CommandHistorySize Icons MatchedIcons DefaultCommandPerSuffix

		VisitedFileHistory LastEnforcedNameSpace'

	poolDictionaries:''

	category:'Interface-Tools-File'

!

!FileBrowser class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1991 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this used to be a very simple demo application,

    but migrated into a quite nice tool, includes all kinds of 

    warning and information boxes, background processes for directory-

    reading and internationalized strings. A good example for beginners,

    on how to do things .... (and maybe how not to do things ;-, since some

    stuff is historic and was implemented at times when better mechanisms

    were not available)

    See additional information in 'doc/misc/fbrowser.doc'.

    WARNING: files edited with FileBrowser will have leading spaces (multiple-8)

             being replaced by tabs. If tabs are to be preserved at other

             positions (for example, sendmail-config files) they will be

             corrupt after being written.

    [instance variables]:

        checkDelta      <Integer>       number of seconds of check interval

                                        (looks ever so often if shown directory

                                         has changed). You may make this number

                                        higher, if your network-times are

                                        incorrect and thus, the filebrowser

                                        checks too often.

        compressTabs    <Boolean>       if true, leading spaces will be

                                        replaced by tabs when saving text

    some of the defaults (long/short list etc.) can be set by the resource file;

    see FileBrowser>>initialize for more details..

    [author:]

        Claus Gittinger

    [start with:]

        FileBrowser open

"

! !

!FileBrowser class methodsFor:'instance creation'!

on:aDirectoryPath

    "return a new FileBrowser in a pathname"

    ^ (self new currentDirectory:aDirectoryPath)

    "

     (FileBrowser on:'/usr/local/bin') open

     (FileBrowser on:'/etc'          ) open

     (FileBrowser on:'..'            ) open

     (FileBrowser on:'.'             ) open

    "

!

openOn:aDirectoryPath

    "start a new FileBrowser in a pathname"

    ^ (self on:aDirectoryPath) open

    "

     FileBrowser openOn:'/etc'

     FileBrowser openOn:'..'

     FileBrowser openOn:'.'

    "

!

openOn:aDirectoryPath withExtent:extent

    "start a new FileBrowser in a pathname"

    ^ (self on:aDirectoryPath) openWithExtent:extent

    "

     FileBrowser openOn:'/etc'           withExtent:200@300

     FileBrowser openOn:'..'             withExtent:200@300

     FileBrowser openOn:'.'              withExtent:200@300

    "

!

openOnFileNamed:aFilename

    "start a new FileBrowser on a file"

    |f browser|

    f := aFilename asFilename.

    f isDirectory ifTrue:[

        ^ self openOn:aFilename

    ].

    browser := self on:f directoryName.

    browser updateCurrentDirectory.

    browser showFile:f baseName.

    ^ browser open.

    "

     FileBrowser openOnFileNamed:'Makefile'

     FileBrowser openOnFileNamed:'../Makefile'

     FileBrowser openOnFileNamed:'/tmp/foo'

    "

    "Modified: / 17.6.1998 / 11:25:29 / cg"

! !

!FileBrowser class methodsFor:'aspects'!

directoryHistory

    ^ AbstractFileBrowser directoryHistory.

! !

!FileBrowser class methodsFor:'class initialization'!

icons

    Icons isNil ifTrue:[

        self initializeIcons

    ].

    ^ Icons

!

initializeFileTypeIcons

    |resources|

    resources := self classResources.

    #(

        "/ internal-type to icon mappings.

        (#directory             'ICON_DIRECTORY'            'tiny_yellow_dir.xpm'            )

        (#directoryOpen         'ICON_DIRECTORY_OPEN'       'tiny_yellow_dir_open.xpm'       )

        (#directoryLocked       'ICON_DIRECTORY_LOCKED'     'tiny_yellow_dir_locked.xpm'     )

        (#directoryLink         'ICON_DIRECTORY_LINK'       'tiny_yellow_dir_link.xpm'       )

        (#directoryNetwork      'ICON_DIRECTORY_NETWORK'    'tiny_yellow_dir_network.xpm'    )

        (#file                  'ICON_FILE'                 'tiny_file_plain.xpm'            )

        (#fileLink              'ICON_FILE_LINK'            'tiny_file_link.xpm'             )

        (#fileLocked            'ICON_FILE_LOCKED'          'tiny_file_lock.xpm'             )

        (#imageFile             'ICON_IMAGE_FILE'           'tiny_file_pix.xpm'              )

        (#textFile              'ICON_TEXT_FILE'            'tiny_file_text.xpm'             )

        (#executableFile        'ICON_EXECUTABLEFILE'       'tiny_file_exec.xpm'             )

        (#deviceFile            'ICON_DEVICE_FILE'          'tiny_file_device.xpm'           )

        (#binaryFile            'ICON_BINARY_FILE'          'tiny_file_binary.xpm'           )

        (#specialFile           'ICON_SPECIALFILE'          'tiny_file_special.xpm'          )

        (#addOnLocked           'ICON_ADDON_LOCKED'         'tiny_addOn_lock.xpm'            )

        (#addOnLinked           'ICON_ADDON_LINKED'         'tiny_addOn_link.xpm'            )

        (#directoryGray         'ICON_DIRECTORY_GRAY'       'tiny_yellow_dir_gray.xpm'       )

        (#directoryOpenGray     'ICON_DIRECTORY_OPEN_GRAY'  'tiny_yellow_dir_open_gray.xpm'  )

     ) do:[:entry |

        |key resource defaultName nm img|

        key := entry at:1.

        resource := entry at:2.

        defaultName := entry at:3.

        resource notNil ifTrue:[

            nm := resources at:resource default:nil.

        ].

        nm isNil ifTrue:[

            nm := 'xpmBitmaps/document_images/' , defaultName

        ].

        Icons at:key put:(Smalltalk imageFromFileNamed:nm forClass:self).

    ]

    "

     self initializeFileTypeIcons

    "

!

initializeIcons

    Icons := Dictionary new.

    MatchedIcons := OrderedCollection new.

    self initializeFileTypeIcons.

    self initializeMimeTypeIcons.

    "

     self initializeIcons

    "

    "Modified: / 1.8.1998 / 17:39:27 / cg"

!

initializeMimeTypeIcons

    #(

        "/ mime-type to icon mappings.

"/        'image/jpeg'                                    'tiny_file_pix.xpm'

"/        'image/gif'                                     'tiny_file_pix.xpm'

"/        'image/tiff'                                    'tiny_file_pix.xpm'

"/        'image/x-xbitmap'                               'tiny_file_pix.xpm'

"/        'image/x-xpixmap'                               'tiny_file_pix.xpm'

"/        'image/x-png'                                   'tiny_file_pix.xpm'

"/        'image/x-photo-cd'                              'tiny_file_pix.xpm'

"/        'image/x-MS-bmp'                                'tiny_file_pix.xpm'

"/        'image/x-rgb'                                   'tiny_file_pix.xpm'

"/        'image/x-portable-pixmap'                       'tiny_file_pix.xpm'

"/        'image/x-portable-graymap'                      'tiny_file_pix.xpm'

"/        'image/x-portable-bitmap'                       'tiny_file_pix.xpm'

"/        'image/x-portable-anymap'                       'tiny_file_pix.xpm'

"/        'image/x-xwindowdump'                           'tiny_file_pix.xpm'

"/        'image/x-cmu-raster'                            'tiny_file_pix.xpm'

"/        'image/x-targa'                                 'tiny_file_pix.xpm'

        'image/*'                                       'tiny_file_pix.xpm'

        "/ misc text ...

        'text/html'                                     'tiny_file_html.xpm'

"/        'text/plain'                                    'tiny_file_text.xpm'

        'text/*'                                        'tiny_file_text.xpm'

        'application/postscript'                        'tiny_file_postscript.xpm'

        'application/pdf'                               'tiny_file_pdf.xpm'

        'application/rtf'                               'tiny_file_rtf.xpm'

        "/ video formats ...

"/        'video/x-sgi-movie'                             'tiny_file_movie.xpm'

"/        'video/x-msvideo'                               'tiny_file_movie.xpm'

"/        'video/quicktime'                               'tiny_file_movie.xpm'

"/        'video/x-mpeg2'                                 'tiny_file_movie.xpm'

"/        'video/mpeg'                                    'tiny_file_movie.xpm'

        'video/*'                                       'tiny_file_movie2.xpm'

        'application/vnd.rn-realmedia'                  'tiny_file_movie2.xpm'

        "/ audio formats ...

"/        'audio/x-pn-realaudio'                          'tiny_file_sound.xpm'

"/        'audio/x-mpeg'                                  'tiny_file_sound.xpm'

"/        'audio/x-mp3'                                   'tiny_file_sound.xpm'

"/        'audio/x-wav'                                   'tiny_file_sound.xpm'

"/        'audio/x-aiff'                                  'tiny_file_sound.xpm'

"/        'audio/basic'                                   'tiny_file_sound.xpm'

"/        'audio/x-shockwave-flash'                       'tiny_file_sound.xpm'

        'audio/*'                                       'tiny_file_sound.xpm'

        "/ misc stuff

        'application/winword'                           'tiny_file_text.xpm'

        "/ binary formats

        'application/binary'                            'tiny_file_binary.xpm'

        'application/library'                           'tiny_file_binary.xpm'

        'application/shared-library'                    'tiny_file_binary.xpm'

        "/ progr. languages

        'application/x-smalltalk-source'                'tiny_file_st.xpm'

        'application/x-smalltalk-source-sif'            'tiny_file_text.xpm'

        'application/x-c-source'                        'tiny_file_text.xpm'

        'application/x-c-header'                        'tiny_file_text.xpm'

        'application/x-cpp-source'                      'tiny_file_text.xpm'

        'application/x-javascript'                      'tiny_file_text.xpm'

        'application/x-java-source'                     'tiny_file_java.xpm'

        'application/x-sh'                              'tiny_file_text.xpm'

        'application/x-csh'                             'tiny_file_text.xpm'

        'application/x-tcl'                             'tiny_file_text.xpm'

        'application/x-perl'                            'tiny_file_text.xpm'

        'application/x-make'                            'tiny_file_text.xpm'

        'application/x-batch-script'                    'tiny_file_text.xpm'

        'application/x-asn1-source'                     'tiny_file_text.xpm'

        "/ compressors / archivers

        'application/x-tar'                           'tiny_file_archive.xpm'

        'application/x-gtar'                          'tiny_file_archive.xpm'

        'application/x-tar-compressed'                'tiny_file_compressed_archive.xpm'

        'application/x-zip-compressed'                'tiny_file_compressed_archive.xpm'

        'application/x-gzip-compressed'               'tiny_file_compressed_archive.xpm'

        'application/x-cpio'                          'tiny_file_archive.xpm'

        'application/x-shar'                          'tiny_file_archive.xpm'

        'application/java-archive'                    'tiny_file_archive.xpm'

        '*'                                           'tiny_file_plain.xpm'

     ) pairWiseDo:[:mimeTypePattern :fileName |

        | nm |

        nm := 'xpmBitmaps/document_images/' , fileName.

        mimeTypePattern includesMatchCharacters ifTrue:[

            MatchedIcons add:(mimeTypePattern-> (Smalltalk imageFromFileNamed:nm forClass:self)).

        ] ifFalse:[    

            Icons at:mimeTypePattern put:(Smalltalk imageFromFileNamed:nm forClass:self).

        ]

    ]

    "

     self initializeIcons

    "

! !

!FileBrowser class methodsFor:'defaults'!

defaultIcon

    "return the file browsers default window icon"

    <resource: #style (#FILEBROWSER_ICON #FILEBROWSER_ICON_FILE)>

    |nm i res|

    (i := DefaultIcon) isNil ifTrue:[

        res := self classResources.

        i := res at:'FILEBROWSER_ICON' default:nil.

        i isNil ifTrue:[

            nm := res at:'FILEBROWSER_ICON_FILE' default:'FBrowser.xbm'.

            i := Smalltalk imageFromFileNamed:nm forClass:self.

            i isNil ifTrue:[

                i := StandardSystemView defaultIcon

            ]

        ].

        i notNil ifTrue:[

            DefaultIcon := i := i onDevice:Display

        ]

    ].

    ^ i

    "Modified: 19.3.1997 / 20:48:34 / ca"

    "Modified: 15.8.1997 / 15:27:19 / cg"

! !

!FileBrowser class methodsFor:'fileList user interaction'!

goodRenameDefaultForFile:oldName lastOld:lastOldName lastNew:lastNewName

    ^ DoWhatIMeanSupport goodRenameDefaultForFile:oldName lastOld:lastOldName lastNew:lastNewName

! !

!FileBrowser class methodsFor:'history'!

addToCommandHistory:aCommandString for:aFilename

    |cmd suffix|

    (aCommandString notNil and:[aCommandString notEmpty]) ifTrue:[

        CommandHistory notNil ifTrue:[

            CommandHistory addFirst:aCommandString.

            CommandHistory size > CommandHistorySize ifTrue:[

                CommandHistory removeLast

            ]

        ].

        aFilename notNil ifTrue:[

            cmd := aCommandString copyTo:(aCommandString indexOf:Character space ifAbsent:[aCommandString size + 1])-1.

            DefaultCommandPerSuffix isNil ifTrue:[

                DefaultCommandPerSuffix := Dictionary new.

            ].

            suffix := aFilename asFilename suffix.

            suffix notNil ifTrue:[

                DefaultCommandPerSuffix at:suffix put:cmd.

            ]

        ]

    ]

    "Created: 14.11.1996 / 14:58:13 / cg"

!

addToVisitedFileHistory:path

    |idx|

    idx := VisitedFileHistory indexOf:path.

    idx == 0 ifTrue:[

        VisitedFileHistory size >= HistorySize ifTrue:[

            VisitedFileHistory removeLast.

        ]

    ] ifFalse:[

        "already been there before; move the entry to

         the beginning, so it will fall out later."

        VisitedFileHistory removeIndex:idx.

    ].

    VisitedFileHistory addFirst:path.

! !

!FileBrowser class methodsFor:'icon - presentation'!

addOnIconsFor:aFilename to:aIcon

    "given a fileName, return an appropriate icon"

    | addIcns isDirectory isReadable|

    addIcns := OrderedCollection new.

    aFilename isSymbolicLink ifTrue:[

        addIcns add:(self iconForKeyMatching:#addOnLinked).

    ].

    isDirectory := aFilename isDirectory.

    isReadable := aFilename isReadable.

    ((isReadable not and:[isDirectory not]) or:[(isDirectory) and:[(isReadable not) or:[aFilename isExecutable not]]]) ifTrue:[

        addIcns add:(self iconForKeyMatching:#addOnLocked).

    ].

    addIcns notEmpty ifTrue:[

        addIcns addFirst:aIcon.

        ^ MultiImage images:addIcns.

    ].

    ^ aIcon

!

fileTypeIconKeyFor:aFilename

    |key|

    aFilename isDirectory ifTrue:[

        key := #directory.

    ] ifFalse:[

        key := #file.

        aFilename isExecutableProgram ifTrue:[

            key := #executableFile

        ].

        aFilename isSpecialFile ifTrue:[

            ^ #specialFile.

        ].

    ].

    ^ key

!

iconForFile:aFilename

    "given a fileName, return an appropriate icon"

    |icn|

    icn := self iconForKeyMatching:(self iconKeyForFile:aFilename).

    ^ self addOnIconsFor:aFilename to:icn.

!

iconForKeyMatching:aKey

    |icn assoc|

    icn := self icons at:aKey ifAbsent:nil.

    icn notNil ifTrue:[^icn].

    assoc := MatchedIcons detect:[:assoc | assoc key match:aKey] ifNone:nil.

    assoc notNil ifTrue:[^ assoc value].

    ^ nil.

!

iconKeyForFile:aFilenameArg

    "given a fileName, return an appropriate icon"

    |aFilename fileType mimeType suffix|

    aFilename := aFilenameArg.

    aFilenameArg isFilename ifTrue:[

        fileType := self fileTypeIconKeyFor:aFilename.

    ] ifFalse:[

        fileType := #file

    ].

    (fileType == #directory) ifFalse:[

        suffix := aFilename suffix.

        (suffix = 'bak' or:[suffix = 'sav']) ifTrue:[

            aFilename := aFilename withoutSuffix.

        ].

        mimeType := MIMETypes mimeTypeForFilename:aFilename.