"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview' }"

Dictionary subclass:#ResourcePack

	instanceVariableNames:'superPack packsClassName fileReadFailed'

	classVariableNames:'Packs'

	poolDictionaries:''

	category:'Interface-Internationalization'

!

!ResourcePack class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class supports easy customization of smalltalk code (i.e. internationalization

    and viewStyle adaption).

    ResourcePacks are class specific, meaning that every subclass of View

    and ApplicationModel has an instance of ResourcePack (instVar called 'resources') 

    which is created when the first instance of the view/app is created,

    and cached in a class-instVar (so the file is only read once).

    The resourcePack consists of a mapping from strings to values, which are

    then used in labels, buttons, menus etc.

    The resourcePack initializes itself from a file found in 'resources/<className>.rs',

    where 'className' is built by the usual abbreviation mechanism (see abbrev-files).

    Conditional mappings are possible, by including lines as:

	#if <expression>

	#endif

    in the resourcefile. Example:

    file 'foo.rs':

	#if Language == #de

	'abort' 'Abbruch'

	#endif

	#if Language == #fr

	'abort' 'canceller'

	#endif

    the corresponding resource-strings are accessed (from methods within the class)

    using:

	resources string:'abort'

    returning the mapped string (i.e. 'Abbruch' if the global Language is set

    to #de)..

    If no corresponding entry is found in the resources, the key is returned;

    alternatively, use:

	resources string:'foo' default:'bar'

    which returns 'bar', if no resource definition for 'foo' is found.

    Translations can also include arguments, such as:

	resources string:'really delete %1' with:fileName

    This scheme has the advantage, that you can write your programs using your

    native language strings. Later, when new languages are to be supported,

    simply create a resource file for the class and add translations for

    all those strings. (find the keys by looking at users of resource or senders

    of 'string:*').

    Notice, that the grammar of different languages may imply a reordering,

    so the above string becomes the german 'wollen Sie %1 wirklich löschen';

    so using percent-placeholders is much better than simple concatenations of

    arguments to the question.

    More languages can be added later without any change in the code,

    recompilation or the like. 

    Even by people without access to the source code i.e. which only have the 

    applications binary.

    Also, unsupported languages' strings are simply left unchanged - if you

    write your application in (say) english, and only plan to use it in english,

    no additional work is required (i.e you dont need a resource file then).

    Strings for unknown languages will come in english 

    (which is better than nothing or empty button labels ;-)

    Summary:

	in subclasses of View and ApplicationModel,

	instead of writing:

		...

		b := Button label:'press me'

		...

	always write:

		...

		b := Button label:(resources string:'press me')

		...

	if your class is not a subclass of one of the above, AND you need

	resource translations, you wont inherit the resources variable

	(which is automatically initialized).

	In this case, you have to ask the ResourcePack class explicitely for

	a corresponding package:

		ResourcePack for:aClassName

	as an example, see how the Date class gets the national names of

	week & monthnames.

    [author:]

	Claus Gittinger

"

!

examples

"

    normally, resources are found in files named after their classes sourcefile

    For example, the FileBrowsers resources are found in 'FBrowser.rs'.

    For the examples below, we process resources from a constant string;

	this is NOT representative.

									[exBegin]

	|stream res|

	stream := ReadStream on:'

foo  ''the translation for foo''

#if Language == #de

bar  ''die deutsche uebersetzung von bar''

baz  ''baz hat den Wert %1''

#endif

#if Language == #fr

bar  ''bar en francaise''

baz  ''%1, c''''est baz''

#endif

'.

	res := ResourcePack new readFromResourceStream:stream in:nil.

	Transcript showCR:'baz is translated to: ' , (res string:'baz' with:'1234').

	Transcript showCR:'bar is translated to: ' , (res string:'bar').

	Transcript showCR:'foo is translated to: ' , (res string:'foo').

	Transcript showCR:'fooBar is translated to: ' , (res string:'fooBar').

									[exEnd]

    set the Language to french:

									[exBegin]

	Language := #fr

									[exEnd]

    and repeat the above.

    back to english:

									[exBegin]

	Language := #en 

									[exEnd]

    back to german:

									[exBegin]

	Language := #de 

									[exEnd]

"

! !

!ResourcePack class methodsFor:'initialization'!

flushCachedResourcePacks

    "forget all cached resources - needed after a style change"

    Packs := nil.

    self initialize

    "ResourcePack flushCachedResourcePacks"

!

initialize

    Packs isNil ifTrue:[

	Packs := WeakArray new:30

    ].

    "ResourcePack initialize"

! !

!ResourcePack class methodsFor:'instance creation'!

for:aClass

    "get the full resource definitions for aClass (i.e. with super packs).

     Also leave the resulting pack in the cache for faster access next time."

    ^ self for:aClass cached:true

    "

     ResourcePack for:TextView     

     ResourcePack for:CodeView

     ResourcePack for:Workspace  

     ResourcePack for:View      

     ResourcePack for:ErrorLogger 

     ResourcePack for:NewLauncher 

     Workspace classResources

    "

!

for:aClass cached:cached

    "get the full resource definitions for aClass (i.e. with super packs).

     Also leave the resulting pack in the cache for faster access next time."

    |nm pack rsrcDir baseName|

    nm := aClass resourcePackName.

    cached ifTrue:[

        pack := self searchCacheFor:nm.

        pack notNil ifTrue:[^ pack].

    ].

    baseName := (Smalltalk fileNameForClass:nm) , '.rs'.

    rsrcDir := aClass resourceDirectory.

    (rsrcDir notNil 

    and:[rsrcDir exists 

    and:[(rsrcDir construct:baseName) exists]]) ifTrue:[

        pack := self fromFile:baseName directory:rsrcDir pathName.

    ] ifFalse:[

        pack := self fromFile:baseName.

    ].

    aClass == Object ifFalse:[

        pack superPack:(self for:(aClass superclass)).

    ].

    pack packsClassName:nm.

    cached ifTrue:[

        self addToCache:pack.

    ].

    ^ pack

    "

     ResourcePack for:TextView     

     ResourcePack for:CodeView

     ResourcePack for:Workspace  

     ResourcePack for:View      

     ResourcePack for:ErrorLogger 

     ResourcePack for:NewLauncher 

     Workspace classResources

    "

!

forPackage:package 

    "get the full resource definitions given a package id (such as stx:libbasic').

     Also leave the resulting pack in the cache for faster access next time."

    ^ self forPackage:package cached:true

    "

     ResourcePack forPackage:'stx:libbasic'   

    "

!

forPackage:package cached:cached

    "get the full resource definitions given a package id (such as stx:libbasic').

     Also optionally leave the resulting pack in the cache for faster access next time."

    |fullName pack rsrcDir|

    fullName := package , '/resources/resources.rs'.

    cached ifTrue:[

        pack := self searchCacheFor:fullName.

        pack notNil ifTrue:[^ pack].

    ].

    rsrcDir := Smalltalk projectDirectoryForPackage:package.

    rsrcDir isNil ifTrue:[^ nil].

    rsrcDir := rsrcDir asFilename construct:'resources'.

    rsrcDir exists ifFalse:[^ nil].

    pack := self fromFile:'resources.rs' directory:rsrcDir.

    pack packsClassName:fullName.

    cached ifTrue:[

        self addToCache:pack.

    ].

    ^ pack

    "

     ResourcePack forPackage:'stx:libbasic' cached:false     

    "

!

fromFile:aFileName

    "get the resource definitions from a file in the default directory.

     Uncached low-level entry."

    ^ self fromFile:aFileName directory:'resources'

    "

     ResourcePack fromFile:'SBrowser.rs'

     ResourcePack fromFile:'FBrowser.rs'

     ResourcePack fromFile:'Smalltalk.rs'

     ResourcePack fromFile:'Smalltalk.rs' asFilename

     ResourcePack fromFile:'../../libtool/resources/AboutBox_ru.rs' asFilename

    "

!

fromFile:aFileName directory:dirName

    "get the resource definitions from a file in a directory.

     Uncached low-level entry."

    |newPack|

    newPack := self new.

    newPack readFromFile:aFileName directory:dirName.

    ^ newPack

! !

!ResourcePack class methodsFor:'private'!

addToCache:aPack

    |idx|

    idx := Packs identityIndexOf:nil.

    idx == 0 ifTrue:[

    ].

    idx == 0 ifTrue:[

    ].

    Packs at:idx put:aPack

!

searchCacheFor:aClassname

    |sz "{ Class: SmallInteger }" |

    Packs isNil ifTrue:[

	self initialize.

	^ nil

    ].

    sz := Packs size.

    1 to:sz do:[:idx |

	|aPack|

	aPack := Packs at:idx.

	(aPack notNil 

	and:[aPack ~~ 0]) ifTrue:[

	    aClassname = aPack packsClassName ifTrue:[

		"

		 bring to end for LRU

		"

		Packs replaceFrom:idx to:sz-1 with:Packs startingAt:idx+1.

		Packs at:sz put:aPack.

		^ aPack

	    ]

	]

    ].

    ^ nil

    "

     ResourcePack searchCacheFor:'TextView' 

    "

! !

!ResourcePack methodsFor:'accessing'!

array:anArray

    "translate a collection of strings"

    ^ anArray collect:[:r | self at:r default:r]

    "

     Launcher classResources array:#('file' 'classes') 

    "

    "Modified: / 29.1.1998 / 22:44:22 / cg"

!

at:aKey

    "translate a string"

    ^ self at:aKey ifAbsent:aKey

!

at:aKey default:default

    "translate a string"

    ^ self at:aKey ifAbsent:default

!

at:aKey ifAbsent:defaultValue

    "translate a string.

     Some special 'intelligence' has been added:

        if no value for aKey is found,

          lookup aKey with first character caseChanged and change the results first characters case.

          or aKey ends with a ':', then lookup aKey without ':' and append ':' to the result.

          or aKey ends with a '=', then lookup aKey without '=' and append '=' to the result.

          or aKey ends with a '.', then lookup aKey without '.' and append '.' to the result.

          or aKey ends with a ' ', then lookup aKey without ' '.

          or aKey ends with a ' ...', then lookup aKey without ' ...' and append '...' to the result.

          or aKey ends with a '...', then lookup aKey without '...' and append '...' to the result.

          or aKey includes '&', then lookup aKey without '&'.

     This means, that only a single translation is required to provide local translations for

     things like 

        'search'

        'search:'

        'search...'

    "

    |val alternativeKey rest usedKey idx|

    aKey notNil ifTrue:[

        val := super at:aKey ifAbsent:nil.

        val notNil ifTrue:[^ val].

        (aKey isString and:[aKey size > 0]) ifTrue:[

            "/ try with case-first swapped...

            (aKey first isLetter) ifTrue:[

                alternativeKey := aKey first isUppercase 

                                    ifTrue:[aKey asLowercaseFirst]

                                    ifFalse:[aKey asUppercaseFirst].

                val := super at:alternativeKey ifAbsent:nil.

                val notNil ifTrue:[

                    aKey first isUppercase ifTrue:[

                        ^ val asUppercaseFirst

                    ].

                    ^ val asLowercaseFirst.                

                ].

            ].

            (':=.' includes:aKey last) ifTrue:[

                rest := aKey last.

                usedKey := aKey copyWithoutLast:1.

                val := self at:usedKey ifAbsent:nil.        "/ recursion

                val notNil ifTrue:[^ val , rest].

            ].

            (aKey endsWith:' ') ifTrue:[

                usedKey := aKey withoutSeparators.

                val := self at:usedKey ifAbsent:nil.        "/ recursion

                val notNil ifTrue:[^ val].

            ].

            (aKey endsWith:' ...') ifTrue:[

                usedKey := aKey copyWithoutLast:4.

                val := self at:usedKey ifAbsent:nil.        "/ recursion

                val notNil ifTrue:[^ val , '...'].

            ].

            (aKey endsWith:'...') ifTrue:[

                usedKey := aKey copyWithoutLast:3.

                val := self at:usedKey ifAbsent:nil.        "/ recursion

                val notNil ifTrue:[^ val , '...'].

            ].

            (idx := aKey indexOf:$&) ~~ 0 ifTrue:[

                (aKey at:idx+1 ifAbsent:nil) ~~ $& ifTrue:[

                    usedKey := (aKey copyTo:idx-1) , (aKey copyFrom:idx+1).

                    val := self at:usedKey ifAbsent:nil.    "/ recursion

                    val notNil ifTrue:[^ val].

                ].

            ].

        ].

        superPack notNil ifTrue:[

            ^ superPack at:aKey ifAbsent:defaultValue.

        ].

    ].