"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg' }"

"{ NameSpace: Smalltalk }"

ListView subclass:#TextView

	instanceVariableNames:'selectionStartLine selectionStartCol selectionEndLine

		selectionEndCol clickPos clickStartLine clickStartCol clickLine

		clickCol clickCount expandingTop wordStartCol wordStartLine

		wordEndCol wordEndLine selectionFgColor selectionBgColor

		selectStyle directoryForFileDialog defaultFileNameForFileDialog

		externalEncoding contentsWasSaved searchAction lastSearchPattern

		lastSearchWasMatch lastSearchIgnoredCase lastSearchDirection

		lastSearchWasVariableSearch parenthesisSpecification dropSource

		dragIsActive saveAction st80SelectMode searchBarActionBlock'

	classVariableNames:'DefaultViewBackground DefaultSelectionForegroundColor

		DefaultSelectionBackgroundColor

		DefaultAlternativeSelectionForegroundColor

		DefaultAlternativeSelectionBackgroundColor MatchDelayTime

		WordSelectCatchesBlanks LastSearchPatterns

		NumRememberedSearchPatterns LastSearchIgnoredCase

		LastSearchWasMatch DefaultParenthesisSpecification

		LastSearchWasMatchWithRegex LastSearchWasWrapAtEndOfText

		LastSearchWasReplace LastSearchReplacedString'

	poolDictionaries:''

	category:'Views-Text'

!

!TextView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    a view for readOnly text - this class adds selections to a simple list.

    The text is not editable and there is no cursor.

    Use TextViews for readonly text, EditTextView for editable text.

    Please read the historic notice in the ListView class.

    [Instance variables:]

      selectionStartLine      <Number>                the line of the selection start (or nil)

      selectionStartCol       <Number>                the col of the selection start

      selectionEndLine        <Number>                the line of the selection end

      selectionEndCol         <Number>                the col of the selection end

      clickStartLine          <Number>                temporary - remember where select operation started

      clickStartCol           <Number>                temporary

      clickLine               <Number>                temporary

      clickCol                <Number>                temporary

      clickCount              <Number>                temporary

      expandingTop            <Boolean>               temporary - for expandSelection

      selectionFgColor        <Color>                 color used to draw selections

      selectionBgColor        <Color>                 color used to draw selections

      selectStyle             <Symbol>                how words are selected

      directoryForFileDialog  <nil|pathName>          directory where save dialog should start

      contentsWasSaved        <Boolean>               set to true, whenever saved in a file

      externalEncoding        <Symbol|nil>            external encoding, used when text is saved to

						      a file. Usually something like

						      #jis7, #euc, #sjis etc.

						      (currently only passed down from the

						       fileBrowser)

      dropSource              <DropSource>            drag operation descriptor or nil (dragging disabled)

      dragIsActive            <Boolean>               true, drag operation is activated

      searchAction            <Block>                 an autosearch action; typically set by the browser.

						      Will be used as default when searchFwd/searchBwd is

						      pressed. If the searchPattern is changed, no autosearch

						      action will be executed.

      searchBarActionBlock    <Block>                 search action block for embedded search

						      panel. Used as second chance for searchFwd/bwd

    [class variables:]

	ST80Selections        <Boolean>               enables ST80 style doubleclick behavior

						      (right after opening parenthesis, right before

						       closing parenthesis, at begin of a line

						       at begin of text)

    [StyleSheet parameters:]

      textView.background                       defaults to viewBackground

      textView.ViewFont                         defaults to textFont

      text.st80Selections                       st80 behavior (click on char after parent or quote)

      text.selectionForegroundColor             defaults to textBackgroundColor

      text.selectionBackgroundColor             defaults to textForegroundColor

      text.alternativeSelectionForegroundColor  pasted text (i.e. paste will not replace)

						defaults to selectionForegroundColor

      text.alternativeSelectionBackgroundColor  pasted text (i.e. paste will not replace)

						defaults to selectionBackgroundColor

    [author:]

	Claus Gittinger

    [see also:]

	EditTextView CodeView Workspace

"

!

examples

"

    although textViews (and instances of subclasses) are mostly used

    as components (in the fileBrowser, the browser, the launcher etc.),

    they may also be opened as a textEditor;

    open a (readonly) textView on some information text:

							[exBegin]

	TextView

	    openWith:'read this'

	    title:'demonstration'

							[exEnd]

    the same, but open it modal:

							[exBegin]

	TextView

	    openModalWith:'read this first'

	    title:'demonstration'

							[exEnd]

    open it modal (but editable) on some text:

    (must accept before closing)

    This is somewhat kludgy - when closed, the view has already

    nilled its link to the model. Therefore, the accept must be

    done 'manually' below.

    However, usually an applicationModel is installed as the

    editor-topViews application. This would get a closeRequest,

    where it could handle things.

							[exBegin]

	|m textView|

	m := 'read this first' asValue.

	textView := EditTextView openModalOnModel:m.

	textView modified ifTrue:[

	    (self confirm:'text was not accepted - do it now ?')

	    ifTrue:[

		m value:textView contents

	    ]

	].

	Transcript showCR:m value.

							[exEnd]

    open a textEditor on some file:

							[exBegin]

	EditTextView openOn:'Makefile'

							[exEnd]

"

! !

!TextView class methodsFor:'instance creation'!

on:aModel aspect:aspect change:change menu:menu initialSelection:initial

    "for ST-80 compatibility"

    ^ (self new)

	on:aModel

	aspect:aspect

	list:aspect

	change:change

	menu:menu

	initialSelection:initial

!

with:someText

    ^ (self new)

	contents:someText

! !

!TextView class methodsFor:'class initialization'!

initialize

    DefaultParenthesisSpecification isNil ifTrue:[

	DefaultParenthesisSpecification := IdentityDictionary new.

	DefaultParenthesisSpecification at:#open        put:#( $( $[ ${ "$> $<") .

	DefaultParenthesisSpecification at:#close       put:#( $) $] $} "$> $<").

	DefaultParenthesisSpecification at:#ignore      put:#( $' $" '$[' '$]' '${' '$)' ).

	DefaultParenthesisSpecification at:#eolComment  put:'"/'.     "/ sigh - must be 2 characters

    ].

! !

!TextView class methodsFor:'defaults'!

defaultIcon

    "return the default icon if started as a topView"

    <resource: #programImage>

    <resource: #style (#ICON #ICON_FILE)>

    |nm i|

    i := self classResources at:'ICON' default:nil.

    i isNil ifTrue:[

	nm := ClassResources at:'ICON_FILE' default:'Editor.xbm'.

	i := Smalltalk imageFromFileNamed:nm forClass:self.

    ].

    i notNil ifTrue:[

	i := i onDevice:Display

    ].

    ^ i

    "Modified: / 17-09-2007 / 11:36:29 / cg"

!

defaultMenuMessage

    "This message is the default yo be sent to the menuHolder to get a menu"

    ^ #editMenu

    "Created: 3.1.1997 / 01:52:21 / stefan"

!

defaultParenthesisSpecification

    ^ DefaultParenthesisSpecification

    "Created: / 14-06-2011 / 14:00:59 / cg"

!

defaultSelectionBackgroundColor

    "return the default selection background color"

    ^DefaultSelectionBackgroundColor

!

defaultSelectionForegroundColor

    "return the default selection foreground color"

    ^DefaultSelectionForegroundColor

!

defaultViewBackgroundColor

    "return the default view background"

    ^DefaultViewBackground

!

lastSearchIgnoredCase

    ^ LastSearchIgnoredCase

!

lastSearchWasMatch

    ^ LastSearchWasMatch

!

st80SelectMode

    ^ UserPreferences current st80SelectMode

    "Modified: / 03-07-2006 / 16:26:44 / cg"

!

st80SelectMode:aBoolean

    UserPreferences current st80SelectMode:aBoolean

    "Created: / 07-01-1999 / 13:35:24 / cg"

    "Modified: / 03-07-2006 / 16:27:01 / cg"

!

updateStyleCache

    "extract values from the styleSheet and cache them in class variables"

    <resource: #style (#'textView.background'

                       #'text.selectionForegroundColor'

                       #'text.selectionBackgroundColor'

                       #'text.alternativeSelectionForegroundColor'

                       #'text.alternativeSelectionBackgroundColor'

                       #'textView.font'

                       #'text.wordSelectCatchesBlanks'

                       #'text.st80Selections')>

    DefaultViewBackground := StyleSheet colorAt:'textView.background' default:Color white.

    DefaultSelectionForegroundColor := StyleSheet colorAt:'text.selectionForegroundColor'.

    DefaultSelectionBackgroundColor := StyleSheet colorAt:'text.selectionBackgroundColor'.

"/    DefaultAlternativeSelectionForegroundColor := StyleSheet colorAt:'text.alternativeSelectionForegroundColor' default:DefaultSelectionForegroundColor.

"/    DefaultAlternativeSelectionBackgroundColor := StyleSheet colorAt:'text.alternativeSelectionBackgroundColor' default:DefaultSelectionBackgroundColor.

    DefaultAlternativeSelectionForegroundColor := DefaultSelectionForegroundColor.

    DefaultAlternativeSelectionBackgroundColor := DefaultSelectionBackgroundColor.

    DefaultFont := StyleSheet fontAt:'textView.font'.

    MatchDelayTime := 0.6.

    WordSelectCatchesBlanks := StyleSheet at:'text.wordSelectCatchesBlanks' default:false.

    "Modified: / 03-07-2006 / 16:29:42 / cg"

! !

!TextView class methodsFor:'help specs'!

flyByHelpSpec

    "This resource specification was automatically generated

     by the UIHelpTool of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the UIHelpTool may not be able to read the specification."

    "

     UIHelpTool openOnClass:TextView

    "

    <resource: #help>

    ^ Dictionary new addPairsFrom:#(

#matchSearch

'Search for a pattern (GLOB) as opposed to a direct string search'

#searchCaseSensitive

'Care for case differences'

#searchFullWord

'Search only for full words (ignore occurrences in substring)'

#searchAtBeginOfLineOnly

'Search only for the string at the beginning of a line'

#searchPattern

'String or match-pattern to be searched'

#searchVariable

'Search only for that variable name (ignore occurrences in other contexts)'

#replaceText

'If checked, matching text is replaced by this'

#selectLines

'If checked, lines containing the matched string are selected.'

#replacePreserveCase

'Preserve the title case of replaced text'

#replaceAll

'Search and replace all occurrences of the searched string'

#searchWithWrap

'Wrap around at the end of the text, and continue the search from the top'

#matchWithRegex

'Use regex pattern for search (as opposed to GLOB pattern)'

)

! !

!TextView class methodsFor:'interface specs'!

searchDialogSpec

    "This resource specification was automatically generated

     by the UIPainter of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the UIPainter may not be able to read the specification."

    "

     UIPainter new openOnClass:TextView andSelector:#searchDialogSpec

    "

    <resource: #canvas>

    ^

    #(FullSpec

       name: searchDialogSpec

       window:

      (WindowSpec

	 label: 'String search'

	 name: 'String search'

	 min: (Point 10 10)

	 max: (Point 1280 1024)

         bounds: (Rectangle 0 0 475 376)

       )

       component:

      (SpecCollection

	 collection: (

	  (LabelSpec

	     label: 'SearchPattern:'

	     name: 'label'

	     layout: (LayoutFrame 1 0.0 3 0 -1 1.0 20 0)

	     level: 0

	     translateLabel: true

	     adjust: left

	   )

	  (ComboBoxSpec

	     name: 'patternComboBox'

	     layout: (LayoutFrame 2 0.0 26 0 -2 1.0 48 0)

	     activeHelpKey: searchPattern

	     tabable: true

	     model: searchPattern

	     immediateAccept: false

	     acceptOnLeave: true

	     acceptOnReturn: true

	     acceptOnTab: true

	     acceptOnLostFocus: true

	     acceptOnPointerLeave: false

	     autoSelectInitialText: true

	     comboList: patternList

	   )

	  (VerticalPanelViewSpec

	     name: 'VerticalPanel1'

             layout: (LayoutFrame 0 0.0 52 0 0 1.0 -32 1)

	     horizontalLayout: fit

	     verticalLayout: top

	     component:

	    (SpecCollection

	       collection: (

		(CheckBoxSpec

		   label: 'Case Sensitive'

		   name: 'ignoreCaseCheckBox'

		   activeHelpKey: searchCaseSensitive

		   level: 0

		   tabable: true

		   model: caseSensitive

		   translateLabel: true

                   extent: (Point 475 24)

		 )

                (ViewSpec

                   name: 'MatchBox'

                   component: 

                  (SpecCollection

                     collection: (

                      (CheckBoxSpec

                         label: 'Match (forward only)'

                         name: 'matchCheckBox'

                         layout: (LayoutFrame 0 0 0 0 260 0 0 1)

                         activeHelpKey: matchSearch

                         level: 0

                         tabable: true

                         model: match

                         translateLabel: true

                       )

                      (CheckBoxSpec

                         label: 'Regex Match'

                         name: 'CheckBox6'

                         layout: (LayoutFrame -170 1 0 0 0 1 22 0)

                         activeHelpKey: matchWithRegex

                         enableChannel: matchWithRegexVisible

                         model: matchWithRegex

                         translateLabel: true

                       )

                      )

                   )

                   extent: (Point 475 24)

		 )

		(CheckBoxSpec

		   label: 'Search Full Words'

		   name: 'CheckBox2'

		   activeHelpKey: searchFullWord

		   level: 0

		   enableChannel: searchFullWordEnabled

		   tabable: true

		   model: searchFullWord

		   translateLabel: true

                   extent: (Point 475 24)

                 )

                (CheckBoxSpec

                   label: 'At Begin of Line Only'

                   name: 'CheckBox5'

                   activeHelpKey: searchAtBeginOfLineOnly

                   level: 0

                   tabable: true

                   model: searchAtBeginOfLineOnly