"

 COPYRIGHT (c) 1997 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

ImageView subclass:#ImageEditView

	instanceVariableNames:'magnification selectColors imageReaderClass resourceClass

		resourceSelector mouseKeyColorMode undoImage modified

		masterApplication editMode'

	classVariableNames:'Clipboard GridMagnification'

	poolDictionaries:''

	category:'Views-Misc'

!

!ImageEditView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    The ImageEditView is a view class which can be used by applications

    like the Image Editor for modifying or inspecting images.

    [see also:]

        ImageEditor Image

    [author:]

        Thomas Zwick

"

! !

!ImageEditView methodsFor:'accessing'!

magnification

    ^magnification

!

magnification: aPoint

    magnification ~= aPoint

    ifTrue:

    [

        magnification := aPoint asPoint.

        self scrollToTopLeft.

        self contentsChanged.

        self invalidate

    ]

!

masterApplication

    ^masterApplication

!

masterApplication: anApplicationModel

    masterApplication := anApplicationModel

!

resourceClass

    ^resourceClass

!

resourceClass: aClassOrSymbol

    resourceClass := aClassOrSymbol isClass ifTrue: [aClassOrSymbol name] ifFalse: [aClassOrSymbol asSymbol]

!

resourceMessage

    ^resourceClass, ' ', resourceSelector

!

resourceMessage: aString

    (aString isString and: [aString trimBlanks size > 0])

    ifTrue:

    [

        resourceClass := (aString readStream upTo: Character space) asSymbol.

        resourceSelector := (aString copy reverse readStream upTo: Character space) reverse asSymbol

    ]

    ifFalse:

    [

        ^nil

    ]

!

resourceSelector

    ^resourceSelector

!

resourceSelector: aStringOrSymbol

    resourceSelector := aStringOrSymbol asSymbol

!

selectColors

    ^selectColors

!

selectColors: anArrayTwoColors

    selectColors := anArrayTwoColors

!

selectedColor

   ^selectColors at: mouseKeyColorMode

!

selectedColor: aColor

    selectColors at: mouseKeyColorMode put: aColor

! !

!ImageEditView methodsFor:'drawing'!

fillFramedRectangle: aRectangle

    self fillRectangle: aRectangle.

    self drawFramesIn: aRectangle

!

redrawImageX:x y:y width:w height:h

    |ih iw magX magY minX maxX minY maxY color lastColor lastY runW x0 xI yI maskColor sizeOfMaskPoint|

    ih := image height.

    iw := image width.

    magX := magnification x.

    magY := magnification y.

    minX := (x // magX - 1) max: 0.

    minX >= iw ifTrue:[minX := (iw - 1) max: 0].

    minY := (y // magY - 1) max: 0.

    minY >= ih ifTrue:[minY := (ih - 1) max: 0].

    maxX := (x + w) // magX + 1.

    maxX > iw ifTrue:[maxX := iw].

    maxY := (y + h) // magY + 1.

    maxY > ih ifTrue:[maxY := ih].

    lastY := -1.

    x0 := minX.

    runW := 0.

    maskColor := false.

    sizeOfMaskPoint := magnification//3.

    image colorsFromX: minX y: minY toX: maxX-1 y: maxY-1 do:

    [:xx :yy :color|

        yy ~~ lastY

        ifTrue:

        [

            runW ~~ 0

            ifTrue:

            [

                |origin|

                origin := (x0 * magX + margin)@(lastY * magY + margin).

                self fillFramedRectangle: (origin extent: (runW@magY)).                    

                maskColor ifTrue:

                [

                    self xoring: [self fillRectangle: (origin + sizeOfMaskPoint extent: sizeOfMaskPoint)]

                ].

                runW := 0.

            ]. 

            x0 := xx.

            lastY := yy.

        ]. 

        color ~~ lastColor

        ifTrue:

        [

            runW ~~ 0

            ifTrue:

            [

                |origin|

                origin := (x0 * magX + margin)@(yy * magY + margin).

                self fillFramedRectangle: (origin extent: (runW@magY)).

                maskColor ifTrue:

                [

                    self xoring: [self fillRectangle: (origin + sizeOfMaskPoint extent: sizeOfMaskPoint)]

                ].

                runW := 0.

            ].

            self paint: (lastColor := color).

            image mask notNil ifTrue:

            [  

                maskColor := false.

                (image mask colorAt: xx@yy) = Color black ifTrue:

                [

                    self paint: (lastColor := self viewBackground).

                    maskColor := true.

                ].

                lastColor := nil.

            ].

            runW := 0.

            x0 := xx.

        ].  

        runW := runW + magX

    ].

    runW ~~ 0 ifTrue:

    [

        |origin|

        origin := (x0 * magX + margin)@(lastY * magY + margin).

        self fillFramedRectangle: (origin extent: runW@magY).

        maskColor ifTrue:

        [

            self xoring: [self fillRectangle: (origin + sizeOfMaskPoint extent: sizeOfMaskPoint)]

        ].

        runW := 0.

    ].

!

redrawX:x y:y width:w height:h

    |ih iw xI yI|

    magnification = (1@1) ifTrue: [^super redrawX:x y:y width:w height:h].

    image isNil ifTrue:[^self].

    self clippingRectangle: (x@y extent: w@h).

    self redrawImageX:x y:y width:w height:h.

    "/ right of image ?

    adjust == #center ifTrue:

    [

        xI := (width - ih) // 2 - margin.

        yI := (height - iw) // 2 - margin.

    ]

    ifFalse:

    [

        xI := yI := margin

    ].

    (x + w - 1) > (xI + (magnification x * image width)) ifTrue:

    [

        self clearRectangleX:(xI + (magnification x * image width))

                           y:y

                       width:(x + w - (magnification x * image width) - xI)

                      height:h

    ].

    (y + h - 1) > (yI + (magnification y * image height)) ifTrue:

    [

        self clearRectangleX:margin

                           y:(yI + (magnification y * image height))

                       width:w

                      height:(y + h - (magnification y * image height) - yI)  

    ].

    self drawFrame.

    self clippingRectangle: nil.

! !

!ImageEditView methodsFor:'edit modes'!

editMode

    ^editMode ? (editMode := 'point')

!

editMode:aMode

    editMode := aMode

!

mouseKeyColorMode

    ^mouseKeyColorMode printString

!

mouseKeyColorMode:aMode

    mouseKeyColorMode := aMode asInteger

! !

!ImageEditView methodsFor:'event handling'!

buttonMotion:state x:x y:y

    self drawCursorAt: x@y.

    state ~~ 0

    ifTrue:

    [

        self selectedColor notNil & image notNil & (self imageContainsPoint: x@y) & (editMode = 'point')

            ifTrue: [^self pointAt: x@y]

    ]

!

buttonPress:button x:x y:y

    self drawCursorAt: x@y.

    self selectedColor notNil & image notNil & (self imageContainsPoint: x@y)

    ifTrue:

    [   

        |mouseButtonColorToolBar|

        mouseKeyColorMode := button.

        mouseButtonColorToolBar := masterApplication builder componentAt: #MouseButtonColorToolBar.

        undoImage := image copy.

        masterApplication valueOfCanUndo value: true.

        (mouseButtonColorToolBar itemAt: mouseKeyColorMode) toggleIndication.

        mouseButtonColorToolBar do: [:i| i updateIndicators].

        self perform: (editMode, 'At:') asSymbol with: x@y

    ]

!

pointerLeave:state

    super pointerLeave: state.

    self drawLabel: self imageInfoString.

    Cursor normal show

! !

!ImageEditView methodsFor:'image editing'!

boxAt: aPoint

    |choosedBox imageBox|

    choosedBox := self drawRectangleStartingAt: aPoint emphasis: #box.

    image rectangle: (imageBox := choosedBox origin//magnification extent: (choosedBox extent//magnification)) withColor: self selectedColor.

    image restored.

    self redraw: (choosedBox expandedBy: 1).

    masterApplication imagePreView redraw: (imageBox expandedBy: 1).

    modified := true

!

copyAt: aPoint

    |choosedBox|

    choosedBox := self drawRectangleStartingAt: aPoint emphasis: #inverseFilledBox.

    Clipboard := image subImageIn: (choosedBox origin//magnification extent: (choosedBox extent//magnification)).

    self redraw: (choosedBox expandedBy: 1)    

!

fillAt: aPoint

    Cursor execute showWhile:

    [

        |filledPoints|

        filledPoints := image floodFillAt: aPoint//magnification withColor: self selectedColor.

        image restored.

        filledPoints size < 300

        ifTrue:

        [

            filledPoints do: [:p| self redraw: ((p * magnification extent: magnification) expandedBy: 1)]

        ]

        ifFalse:

        [

            self invalidate

        ].

        masterApplication imagePreView invalidate.

        modified := true

    ]

!

filledBoxAt: aPoint

    |choosedBox imageBox|

    choosedBox := self drawRectangleStartingAt: aPoint emphasis: #filledBox.

    image fillRectangle: (imageBox := choosedBox origin//magnification extent: (choosedBox extent//magnification)) withColor: self selectedColor.

    image restored.

    self redraw: (choosedBox expandedBy: 1).

    masterApplication imagePreView redraw: (imageBox expandedBy: 1).

    modified := true

!

flipHorizontal

    self image: image copy flipHorizontal

!

flipVertical

    self image: image copy flipVertical

!

magnifyImage

    |box newSize|

    box := EnterBox new.

    box title:'Image new size:'.

    box okText:'OK'.

    box abortText:'Cancel'.

    box initialText:image extent printString.

    box showAtPointer.

    (box accepted and: [(newSize := Object readFromString: box contents onError:nil) notNil])

    ifTrue:

    [

        self image: (image magnifiedBy: newSize/image extent)

    ]

!

negativeImage

    self image: image copy negative

!

pasteAt: aPoint

    Object errorSignal handle:

    [:ex|

        self warn: 'Pasting at selected point failed!!'

    ] 

    do:

    [   

        |imagePoint imageBox|

        imagePoint := aPoint//magnification.

        image copyFrom: Clipboard x:0 y:0 toX: imagePoint x y: imagePoint y width: Clipboard width height: Clipboard height.

        image restored.

        self redraw: (imageBox := (imagePoint * magnification extent: (Clipboard extent * magnification)) expandedBy: 1@1).

        masterApplication imagePreView redraw: (imageBox expandedBy: 1).

        modified := true

    ]

!

pointAt: aPoint

    |imagePoint imageBox|

    imagePoint := aPoint//magnification.

    image atImageAndMask: imagePoint put: self selectedColor.

    image restored.

    self redraw: (imageBox := (imagePoint * magnification extent: magnification) expandedBy: 1).

    masterApplication imagePreView redraw: ((imagePoint - 1) extent: 3@3).

    modified := true.

!

resizeImage

    |box newSize|

    box := EnterBox new.

    box title:'Image new size:'.

    box okText:'OK'.

    box abortText:'Cancel'.

    box initialText:image extent printString.

    box showAtPointer.

    (box accepted and: [(newSize := Object readFromString: box contents onError:nil) notNil])

    ifTrue:

    [

        |newImage|

        newImage := image class width: newSize x height: newSize y depth: image depth.

        newImage photometric:image photometric.

        newImage colorMap:image colorMap copy.

        newImage bits: (ByteArray new: newImage bytesPerRow * newSize y).

        image mask notNil

        ifTrue: 

        [

            |newMaskImage|

            newMaskImage := Depth1Image width: newSize x height: newSize y.

            newMaskImage photometric: image mask photometric.

            newMaskImage colorMap: image mask colorMap copy.

            newMaskImage bits:(ByteArray new: newMaskImage bytesPerRow * newSize y).

            newImage mask: newMaskImage

        ].