"{ Package: 'stx:libtool' }"!

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatExpression:aString in:aClass elementsInto:elementsCollection

    ^self formatExpression:aString in:aClass

    "Created: / 25-07-2010 / 08:57:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 04-10-2011 / 19:47:20 / cg"

! !

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatFileContents:aString elementsInto:elementsCollection

    "format (recolor) a file's contents.

     Return the text containing font changes and color information.

     Here, nothing is done ,just for protocol completeness"

    ^ aString

    "Created: / 21-10-2017 / 13:28:35 / cg"

! !

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatMethod:aString in:aClass using:preferencesOrNil elementsInto: elements

    <resource: #obsolete>

    self obsoleteMethodWarning.

    ^ self formatMethodSource:aString in:aClass using:preferencesOrNil

    "Created: / 25-07-2010 / 08:58:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatMethod:aMethodOrNil source:aString in:aClass using:preferencesOrNil elementsInto: elements

    ^ self formatMethod:aMethodOrNil source:aString in:aClass using:preferencesOrNil

    "Created: / 05-07-2011 / 10:41:14 / cg"

    "Modified: / 20-07-2011 / 16:29:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractTime methodsFor:'inspecting'!

inspectorValueListIconFor:anInspector

    "returns the icon to be shown alongside the value list of an inspector"

    ^ anInspector imageFor_timeAndDate

    "Created: / 12-12-2018 / 16:32:37 / Claus Gittinger"

! !

!AbstractTime class methodsFor:'misc ui support'!

iconInBrowserSymbol

    "the browser will use this as index into the toolbariconlibrary"

    <resource: #programImage>

    ^ #timeClassBrowserIcon

! !

!ApplicationModel methodsFor:'inspecting'!

inspectorExtraAttributes

    |atts nameDict bindingDict|

    atts := super inspectorExtraAttributes.

    builder notNil ifTrue:[

"/        (nameDict := builder namedComponents) notNil ifTrue:[

"/            nameDict keysAndValuesDo:[:eachName :eachWidget |

"/                atts add:('-[: ',eachName,' :]') -> [ nameDict at:eachName ].

"/            ].

"/        ].

        (bindingDict := builder bindings) notNil ifTrue:[

            bindingDict keysAndValuesDo:[:eachName :eachAspect |

                atts add:('[',eachName allItalic,']') -> [ bindingDict at:eachName ].

            ].

        ].

        atts add:('-- window automationID') -> [ builder window isNil

                                                ifTrue:['«no window»']

                                                ifFalse:[builder window uuid] ].

    ].

    ^ atts

    "Modified: / 29-07-2018 / 13:38:11 / Claus Gittinger"

! !

!Array methodsFor:'inspecting'!

inspectorValueStringInListFor:anInspector

    "returns a string to be shown in the inspector's selection list"

    (self class == Array and:[self size == 0]) ifTrue:[

        ^ '#()'

    ].

    ^ super inspectorValueStringInListFor:anInspector

    "Modified (comment): / 16-08-2017 / 20:52:01 / cg"

    "Modified: / 29-03-2019 / 11:47:58 / Claus Gittinger"

! !

!ArrayedCollection methodsFor:'inspecting'!

inspector2TabForHexDump

    "a tab, showing a hex dump; defined here, so that both byteArrays and other bulk data

     containers can define it in their inspector2Tabs methods."

    ^ self class inspector2TabForHexDumpFor:self

    "

     (ByteArray new:1000) inspect

     (0 to:255) asByteArray inspect

    "

    "Created: / 13-02-2012 / 15:08:42 / cg"

    "Modified: / 11-11-2018 / 12:20:02 / Claus Gittinger"

    "Modified (comment): / 12-03-2019 / 16:42:24 / Claus Gittinger"

! !

!ArrayedCollection methodsFor:'inspecting'!

inspectorValueListIconFor:anInspector

    "returns the icon to be shown alongside the value list of an inspector"

    self isEmpty ifTrue:[

        ^ anInspector imageFor_collections_empty

    ].    

    ^ anInspector imageFor_arrays

    "Created: / 12-12-2018 / 16:20:08 / Claus Gittinger"

! !

!ArrayedCollection class methodsFor:'inspecting - helpers'!

hexDumpViewFor:instOrHolder

    "a tab, showing a hex dump; defined here, so that both byteArrays and other bulk data

     containers can define it in their inspector2Tabs methods."

    |getByteSize wrapper hv v genDump baseAddressHolder 

     highlightRangeHolder baseHolder|

    getByteSize := [ instOrHolder value size * instOrHolder value class elementByteSize ].

    wrapper := Plug new.

    wrapper respondTo:#size with:[ getByteSize value ].

    wrapper respondTo:#at: with:[:byteIdx | instOrHolder value byteAt:byteIdx ].

    wrapper respondTo:#do: with:[:aBlock |

                                    |sz|

                                    sz := getByteSize value.

                                    1 to:sz do:[:i |

                                        aBlock value:(instOrHolder value byteAt:i) 

                                    ].

                                ].

    highlightRangeHolder := (nil asValue).

    baseHolder := 16 asValue.

    "/ instOrHolder isExternalBytes ifTrue:[

    "/     baseAddressHolder := instOrHolder address asValue.

    "/ ] ifFalse:[

        baseAddressHolder := 0 asValue.

    "/ ].

    genDump := [

                    |dump|

                    v topView withWaitCursorDo:[

                        dump := AbstractFileBrowser 

                            contentsOfBytesAsDump:wrapper base:baseHolder

                            numberOfAddressDigits:(getByteSize value hexPrintString size) 

                            addressStart:baseAddressHolder

                            characterEncoding:#'iso8859-1'

                            highlightRangeHolder:highlightRangeHolder.

                        v list:dump expandTabs:false scanForNonStrings:false includesNonStrings:false.

                    ].

               ].

    hv := HVScrollableView for:TextView. 

    hv autoHideScrollBars:true.

    v := hv scrolledView.

    v objectAttributeAt:#highlightRangeHolder put:highlightRangeHolder.

    genDump value.

    instOrHolder onChangeEvaluate:genDump.

    v 

        menuHolder:

            [    

                |m changeBase| 

                changeBase := 

                    [:b |

                        baseHolder value:b.

                        v flushCachedWidthOfWidestLine.

                        v contentsChanged. 

                        v invalidate

                    ].

                m := v editMenu.

                m addSeparator.  "/ m addLabel:'-' selector:nil.

                m addLabel:'Hex' selector:#changeToHex action:[ changeBase value:16 ].

                m addLabel:'Decimal' selector:#changeToDecimal action:[ changeBase value:10 ].

                m addLabel:'Binary' selector:#changeToBinary action:[ changeBase value:2 ].

                m addLabel:'Octal' selector:#changeToOctal action:[ changeBase value:8 ].

                m addSeparator.  "/ m addLabel:'-' selector:nil.

                m addLabel:'Change Base Address...' 

                  selector:#changeBase

                  action:[ 

                        |s b|

                        s := Dialog request:'Base address (hex):' initialAnswer:(baseAddressHolder value printStringRadix:16).

                        s notEmptyOrNil ifTrue:[

                            b := Integer readFrom:s radix:16 onError:nil.

                            b notNil ifTrue:[

                                baseAddressHolder value:b. 

                                "/ genDump value.

                                v flushCachedWidthOfWidestLine.

                                v contentsChanged. 

                                v invalidate

                            ].

                        ].

                    ].

                m.

            ];

        menuMessage: #value.

    ^ hv

    "

     (ByteArray new:1000) inspect

     (0 to:255) asByteArray inspect

    "

    "Created: / 13-02-2012 / 15:08:42 / cg"

    "Modified: / 11-11-2018 / 12:20:02 / Claus Gittinger"

    "Modified (comment): / 12-03-2019 / 16:42:24 / Claus Gittinger"

! !

!ArrayedCollection class methodsFor:'inspecting - helpers'!

inspector2TabForHexDumpFor:anInstance

    "a tab, showing a hex dump; defined here, so that both byteArrays and other bulk data

     containers can define it in their inspector2Tabs methods."

    ^ Tools::Inspector2Tab new

            priority: 40;

            label:'Hexdump';

            view:(self hexDumpViewFor:anInstance);

            yourself

    "

     (ByteArray new:1000) inspect

     (0 to:255) asByteArray inspect

    "

    "Created: / 13-02-2012 / 15:08:42 / cg"

    "Modified: / 11-11-2018 / 12:20:02 / Claus Gittinger"

    "Modified (comment): / 12-03-2019 / 16:42:24 / Claus Gittinger"

! !

!Autoload class methodsFor:'message catching'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ #()

! !

!Bag methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ super inspectorExtraAttributes

        add:('-histogram' -> [ (self sortedCounts collect:[:e| e displayString]) asStringCollection asString ]);

        yourself

! !

!Behavior methodsFor:'misc ui support'!

iconInBrowserSymbol

    "can be redefined for a private icon in the browser (for me and my subclasses).

     The returned symbol must be a selector of the ToolbarIconLibrary.

     The browser will use this as index into the toolbariconlibrary"

    <resource: #programImage>

    self isLoaded ifFalse:[

        ^ #autoloadedClassBrowserIcon

    ].

    (self isBrowserStartable) ifTrue:[

        self isVisualStartable ifTrue:[

            ^ #visualStartableClassBrowserIcon

        ].

        ^ #startableClassBrowserIcon

    ].

    "/ give ruby and other special metaclasses a chance to provide their own icon...

    ^ self class iconInBrowserSymbol

    "Created: / 20-07-2007 / 08:52:17 / cg"

! !

!Behavior methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ super inspectorExtraAttributes

        add:(self isMeta

                ifFalse:[ '-meta'   -> self theMetaclass ]

                ifTrue:[ '-nonMeta' -> self theNonMetaclass ]);

        add:( '-project definition class' -> [ self theNonMetaclass projectDefinitionClass ] );

        yourself

    "Modified (format): / 18-07-2017 / 19:56:35 / cg"

! !

!Behavior methodsFor:'inspecting'!

inspectorValueListIconFor:anInspector

    "returns the icon to be shown alongside the value list of an inspector"

    ^ anInspector imageFor_classes

    "Created: / 12-12-2018 / 16:21:16 / Claus Gittinger"

! !

!Behavior methodsFor:'inspecting'!

inspectorValueStringInListFor:anInspector

    "returns a string to be shown in the inspector's selection list"

    |nm|

    (nm := self name) notEmptyOrNil ifTrue:[

        ^ nm

    ].

    ^ super inspectorValueStringInListFor:anInspector

    "Modified (comment): / 16-08-2017 / 20:52:05 / cg"

! !

!Behavior methodsFor:'queries'!

methodsCount

    "Return a number of methods or nil if number of methods

     is not known (such as for lazy-loaded classes)"

    ^ methodDictionary size

    "Created: / 25-02-2015 / 16:14:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Block methodsFor:'inspecting'!

inspector2TabClassOfHome

    "another tab browsing the block's home method"

    <inspector2Tab>

    |homeMethod mclass|

    (homeMethod := self homeMethod) notNil ifTrue:[

        (mclass := homeMethod mclass) notNil ifTrue:[

            ^ Tools::Inspector2Tab 

                toBrowseClass:mclass 

                selector:(homeMethod selector) 

                label:'Block''s Home Class'

        ].

    ].

    ^ nil

    "Created: / 14-09-2018 / 18:21:52 / Claus Gittinger"

    "Modified (comment): / 14-09-2018 / 21:34:01 / Claus Gittinger"

! !

!Block methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    |d|

    d := super inspectorExtraAttributes.

    self homeMethod isNil ifTrue:[

        d

            add:'-code'   -> 'no home method';

            add:'-source' -> 'no home method'.

    ] ifFalse:[

        d    

            add:'-code'   -> [ String streamContents:[:s | self homeMethod decompileTo:s]];

            add:'-source' -> [ self homeMethod source].

    ].

    ^ d

    "Created: / 15-11-2011 / 14:24:10 / cg"

    "Modified (format): / 18-07-2017 / 19:56:44 / cg"

! !

!Boolean methodsFor:'inspecting'!

inspectorValueStringInListFor:anInspector

    "returns a string to be shown in the inspector's selection list"

    ^ self printString

    "Modified (comment): / 16-08-2017 / 20:52:09 / cg"

! !

!Breakpoint methodsFor:'accessing'!

icon

    ^description icon

    "Created: / 11-07-2011 / 18:21:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!BreakpointDescription methodsFor:'accessing'!

icon

    "do not use abbreviations like bpnt or brp or similar;

     when I do not know the exact name, I tend to search for implementors/senders

     of '*break*' or '*disabled*'.

     I will not find anything useful and have to single step if methods are named

     cryptically."

    icon notNil ifTrue:[^ icon].

    condition isNil ifTrue:[

        state == #enabled ifTrue:[^ ToolbarIconLibrary breakpointRedEnabled].

        state == #disabled ifTrue:[^ ToolbarIconLibrary breakpointRedDisabled].

        state == #tracing ifTrue:[^ ToolbarIconLibrary tracepointBlue].

    ] ifFalse:[

        state == #enabled ifTrue:[^ ToolbarIconLibrary breakpointBlueEnabled].

        state == #disabled ifTrue:[^ ToolbarIconLibrary breakpointBlueDisabled].

    ].

    ^nil

    "Created: / 28-06-2011 / 08:29:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 27-01-2012 / 13:46:23 / cg"

! !

!ByteArray methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    |basePrinter|

    basePrinter := 

        [:arr :b |

            String

                streamContents:[:s |

                    arr class isWords ifTrue:[

                        arr asWordArray printOn:s base:b showRadix:true

                    ] ifFalse:[

                        arr class isLongs ifTrue:[

                            arr asLongIntegerArray printOn:s base:b showRadix:true

                        ] ifFalse:[

                            arr asByteArray printOn:s base:b showRadix:true

                        ]

                    ]

                ]

        ].

    ^ super inspectorExtraAttributes

        add:'-hexstring'   -> [ self hexPrintString "WithSeparator:Character space" ];

        add:'-hexadecimal' -> [ basePrinter value:self value:16 ];

        add:'-binary'      -> [ basePrinter value:self value:2 ];

        add:'-base64'      -> [ self base64Encoded ];

        add:'-asciiString' -> [ self asString ];

        add:'-cString'     -> [ '{',(String streamContents:[:s | self do:[:b | s printf:'0x%02x' with:b ] separatedBy:[s nextPutAll:', ']]), '}' ];

        yourself

    "Modified (format): / 18-07-2017 / 19:56:54 / cg"

    "Modified: / 19-09-2018 / 12:08:42 / Claus Gittinger"

! !

!ByteArray methodsFor:'inspecting'!