more adding support is required - especially for row-wise

	construction.

	The programmatic interface is best suited for row-wise

	arranged components; laying out elements in columns is a bit

	complicate - for complicated dialogs, it may be better to not use

	the automatic arrangement, but instead give explicit layouts to

	the components (in a subclass).

	For ST-80 compatibility, DialogBox is also accessable under

	the global named 'Dialog' (which is the name of an ST-80 class,

	providing a very similar protocol).

	This may lead to confusion, if DialogBox is recompiled - you have

	to manually assign Dialog again to refer to the new DialogBox class.

	In future versions of ST/X, DialogBox may be renamed to Dialog.

	originally, ST/X had separate classes for the various entry methods;

	there were YesNoBox, EnterBox, InfoBox and so on.

	ST-80 has all this defined in the common Dialog.

	Therefore, for compatibility, many ST/X methods defined here in Dialogs 

	class protocol simply dispatch to some other boxes class method.

	In the future, those existing subclasses' functionality is going to

	be moved full into Dialog, and the subclasses will be replaced by dummy

	delegators. (They will be kept for backward compatibility, though).

	buttonPanel      <PanelView>    contains the button(s)

	okButton         <Button>       the ok-Button

	okAction         <Block>        the action to be performed when ok is pressed,

					or return is pressed.

	acceptReturnAsOK <Boolean>      if true, pressing the return-key counts

					as if ok was pressed. Default is true.

	abortButton      <Button>       the cancel-Button

	abortAction      <Block>        the action to be performed when cancel is

					pressed.

	yPosisition      <Integer>      current y position when adding components

	leftIndent       <Integer>      left inset to use when adding components

	rightIndent      <Integer>      right inset to use when adding components

	addedComponents  <Collection>   programmatically added components

	inputFieldGroup  <EnterFieldGroup>   

					for added input fields

	acceptOnLeave    <Boolean>      if true (the default) and there are 

					tabable inputFields, accept and close when

					the last field is left. If false, the ok

					button must be pressed to close the box.

	acceptedValue    v(<Boolean>)   valueHolder on a boolean

					after close: holds true if box was accepted

					(i.e. ok-Button was pressed), false if box was

					closed via cancel or window manager.

	autoAccept       Boolean        if true, pressing ok (or return)

					sends #accept to all subcomponents.

					I.e. all subfields update their models

					first. The default is true.

	Claus Gittinger

	Button CheckToggle Toggle

	EditField SelectionInListView FileSelectionList

	FramedBox Separator

	( introduction to view programming :html: programming/viewintro.html )

									[exBegin]

	Dialog information:'hi there'

									[exEnd]

									[exBegin]

	Dialog warn:'oops'

									[exEnd]

									[exBegin]

	(Dialog confirm:'is this simple ?')

	ifTrue:[

	    Transcript showCR:'thats what I expected'

	] ifFalse:[

	    Transcript showCR:'read more examples and documentation'

	]

									[exEnd]

									[exBegin]

	|answer|

	answer := Dialog confirmWithCancel:'is this simple ?'.

	answer isNil ifTrue:[

	    Transcript showCR:'no easy decision'

	] ifFalse:[

	    answer ifTrue:[

		Transcript showCR:'thats what I expected'

	    ] ifFalse:[

		Transcript showCR:'read more examples and documentation'

	    ]

	]

									[exEnd]

									[exBegin]

	|s|

	s := Dialog request:'enter your name, please:'.

	s notEmpty ifTrue:[

	    Transcript showCR:'you entered: ' , s.

	]

									[exEnd]

									[exBegin]

	|s|

	s := Dialog 

		request:'enter your name, please:'

		initialAnswer:(OperatingSystem getLoginName).

	s notEmpty ifTrue:[

	    Transcript showCR:'you entered: ' , s.

	]

									[exEnd]

									[exBegin]

	|s|

	s := Dialog 

		requestFileName:'select a file, please:'

		default:''.

	Transcript show:'you entered: '; showCR:s.

									[exEnd]

									[exBegin]

	|s|

	s := Dialog 

		requestFileName:'select a file, please:'

		default:''

		pattern:'*.rc'.

	Transcript show:'you entered: '; showCR:s.

									[exEnd]

									[exBegin]

	|s|

	s := Dialog 

		requestFileName:'select a file, please:'

		default:''

		pattern:'*.rc;*.st;*.h'.

	Transcript show:'you entered: '; showCR:s.

									[exEnd]

									[exBegin]

	|s|

	s := Dialog 

		requestFileName:'select a file, please:'

		default:''

		ok:'show'

		abort:'cancel'

		pattern:'*.rc'.

	Transcript show:'you entered: '; showCR:s.

									[exEnd]

									[exBegin]

	|s|

	s := Dialog 

		requestPassword:'enter your secret, please:'.

	Transcript show:'you entered: '; showCR:s.

									[exEnd]

									[exBegin]

	Dialog 

	   choose:'choose any' 

	   fromList:nil

	   values:nil

	   buttons:#('one' 'two' 'three' 'four') 

	   values:#(1 2 3 4) 

	   lines:nil

	   cancel:nil

									[exEnd]

									[exBegin]

	 Transcript showCR:(

	     Dialog 

		choose:'choose example' 

		fromList:#('one' 'two' 'three' 'four') 

		values:#(1 2 3 4) 

		buttons:#('five' 'six' 'seven')

		values:#(5 6 7)

		lines:4

		cancel:[Transcript flash. #aborted]

	 )

									[exEnd]

									[exBegin]

	DialogBox new open

									[exEnd]

									[exBegin]

	DialogBox new addOkButton; open

									[exEnd]

									[exBegin]

	DialogBox new addAbortButton; addOkButton; open

									[exEnd]

									[exBegin]

	DialogBox new addAbortButton; addOkButtonLabelled:'yeah'; open

									[exEnd]

									[exBegin]

	DialogBox new

	    addTextLabel:'hello';

	    addOkButton; 

	    open

									[exEnd]

									[exBegin]

	DialogBox new

	    addTextLabel:'hello';

	    addAbortButton; 

	    addOkButton; 

	    open

									[exEnd]

									[exBegin]

	|box|

	box := DialogBox new.

	(box addTextLabel:'hello') adjust:#left.

	box addAbortButton; 

	    addOkButton; 

	    open

									[exEnd]

									[exBegin]

	|box|

	box := DialogBox new.

	(box addTextLabel:'are you certain ?') adjust:#left.

	box addAbortButtonLabelled:'not really'. 

	(box addOkButtonLabelled:'yes, absolutely') 

		activeBackgroundColor:Color red. 

	box open

									[exEnd]

									[exBegin]

	|b box|

	box := DialogBox new.

	(box addTextLabel:'are you certain ?') adjust:#left.

	b := Button new.

	b activeLogo:(Image fromFile:'bitmaps/cancel_down.bmp').

	b passiveLogo:(Image fromFile:'bitmaps/cancel_up.bmp').

	b focusLogo:(Image fromFile:'bitmaps/cancel_focus.bmp').

	b beImageButton.

	box addAbortButton:b.

	b := Button new.

	b activeLogo:(Image fromFile:'bitmaps/ok_down.bmp').

	b passiveLogo:(Image fromFile:'bitmaps/ok_up.bmp').

	b focusLogo:(Image fromFile:'bitmaps/ok_focus.bmp').

	b beImageButton.

	box addOkButton:b.

	box open

									[exEnd]

									[exBegin]

	DialogBox new

	    addTextLabel:'hello';

	    addTextLabel:'world';

	    addAbortButton; 

	    addOkButton; 

	    open

									[exEnd]

									[exBegin]

	DialogBox new

	    label:'a simple dialog';

	    addTextLabel:'hello';

	    addAbortButton; 

	    addOkButton; 

	    extent:200@200;

	    sizeFixed:true;

	    open

									[exEnd]

									[exBegin]

	(DialogBox new

	    label:'a simple dialog';

	    addTextLabel:'hello';

	    addAbortButton; 

	    addOkButton; 

	    extent:200@200;

	    sizeFixed:true;

	    open

	) accepted ifTrue:[

	    Transcript showCR:'yes'

	] ifFalse:[

	    Transcript showCR:'no'

	]

									[exEnd]

									[exBegin]

	DialogBox new

	    addTextLabel:(Image fromFile:'bitmaps/garfield.gif');

	    addOkButton; 

	    open

									[exEnd]

									[exBegin]

	DialogBox new

	    addTextLabel:'hello';

	    addTextLabel:((Image fromFile:'bitmaps/garfield.gif')

				magnifiedTo:200@150);

	    addTextLabel:'world';

	    addAbortButton; 

	    addOkButton; 

	    open

									[exEnd]

									[exBegin]

	|stringModel|

	stringModel := '' asValue.

	(DialogBox new

	    addTextLabel:'Please enter a string:';

	    addInputFieldOn:stringModel; 

	    addAbortButton; 

	    addOkButton; 

	    open

	) accepted ifTrue:[

	    Transcript showCR:'entered: ', stringModel value

	]

									[exEnd]

									[exBegin]

	|firstName lastName|

	firstName := '' asValue.

	lastName := '' asValue.

	(DialogBox new

	    addTextLabel:'Please enter your name:';

	    addInputFieldOn:firstName; 

	    addVerticalSpace;

	    addInputFieldOn:lastName; 

	    addAbortButton; 

	    addOkButton; 

	    open

	) accepted ifTrue:[

	    Transcript showCR:'entered: ', firstName value , ' ' , lastName value

	]

									[exEnd]

									[exBegin]

	|firstName lastName p line i name|

	firstName := '' asValue.

	lastName := '' asValue.

	p := PipeStream readingFrom:'finger ' , OperatingSystem getLoginName.