"

 COPYRIGHT (c) 1988 by Claus Gittinger

 COPYRIGHT (c) 2009-2011 Jan Vrany

 COPYRIGHT (c) 2015-2018 Jan Vrany

 COPYRIGHT (c) 2020 LabWare

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

"{ NameSpace: Smalltalk }"

Object subclass:#Smalltalk

	instanceVariableNames:''

	classVariableNames:'StartBlocks ImageStartBlocks ExitBlocks CachedClasses

		NumberOfClassesHint SystemPath StartupClass StartupSelector

		StartupArguments CommandLine CommandName CommandLineArguments

		CachedAbbreviations VerboseStartup VerboseLoading Verbose

		SilentLoading Initializing StandAlone HeadlessOperation IsPlugin

		IsSharedLibraryComponent IsSTScript IsRepl DebuggingStandAlone

		Silent Debugging LogDoits LoadBinaries RealSystemPath

		ResourcePath SourcePath BinaryPath FileInPath PackagePath

		BinaryDirName ResourceDirName SourceDirName BitmapDirName

		PackageDirName FileInDirName ChangeFileName ImageStartTime

		ImageRestartTime DemoMode SaveEmergencyImage SpecialObjectArray

		CallbackSignal ClassesFailedToInitialize HasNoConsole IgnoreHalt

		PackageToPathMapping IgnoreAssertions LanguageModifier

		LanguageCodeset'

	poolDictionaries:''

	category:'System-Support'

!

Smalltalk comment:''

!

!Smalltalk class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1988 by Claus Gittinger

 COPYRIGHT (c) 2009-2011 Jan Vrany

 COPYRIGHT (c) 2015-2018 Jan Vrany

 COPYRIGHT (c) 2020 LabWare

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This is one of the central classes in the system;

    it provides all system-startup, shutdown and maintenance support.

    Also global variables are (conceptionally) kept here.

    As you will notice, this is NOT a Dictionary

    - my implementation of globals is totally different

      due to the need to be able to access globals from c-code as well,

      I do not use associations for globals, but instead keep the

      name<->value relations in the VM and access globals via utility

      functions found there.

    However, it provides the known enumeration protocol.

    It may change to become a subclass of collection at some time,

    to inherit more collection stuff ...

    [Instance variables:]

					none - all handling is done in the VM

    [Class variables:]

	StartBlocks     <Collection>    blocks to be executed in a separate process after

					everything has been initialized. These blocks will

					be deleted after execution and therefore not be

					executed after an image restart. Initial processes

					(such as the Launcher) are usually started here.

					These blocks are added by smalltalk.rc/private.rc etc.

					via #addStartBlock during early initialization.

	ImageStartBlocks

			<Collection>    blocks to be executed in a separate process after

					everything has been initialized. These blocks will be

					executed after an image restart.

					These blocks are usually added by smalltalk_r.rc etc.

	ExitBlocks      <Collection>    blocks to evaluate before system is

					left. Not currently used (GNU-ST compatibility).

	SystemPath      <Collection>    path to search for system files (sources, bitmaps etc)

					Set to a default here, but typically changed from some

					startup.rc file

	PackagePath     <Collection>    path to search for package.

					This is going to replace the above systemPath, and a classes

					resources will eventually searched in its package directory.

					This list defines the path, where packages are searched for,

					initially this is something like /opt/smalltalk/packages.

					Set to a default here, but typically changed from some

					startup.rc file

	StartupClass    <Class>         class and selector, where the system starts up

	StartupSelector <Symbol>        (right after VM initialization)

	StartupArguments <Array>        If an image is saved while those being nonNil,

					the image will come up there.

					Allows for customized images to be generated from a standard ST/X.

					StandAlone programs also set those during initialization.

	CommandLine          <String>   Unix (OS-) command line

	CommandName          <String>   the command (i.e. argv[0])

	CommandLineArguments <Array>    Unix (OS-) command line arguments broken into words

					CommandName has been stripped off.

					(initially set by the VM)

	SilentLoading   <Boolean>       OBSOLETE:

					suppresses messages during fileIn and in compiler

					(can be set to true from a customized main.c)

	VerboseLoading   <Boolean>      generate messages during fileIn and in compiler

					(can be set to true from a customized main.c)

	Initializing    <Boolean>       true while (re-)initializing

					Controls the behavior of certain error

					reporters (for example: suppress dialogBoxes)

					while the system is not yet fit for full operation.

	StandAlone      <Boolean>       true, if this is a standalone app;

					if true the process scheduler watches for

					which processes are still running, and

					exits ST/X, when the last non-background

					and non-system process exits.

					Can be set in an application-specific startup script,

					or, for standAlone programs, by C-code during initialization.

	HeadlessOperation               if true, a non-existing Display connection

			<Boolean>       will NOT lead to an error-exit during startup.

					Default is false.

					Can be set in an application-specific startup script,

					or, for standAlone programs, by C-code during initialization.

	LogDoits        <Boolean>       if true, doits are also logged in the changes

					file. Default is false, since the changes file

					may become huge if every tiny doIt is saved there ...

	LoadBinaries    <Boolean>       if true, we attempt to load classes rom a binary

					file, if present. If false, this is always suppressed.

	SaveEmergencyImage <Boolean>    if true (the default), an emergency image

					is saved, if the main Display looses its

					connection. This is useful if you have a

					flaky display connection (serial line)

					and want to have your stuff saved automatically

					in case of a broken connection.

	IgnoreAssertions  <Boolean>     if true, assertions are ignored (i.e. no errors reported).

					Usually false in the development system, true in a standalone deployed app.

    strictly private classVariables (helpers):

	CachedClasses   <Collection>    known classes (cached for faster class enumeration)

	CachedAbbreviations

			<Dictionary>    className to filename mappings

	RealSystemPath  <Collection>    cached collection of directories along the path

					which really exist. Caching avoids long checks

					for existing directories on broken NFS volumes.

	SourcePath      <Collection>    cached names of really existing directories

					These are remembered, as in NFS systems,

	ResourcePath                    the time to lookup files may become long

	BinaryPath                      (especially, if some directories are on machines

	FileInPath                      which are not up ...).

					Therefore, the set of really

					existing directories is cached when the SystemPath

					is walked the first time.

					A consequence is that you have to invoke

					flushSystemPath, when you create any of those

					directories while running

					(and want the running ST/X to look there)

    [author:]

	Claus Gittinger

    [see also:]

	ObjectMemory

	StandaloneStartup

	GetOpt

	ReadEvalPrintLoop

"

!

readme_resources

"

    What is a resource file:

	resource files contain language transformation and sometimes

	UI-look specifics such as icons etc.

    Where are resources stored in the image:

	Resource files are only read on demand (i.e. when needed) and only read once

	i.e. they are cached in the image).

	The cached data is held in a per-class class-instVar named 'ClassResources'.

	With only a few exceptions, the only classes which need resources are the GUI

	classes under the SimpleView hierarchy.

    How does the system find resources:

	The idea is that the system-provided resource files can be overwritten

	by the user or an application configuration.

	This works via a hierarchy of directories where resources are searched for,

	with the systems standard resource-files being at the end of that chain.

	When searching for a resource file for class X, the following files are searched

	in order:

		{ResourcePath} / resources / X.rs

		{SystemPath} / (CLASSES-PACKAGE-PATH) / X.rs

		{ResourcePath} / (CLASSES-PACKAGE-PATH) / X.rs

"

! !

!Smalltalk class methodsFor:'initialization'!

basicInitializeSystem

    "initialize all other classes.

     This one is the very first entry into the smalltalk world

     [with error handling, via the initializeSystem],

     right after startup, usually immediately followed by Smalltalk>>start.

     Notice:

        this is NOT called when an image is restarted; in this

        case the show starts in Smalltalk>>restart."

    OrderedCollection initialize.

    Smalltalk at:#Compiler put:ByteCodeCompiler.

    Compiler isNil ifTrue:[

        "

         ByteCodeCompiler is not in the system (i.e. has not been linked in)

         this allows at least immediate evaluations for runtime systems without compiler

         NOTICE: a parser is always needed, otherwise we cannot read resource files etc.

        "

        Smalltalk at:#Compiler put:Parser

    ].

    "/

    "/ start catching SIGSEGV and SIGBUS

    "/

    OperatingSystem enableHardSignalInterrupts.

    self initGlobalsFromEnvironment.

    "/

    "/ sorry - there are some, which MUST be initialized before ..

    "/ reason: if any error happens during init, we need Signals, Stdout etc. to be there

    "/

    SmallInteger initialize.

    Object initialize.

    UninterpretedBytes initialize.

    OperatingSystem initialize.

    Stream initialize.

    PositionableStream initialize.

    Filename initialize.

    ObjectMemory initialize.

    ExternalStream initialize.

    ProcessorScheduler initialize.

    self initStandardStreams.    "/ setup Stdin, Stdout etc.

    "/

    "/ sorry, path must be set before ...

    "/ reason: some classes need it during initialize (they might need resources, bitmaps etc)

    "/

    "/ but, on OSX we need the CharacterEncoder to be initialized

    CharacterEncoder initialize.

    self initSystemPath.

    self initPackagePath.

    "/

    "/ in case, someone needs the objectFileLoader early

    "/

    ObjectFileLoader notNil ifTrue:[

        ObjectFileLoader initialize.

    ].

    "/

    "/ now, finally, initialize all other classes

    "/

    self initializeModules.

    ImageStartTime := Timestamp now.

    self initInterrupts.

    self initUserPreferences.

    "/ just to make sure: if any prefs affect any resources,

    "/ flush them here, so they are reread in any case.

    "/ required for some apps, for example to show the menu correctly (see launcher's help menu)

    ApplicationModel notNil ifTrue:[

        ApplicationModel flushAllClassResources.

    ].

    "/

    "/ give classes a chance to perform 2nd-level initialization

    "/ now, we are certain, that all other classes have been initialized

    "/ (especially: streams and signals can now be used)

    "/

    ObjectMemory changed:#initialized.

    "Modified: / 08-01-1997 / 19:58:12 / stefan"

    "Modified: / 05-12-2006 / 21:48:58 / cg"

    "Modified: / 24-10-2012 / 18:45:15 / sr"

    "Modified: / 25-06-2016 / 16:35:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

initGlobalsFromEnvironment

    "setup globals from the shell-environment"

    StandAlone isNil ifTrue:[

        StandAlone := false.

    ].

    HeadlessOperation isNil ifTrue:[

        HeadlessOperation := false.

    ].

    "

     Smalltalk initGlobalsFromEnvironment

    "

    "Modified: / 14-02-2012 / 15:25:08 / cg"

    "Modified: / 21-11-2017 / 21:29:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

initInterrupts

    "initialize interrupts"

    OperatingSystem enableUserInterrupts.

    OperatingSystem enableHardSignalInterrupts.

    OperatingSystem enableCrashSignalInterrupts.

    ObjectMemory userInterruptHandler:self.

    ObjectMemory signalInterruptHandler:self.

    ObjectMemory recursionInterruptHandler:self.

    OperatingSystem isOSXlike ifTrue:[

	"/ OSX sends SIGABRT for NSExceptions

	OperatingSystem operatingSystemSignal:(OperatingSystem sigABRT) install:NSException.

	OperatingSystem enableAbortInterrupts.

    ].

    "

     Smalltalk initInterrupts

    "

    "Modified: 20.8.1997 / 09:35:49 / stefan"

!

initPackagePath

    "Initialize package path"

    PackagePath := OperatingSystem defaultPackagePath.

    self addWorkspaceDirectoryToPackagePath.

    "Created: / 25-06-2016 / 16:35:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

initStandardStreams

    "initialize some well-known streams"

    Stdout := NonPositionableExternalStream forStdout.

    Stderr := NonPositionableExternalStream forStderr.

    Stdin := NonPositionableExternalStream forStdin.

    PrinterStream notNil ifTrue:[

	Printer := PrinterStream defaultPrinter.

    ].

    Transcript := Stderr

    "

     Smalltalk initStandardStreams

    "

    "Modified: / 25-10-2006 / 17:36:46 / cg"

!

initStandardTools

    "predefine some tools which we might need later

     - if the view-classes exist,

       they will redefine Inspector and Debugger for graphical interfaces"

    Display notNil ifTrue:[

	InspectorView notNil ifTrue:[

	    Inspector := InspectorView

	].

	DebugView notNil ifTrue:[

	    Debugger := DebugView

	].

	"/ Display initialize

    ].

    "/ make the changeFilePath an absolute one,

    "/ in case some stupid windows fileDialog changes the current directory...

    ObjectMemory

	nameForChanges:(Filename currentDirectory / ObjectMemory nameForChangesLocal)

			    asAbsoluteFilename pathName

    "

     Smalltalk initStandardTools

    "

    "Modified: / 09-02-2011 / 20:44:47 / cg"

!

initSystemPath

    "setup path where system files are searched for.

     the default path is set to:

            .

            <directory of exe>       (WIN32 only)

            $HOME                    (if defined)

            $HOME/.smalltalk         (if defined & existing)

            $SMALLTALK_LIBDIR        (if defined & existing)

            $STX_LIBDIR              (if defined & existing)

            $STX_TOPDIR              (if defined & existing)

            REGISTRY('HKEY_LOCAL_MACHINE\Software\eXept\Smalltalk/X\<CurrentVersion>\LibDir') (WIN32 only)

            REGISTRY('HKEY_LOCAL_MACHINE\Software\eXept\Smalltalk/X\LibDir')                  (WIN32 only)

            <standard places>

     standard places (unix):

            /opt/smalltalk/<release> (if existing)

            /opt/smalltalk           (if existing)

            /usr/local/lib/smalltalk (if existing)

            /usr/lib/smalltalk       (if existing)

            /lib/smalltalk           (if existing)

     win32:

            \programs\exept\smalltalk (if existing)

            \programs\smalltalk       (if existing)

            \smalltalk                (if existing)

     vms:

            $stx:lib                 (if existing)

            $stx:root                (if existing)

     of course, it is possible to add entries from the 'smalltalk.rc'

     startup file; add expressions such as:

            Smalltalk systemPath addFirst:'/foo/bar/baz'.

        or:

            Smalltalk systemPath addLast:'/fee/foe/foo'.

     However, smalltalk.rc itself must be found along the above path.

    "

    ChangeFileName := 'changes'.

    OperatingSystem isVMSlike ifTrue:[

        BitmapDirName := 'bitmaps.dir'.

        BinaryDirName := 'binary.dir'.

        SourceDirName := 'source.dir'.

        ResourceDirName := 'resources.dir'.

        FileInDirName := 'filein.dir'.

        PackageDirName := 'packages.dir'.

    ] ifFalse:[

        BitmapDirName := 'bitmaps'.

        BinaryDirName := 'binary'.

        SourceDirName := 'source'.

        ResourceDirName := 'resources'.

        FileInDirName := 'fileIn'.

        PackageDirName := 'packages'.

    ].

    SystemPath isEmptyOrNil ifTrue:[

        SystemPath := OperatingSystem defaultSystemPath.

        self flushPathCaches

    ].

    PackagePath isEmptyOrNil ifTrue:[

        PackagePath := OperatingSystem defaultPackagePath.