"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg' }"

"{ NameSpace: Smalltalk }"

TextCollector subclass:#Workspace

	instanceVariableNames:'doItAction codeStartPosition errorFgColor errorBgColor

		commentStrings autoDefineWorkspaceVariables simulatedSelf

		autoDefineVariables compilerClass allowValueDrop

		poolsConsideredInDoIts namespaceForDoits editedMethodOrClass

		editedLanguage'

	classVariableNames:'DefaultErrorBackgroundColor DefaultErrorForegroundColor

		DefaultViewBackground DefaultWarningBackgroundColor

		DefaultWarningForegroundColor DoItHistory Sniplets Snippets

		WorkspaceVariables'

	poolDictionaries:''

	category:'Interface-Smalltalk'

!

Workspace comment:''

!

!Workspace class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    a view for editable text which can evaluate expressions.

    I.e. its basically a view for editable text, with added

    'doIt', 'printIt' and 'inspectIt' functions on the popup-menu.

    The action to be performed on doIt is defined by a block,

    which can be defined by the owner of this view.

    (thus you can put a workspace into more complex widgets, and

     control what should happen on 'doIt').

    A useful default action is automatically defined, which simply

    evaluates the selection as a smalltalk expression.

    (but, a lisp or prolog workspace would define its own action,

     to call for another compiler/interpreter  ...)

    Special workspace- and doIt variables:

        workspaces can be configured to automatically define undefined variables

        as either workspace- or doIt variables. When encountering undefined variables,

        the parser asks for an action, which is responded with #workspace or doIt if a

        workspace is the requestor of a doIt. Both are implemented as value holders, and

        the parser will generate code sending value/value: instead of normal assignment.

        Workspace variables are kept in the Workspace class and will both persist between doIts

        and also be visible across workspaces. They are perfect for scripting (and therefore enabled

        by default when stx is started with one of the scripting options).

        DoIt variables are only valid during a single doIt.

        Be aware that when you ask from the outside via workspaceVariableAt:, you'll get a valueHolder.

        This is by purbose, as it allows for easy monitoring and tracing of changes.

    Caveat:

        in this version, Workspace does not yet support doIt in MVC setups.

        For now, simulate this by setting the doItAction, to notify the

        model manually about the doIt.

    [instance variables:]

      doItAction      <Block>         block to evaluate for doIt

      errorFgColor    <Color>         fg-Color to be used when highlighting errors

      errorBgColor    <Color>         bg-Color to be used when highlighting errors

      codeStartPosition               private temporary

    [styleSheet values:]

      codeErrorSelectionForegroundColor     fg color to highlight errors

                                            (default: selection fg)

      codeErrorSelectionBackgroundColor     bg color to highlight errors

                                            (default: selection bg)

    [start with:]

        Workspace open

    [see also:]

        Workspace EditTextView

        Parser ByteCodeCompiler

    [author:]

        Claus Gittinger

"

! !

!Workspace class methodsFor:'accessing'!

sniplets

    <resource: #obsolete>

    self obsoleteMethodWarning.

    ^ self snippets

    "

     Snippets := nil

    "

!

sniplets:something

    <resource: #obsolete>

    self obsoleteMethodWarning.

    self snippets:something

!

snippets

    Snippets isNil ifTrue:[

        Snippets := Dictionary new.

        self initializeDefaultAbbreviations.

    ].

    ^ Snippets

    "

     Snippets := nil

    "

!

snippets:aDictionary

    Snippets := aDictionary.

! !

!Workspace class methodsFor:'defaults'!

defaultCompletionSupportClass

    ^ WorkspaceCompletionSupport

    "Created: / 26-09-2013 / 17:59:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

defaultLabel

    "my default window label"

    ^ 'Workspace'

    "Created: / 16.5.1998 / 16:53:37 / cg"

!

initializeDefaultAbbreviations

    "default snippets/abbreviations. TODO: save/load snippets"

    "flush and reinitialize snippets with:

         Snippets := Dictionary new.

    "

    "after a code change below, update with:

         self initializeDefaultAbbreviations.

    "

    #(

        't'     'true'

        'f'     'false'

        's'     'self'

        'su'    'super'

        'ss'    'super '

        'n'     'nil'

        'y'     'yourself.'

        'in'    'isNil '

        'nn'    'notNil '

        'ie'    'isEmpty '

        'ne'    'notEmpty '

        'ien'   'isEmptyOrNil '

        'nen'   'notEmptyOrNil '

        '[it'    '[nil] ifTrue:[!!'

        '[if'    '[nil] ifFalse:[!!'

        'it'    'ifTrue:[!!'

        'if'    'ifFalse:[!!'

        'itf'   'ifTrue:[!!] ifFalse:[].'

        'int'   'isNil ifTrue:[!!].'

        'inf'   'isNil ifFalse:[!!].'

        'ints'  'isNil ifTrue:[^ self].'

        'infs'  'isNil ifFalse:[^ self].'

        'nnt'   'notNil ifTrue:[!!].'

        'nnf'   'notNil ifFalse:[!!].'

        'iet'   'isEmpty ifTrue:[!!].'

        'net'   'notEmpty ifTrue:[!!].'

        'ief'   'isEmpty ifFalse:[!!].'

        'nef'   'notEmpty ifFalse:[!!].'

        'wt'    'whileTrue:[!!]'

        'wf'    'whileFalse:[!!]'

        'do'    'do:[:each |!!]'

        'd:'    'do:[:each |!!]'

        'kdo'   'keysAndValuesDo:[:eachKey :eachValue |!!]'

        'kvd'   'keysAndValuesDo:[:eachKey :eachValue |!!]'

        'kv:'   'keysAndValuesDo:[:eachKey :eachValue |!!]'

        'k:'    'keysDo:[:eachKey | !!]'

        'dt'    'detect:[:each | !!]'

        'de'    'detect:[:each | !!]'

        'det'   'detect:[:each | !!]'

        'dtn'   'detect:[:each | !!] ifNone:[]'

        'cl'    'collect:[:each | !!]'

        'co'    'collect:[:each | !!]'

        'col'   'collect:[:each | !!]'

        'sl'    'select:[:each | !!]'

        'se'    'select:[:each | !!]'

        'sel'   'select:[:each | !!]'

        'rj'    'reject:[:each | !!]'

        're'    'reject:[:each | !!]'

        'rej'   'reject:[:each | !!]'

        'inj'   'inject:!! into:[:accum :each | ]'

        'ex'    'Error handle:[ex | !!] do:[].'

        '[ sh'  '[ self halt ].'

        '[sh'   '[self halt].'

        'sh'    'self halt.'

        'mt'    'MessageTally spyOn:[!!].'

        'ih'    '!! ifTrue:[ self halt ].'

        'ik'    'includesKey: #'

        'is'    'includesString: #'

        'af'    'asFilename '

        'as'    'asString '

        'aoc'   'asOrderedCollection '

        'np'    'nextPut: '

        'npa'   'nextPutAll: '

        'npl'   'nextPutLine: '

        'ps'    'printString'

        'sr'    'self subclassResponsibility.'

        'ati'   'at:!! ifAbsent: '

        'atip'  'at:!! ifAbsentPut:[ ] '

        'ap'    'at:!! '

        'st'    'Smalltalk'

        'ts'    'Transcript showCR:''!!''.'

        'trs'   'Transcript showCR:''!!''.'

        'abb'   'Workspace snippets inspect.'

        'ws'    'Delay waitForSeconds: 1.'

        'wfs'   'Delay waitForSeconds: 1.'

        'wfm'   'Delay waitForMilliseconds: 1000.'

        'ini'   'initialize\    super initialize.\    '

        'newi'  'new\    ^ super new initialize.'

        'upd'   'update:something with:aParameter from:changedObject\    !!\    ^ super update:something with:aParameter from:changedObject.'

        'OC'    'OrderedCollection'

        'oc'    'OrderedCollection'

        'SC'    'SortedCollection'

        'sc'    'SortedCollection'

        'D'     'Dictionary'

        'ID'    'IdentityDictionary'

        'Id'    'IdentityDictionary'

        'id'    'IdentityDictionary'

        'iD'    'IdentityDictionary'

        'OCn'   'OrderedCollection new.'

        'ocn'   'OrderedCollection new.'

        'SCn'   'SortedCollection new.'

        'IDn'   'IdentityDictionary new'

        'idn'   'IdentityDictionary new'

        'Dn'    'Dictionary new'

        'dn'    'Dictionary new'

        'Sn'    'Set new'

        'sn'    'Set new'

        'A'     'Array'

        'a'     'Array'

        'An'    'Array new:'

        'an'    'Array new:'

        'Aw'    'Array with:'

        'aw'    'Array with:'

        'Aww'   'Array with:!! with:'

        'sww'   'Array with:!! with:'

        'Awww'  'Array with:!! with: with:'

        'awww'  'Array with:!! with: with:'

        'Awwww' 'Array with:!! with: with: with:'

        'awwww' 'Array with:!! with: with: with:'

        'aw2'   'Array with:!! with:'

        'aw3'   'Array with:!! with: with:'

        'aw4'   'Array with:!! with: with: with:'

        '0'     '(0.0 @ 0.0)'

        '1'     '(1.0 @ 1.0)'

        '['     '[:!! ]'

        '('     '(!! )'

        "/ typos...

        'eslf'  'self'

        'slef'  'self'

        'sefl'  'self'

        'elf'   'self'

        'slf'   'self'

        'sef'   'self'

        'iftrue'   'ifTrue'

        'iffalse'  'ifFalse'

        'iftrue:'  'ifTrue:'

        'iffalse:' 'ifFalse:'

    ) pairWiseDo:[:abbrev :text |

        Snippets

            at:abbrev put:text "/ ifPresent:[ self error:'duplicate abbreviation key' ]

    ].

    "Modified: / 30-04-2016 / 19:43:35 / cg"

!

updateStyleCache

    "extract values from the styleSheet and cache them in class variables"

    <resource: #style (#'codeErrorSelection.foregroundColor'

		       #'codeErrorSelection.backgroundColor'

		       #'codeView.backgroundColor' )>

    DefaultErrorForegroundColor := StyleSheet colorAt:'codeErrorSelection.foregroundColor'.

    DefaultErrorBackgroundColor := StyleSheet colorAt:'codeErrorSelection.backgroundColor'.

    DefaultViewBackground := StyleSheet colorAt:'codeView.backgroundColor'.

! !

!Workspace class methodsFor:'getting a new Workspace'!

open

    "launch a new workspace"

    |scr topView workspace f|

    topView := StandardSystemView

		label:(self classResources string:(self defaultLabel))

		" minExtent:(100 @ 100)".

    scr := HVScrollableView for:self in:topView.

    scr origin:(0.0 @ 0.0) corner:(1.0 @ 1.0).

    workspace := scr scrolledView.

    "/ adjust topViews extent according to my font

    f := workspace font.

    topView extent:((f widthOf:'x') * 40) @ (f height * 10).

    topView open.

    ^ workspace

    "

     Workspace open

    "

    "Modified: / 16.5.1998 / 16:53:53 / cg"

!

openForRemote:hostName

    "launch a new workspace to evaluate expression on some remote machine.

     Entered expressions are sent over to some partner machine, evaluated there,

     and the result is shown here.

     This requires the RemoteObjects package to be loaded."

    |server remoteCompiler workspace|

    RemoteObjectServer isNil ifTrue:[

	self warn:'no remoteObjectServer available'.

	^ nil

    ].

    server := RemoteObjectServer on:hostName.

    remoteCompiler := server get:#Compiler.

    workspace := self open.

    workspace topView

	label:(self classResources string:'Remote Workspace {%1}' with:hostName).

    workspace doItAction:

		[:theCode |

		    remoteCompiler

			evaluate:theCode

			in:nil

			receiver:nil

			notifying:workspace

			logged:true

			ifFail:nil

		]

    "

     Workspace openForRemote:'andi'

    "

    "Modified: / 16.5.1998 / 16:57:38 / cg"

!

openWith:initialText selected:selectedBoolean

    "launch a new workspace with some initial contents"

    |workspace|

    workspace := self open.

    workspace contents:initialText selected:selectedBoolean.

    ^ workspace

    "

     Workspace openWith:'Transcript showCR:''hello world'''

    "

! !

!Workspace class methodsFor:'history'!

clearDoItHistory

    DoItHistory := nil

!

doItHistory

    ^ DoItHistory

!

doItHistorySize

    "the number of remembered doIts"

    ^ 20

!

rememberDoIt:aString

    |string|

    string := aString asString string withoutSeparators.

    (string asCollectionOfWords size <= 1) ifTrue:[

	Error handle:[:ex |

	    "/ unparsable

	    ^ self

	] do:[

	    ((Scanner new scanTokens:string) size <= 1) ifTrue:[

		"it's a variable only"

		^ self

	    ]

	]

    ].

    DoItHistory isNil ifTrue:[

	DoItHistory := OrderedCollection new.

    ].

    DoItHistory remove:string ifAbsent:nil.

    DoItHistory addFirst:string.

    DoItHistory size > self doItHistorySize ifTrue:[

	DoItHistory removeLast

    ].

! !

!Workspace class methodsFor:'queries'!

isVisualStartable

    "returns whether this application class can be started via #open

     (i.e. via a double click on the class in the browser)"

    ^ self == Workspace

    "Created: / 16.5.1998 / 16:59:00 / cg"

    "Modified: / 16.5.1998 / 16:59:39 / cg"

! !

!Workspace class methodsFor:'workspace variables'!

addWorkspaceVariable:name

    "create a new workspace variable"

    |holder|

    holder := self workspaceVariables at:name ifAbsentPut:[ ValueHolder new ].

    ^ holder

!

anyWorkspaceVariableIsDefined

    ^ WorkspaceVariables notEmptyOrNil

    "Created: / 20-04-2005 / 11:57:53 / cg"

!