"

 COPYRIGHT (c) 1997 by Claus Gittinger / eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

"{ NameSpace: Smalltalk }"

Object subclass:#DataSetColumn

	instanceVariableNames:'columnNumber dataSet width description buttonExtent rendererType

		backgroundColor foregroundColor rowSeparatorSelector

		showColSeparator showRowSeparator columnAlignment label

		containsText columnAdaptor descWidth descMinWidth

		longStringCompression minValue maxValue'

	classVariableNames:''

	poolDictionaries:''

	category:'Views-DataSet'

!

!DataSetColumn class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by Claus Gittinger / eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    represent one single column description of a DataSetView

    [Instance variables:]

        columnNumber    <Integer>               sequence number (into list of columns)

        dataSet         <DSVColumnView>         the view it belongs to

        width           <Integer>               width of column

        description     <DataSetColumnSpec>     the column description (a spec)

        buttonExtent    <Point>                 extent of drawable form

        rendererType    <Type>                  renderer type (cached value from

                                                the column specification).

        backgroundColor <Color or nil>          background color of all cells or nil

                                                (nil: use default background color).

        foregroundColor <Color or nil>          foreground color of all cells or nil

                                                (nil: use default foreground color).

        columnAlignment <Symbol>                align text/icon #left #right or #center

                                                in row (on default: #left).

        label           <label/icon or nil>     label resolved by the builder shown

                                                in the column description field.

        readSelector    <Symbol>                cached readSelector (from the spec)

        columnAdaptor   <nil or any>            if non-nil, that one is asked (via

                                                read-writeSelectors to extract a column

                                                from a row object.

                                                If nil, the row object is used itself.

        showColSeparator <Boolean>              true: vertical separators are enabled;

                                                separator between columns

        showRowSeparator <Boolean>              true: horizontal separators are enabled;

                                                separator between rows

        rowSeparatorSelector <Selector or nil>  access specific showRowSeparator state

                                                for a cell

    [from description:]

        fgSelector      <Selector or nil>       access specific foreground color for

                                                a cell

        bgSelector      <Selector or nil>       access specific background color for

                                                a cell

        numberOfRowsProbedForColumnSize         the number of rows which are queries

                                <Integer>       in order to compute the columns width.

                                                (for scrollBar/col width computation)

                                                Notice, if it's expensive to fetch rows

                                                (dataBase apps), this should be small.

                                                Default:15

    [author:]

        Claus Atzkern

    [see also:]

        DataSetColumnSpec

        DSVColumnView

        DataSetView

"

! !

!DataSetColumn class methodsFor:'utilities'!

shortenedStringFor:aString on:aGC maxWidth:maxWidth

    "common code to shorten a string; used in both the DSV label- and column Views,  

     if the string is too long for the column"

    ^ self shortenedStringFor:aString on:aGC maxWidth:maxWidth shortenedAtLeft:false

!

shortenedStringFor:aString on:aGC maxWidth:maxWidth shortenedAtLeft:shortenedAtLeft

    "common code to shorten a string; used in both the DSV label- and column Views,  

     if the string is too long for the column"

    |widthOf3Dots wRest shortenedLabel lUsed lMin lMax|

    aString isString ifFalse:[^ aString].

    (aString widthOn:aGC) <= maxWidth ifTrue:[^ aString].

    widthOf3Dots := '...' widthOn:aGC.

    lMin := 1.

    lMax := aString size.

    [ 

        lUsed := (lMax + lMin) // 2.

        wRest := aString widthFrom:1 to:lUsed on:aGC.

        wRest > (maxWidth-widthOf3Dots) ifTrue:[

            lMax := lUsed - 1.

        ] ifFalse:[

            lMin := lUsed + 1.

        ].

        lMin < lMax

    ] whileTrue.

    shortenedLabel := aString copyFrom:1 to:lUsed.

    shortenedLabel isEmpty ifTrue:[

        ((aString first asString , '..') widthOn:aGC) < maxWidth ifTrue:[

            "/ only two dots and the first/last character

            shortenedAtLeft ifTrue:[

                ^ ('..',aString last asString)

            ].        

            ^ (aString first asString,'..')

        ]

    ].

    shortenedAtLeft ifTrue:[

        ^ ('...',shortenedLabel).

    ].

    ^ (shortenedLabel,'...').

! !

!DataSetColumn methodsFor:'accessing'!

activeHelpText

    "get the active helpText or nil"

    |app key|

    ((key := description activeHelpKey) notEmptyOrNil 

    and:[(app := dataSet application) notNil]) ifTrue:[

        ^ app helpTextForKey:key asSymbol.

    ].

    ^ nil

    "Created: / 26-03-2007 / 13:39:11 / cg"

    "Modified: / 26-03-2007 / 17:51:15 / cg"

!

activeHelpTextForLabel

    "get the active helpText for the label or nil"

    |app key|

    ((key := description activeHelpKeyForLabel) notEmptyOrNil 

    and:[(app := dataSet application) notNil]) ifTrue:[

        ^ app helpTextForKey:key asSymbol.

    ].

    ^ nil

    "Created: / 26-03-2007 / 13:39:11 / cg"

    "Modified: / 26-03-2007 / 17:51:15 / cg"

!

activeHelpTextForRow:rowNr

    "get the active helpText or nil"

    |app key|

    ((key := description activeHelpKey) notEmptyOrNil 

    and:[(app := dataSet application) notNil]) ifTrue:[

        ^ app helpTextForKey:key asSymbol row:rowNr.

    ].

    ^ nil

    "Created: / 26-03-2007 / 13:39:11 / cg"

    "Modified: / 26-03-2007 / 17:51:15 / cg"

!

at:aRowNr

    "get the value of the cell at the row index, aRowNr"

    |row|

    row := dataSet at:aRowNr.

    ^ self extractColFromRow:row rowNr:aRowNr.

!

at:aRowNr put:something

    "set the value of the cell at the row index, aRowNr"

    |row|

    row := dataSet at:aRowNr.

    self storeCol:something inRow:row.

!

columnAdaptor

    ^ columnAdaptor

!

columnAdaptor:anAdapter

    columnAdaptor := anAdapter.

!

columnNumber

    ^ columnNumber

!

description

    "returns the column spec

    "

    ^ description

!

doubleClickedSelector

    ^ description doubleClickedSelector

!

label

    "get the label assigned to the column

    "

    ^ label

!

longStringCompression

    ^ longStringCompression ? true

!

longStringCompression:aBoolean

    longStringCompression := aBoolean

!

longStringCompressionAtLeft

    ^ [description longStringCompressionAtLeft] on:Error do:[false]

!

rendererType

    "returns my renderer type

    "

    ^ rendererType

! !

!DataSetColumn methodsFor:'accessing-color & font'!

backgroundColor

    "returns the background color or nil

    "

    ^ backgroundColor == dataSet backgroundColor ifTrue:[nil] ifFalse:[backgroundColor]

!

backgroundColor: aColor

    backgroundColor := aColor

!

backgroundColorAt:aRowNr

    "returns the background color for a row at list index a rowNr

    "

    description backgroundSelector notNil ifTrue:[

        ^ self backgroundColorFor:(dataSet at:aRowNr) at:aRowNr

    ].

    ^ backgroundColor

!

backgroundColorFor:aRow at:aRowNr     

    "return the background color for a row at list index a rowNr"

    "/ backgroundColor has already been fetched from description/dataSet (see #initialize)

    ^ self

        colorFor:aRow at:aRowNr 

        descriptionSelector:(description backgroundSelector) 

        descriptionColor:backgroundColor 

        dataSetDefaultColor:nil

    "Modified: / 26-03-2007 / 13:27:19 / cg"

!

colorFor:aRow at:aRowNr descriptionSelector:descriptionSelector descriptionColor:descriptionColor dataSetDefaultColor:dataSetColor    

    "common code for returning a color for a row at list index a rowNr, asking both description and dataSet as fallBack"

    |clr|

    descriptionSelector notNil ifTrue:[

        columnAdaptor notNil ifTrue:[

            clr := columnAdaptor perform:descriptionSelector withOptionalArgument:aRow and:aRowNr and:columnNumber and:dataSet

        ] ifFalse:[

            "/ Check if row-object responds to the color message...

            (aRow respondsTo: descriptionSelector) ifTrue:[

                clr := aRow perform:descriptionSelector withOptionalArgument:aRowNr and:columnNumber and:dataSet

            ] ifFalse:[ 

                "/ ...if not, send the message to the application model. This allows application models to

                "/ define visual aspects while data still could be extracted from the row-objects directly. 

                | app |

                app := dataSet application.

                app notNil ifTrue:[ 

                    clr := app perform:descriptionSelector withOptionalArgument:aRow and:aRowNr and:columnNumber and:dataSet

                ].

            ].

        ].

        clr notNil ifTrue:[

            (clr isColor or:[clr isImageOrForm]) ifTrue:[

                ^ clr

            ].

            self error:'unexpected color (not a color or image)'.

        ]

    ].

    ^ descriptionColor ? dataSetColor

    "Created: / 26-03-2007 / 13:05:24 / cg"

    "Modified: / 23-09-2014 / 11:35:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

foregroundColor

    "returns the foreground color or nil

    "

    ^ foregroundColor == dataSet foregroundColor ifTrue:[nil] ifFalse:[foregroundColor]

!

foregroundColor: aColor

    foregroundColor := aColor

!

foregroundColorFor:aRow at:aRowNr

    "returns the foreground color for a row at list index a rowNr

    "

    "/ foregroundColor has already been fetched from description/dataSet (see #initialize)

    ^ self

        colorFor:aRow at:aRowNr 

        descriptionSelector:(description foregroundSelector) 

        descriptionColor:foregroundColor 

        dataSetDefaultColor:nil

    "Modified: / 26-03-2007 / 13:27:39 / cg"

!

selectedBackgroundColorFor:aRow at:aRowNr     

    "returns the selected background color for a row at list index a rowNr"

    ^ self

        colorFor:aRow at:aRowNr 

        descriptionSelector:(description selectedBackgroundSelector) 

        descriptionColor:(description selectedBackgroundColor) 

        dataSetDefaultColor:(dataSet selectionBackgroundColor)

    "Modified: / 26-03-2007 / 13:06:06 / cg"

!

selectedForegroundColorFor:aRow at:aRowNr     

    "returns the selected foreground color for a row at list index a rowNr"

    ^ self

        colorFor:aRow at:aRowNr 

        descriptionSelector:(description selectedForegroundSelector) 

        descriptionColor:(description selectedForegroundColor) 

        dataSetDefaultColor:(dataSet selectionForegroundColor)

    "Modified: / 26-03-2007 / 13:05:31 / cg"

!

selectedFrameColorFor:aRow at:aRowNr     

    "returns the selected frame color for a row at list index a rowNr"

    ^ self

        colorFor:aRow at:aRowNr 

        descriptionSelector:(description selectedBackgroundSelector) 

        descriptionColor:(description selectedBackgroundColor) 

        dataSetDefaultColor:(dataSet selectionFrameColor)

    "Created: / 20-01-2011 / 08:46:32 / cg"

! !

!DataSetColumn methodsFor:'accessing-dimension'!

minWidth

    "get the minimum width required by the column

    "

    descMinWidth notNil ifTrue:[

        ^ descMinWidth

    ].

    descWidth isInteger ifTrue:[

        ^ descWidth

    ].

    ^ 0.

"/   width := nil.

"/  ^ self width

!

minimumRequiredWidth

    "returns the minimum required width

    "

    |minWidth|

    descMinWidth notNil ifTrue:[

        minWidth := DSVLabelView tabSpacing max:2.

      ^ minWidth // 2 + minWidth

    ].

    minWidth := dataSet separatorSize + (2 * dataSet horizontalSpacing).

  ^ minWidth + label preferredWidth.

!

setDescWidth:aWidth

    "set a fixed width

    "

    descMinWidth := 1.

    descMinWidth := width := descWidth := self minimumRequiredWidth max:aWidth.

!

setWidth:pixels

    width := pixels

!

width

    "returns the width in pixels

     Warning:

        only the first numberOfRowsProbedForColumnSize are probed,

        in case the access is expensive (dataBase apps)

     If the descriptor defines a width, that is used, and the items

     are not probed at all."

    |max       "{ Class:SmallInteger }"

     listSize  "{ Class:SmallInteger }"|

    width notNil ifTrue:[^ width].              "/ already computed

    descMinWidth notNil ifTrue:[

        width := descMinWidth.

        ^ width

    ].

    (descWidth ~~ 0 and:[self hasRelativeWidth not "descWidth isLimitedPrecisionReal not"]) ifTrue:[

        width := descMinWidth := descWidth.

        ^ width

    ].

    width := (description minWidth ) max:(label preferredWidth).

    self hasRelativeWidth ifTrue:[

        width := width max:(descWidth * dataSet innerWidth) rounded.

        ^ width

    ].

    containsText ifTrue:[

        "/ take maximum numberOfRowsProbedForColumnSize entries to calculate the width;

        "/ can be resized later if necessary

        listSize := dataSet size.

        max := listSize min:description numberOfRowsProbedForColumnSize.

        max ~~ 0 ifTrue:[

            1 to:max do:[:rowNr| |row|

                row := dataSet at:rowNr.