Object subclass:#Java

	instanceVariableNames:''

	classVariableNames:'Classes UnresolvedClassRefs ClassPath SourceDirectories JavaHome

		Java_lang_String Java_lang_Class PrettyPrintStyle

		LastArgumentString Threads ExcludedClassPath'

	poolDictionaries:''

	category:'Java-Support'

!

!Java class methodsFor:'accessing'!

classForName:aString

    "return a javaClass - either existing or loaded"

    |cls loader classURL|

    cls := self at:aString.

    cls isNil ifTrue:[

	('JAVA [info]: late class loading: ' , aString) infoPrintCR.

	loader := JavaClassReader classLoaderQuerySignal raise.

	loader isNil ifTrue:[

	    "/ load using default (ST/X) loader

	    cls := JavaClassReader loadClass:aString.

	] ifFalse:[

	    "/ load using a Java class loader

"/            classURL := Java as_URL:('file:' , aString , '.class').

"/            loader loadClass:classURL.

	    loader perform:#'loadClass(Ljava/lang/String;)Ljava/lang/Class;'

		with:(Java as_String:aString).

	    cls := self at:aString.

	]

    ].

    ^ cls

    "Created: / 18.3.1997 / 16:45:57 / cg"

    "Modified: / 9.1.1998 / 03:43:16 / cg"

!

classNamed:aString

    ^ self at:aString

!

java_lang_Class

    Java_lang_Class isNil ifTrue:[

	Java_lang_Class := self at:'java.lang.Class'

    ].

    ^ Java_lang_Class

    "Created: 26.3.1997 / 13:42:59 / cg"

    "Modified: 26.3.1997 / 13:46:24 / cg"

!

java_lang_String

    Java_lang_String isNil ifTrue:[

	Java_lang_String := self at:'java.lang.String'

    ].

    ^ Java_lang_String

    "Created: 26.3.1997 / 13:43:17 / cg"

    "Modified: 26.3.1997 / 13:50:21 / cg"

!

prettyPrintStyle

    ^ PrettyPrintStyle

    "Created: 1.8.1997 / 10:37:57 / cg"

!

threads

    Threads isNil ifTrue:[

	Threads := WeakIdentityDictionary new.

    ].

    ^ Threads

    "Created: 26.8.1997 / 19:53:57 / cg"

    "Modified: 26.8.1997 / 19:55:27 / cg"

! !

!Java class methodsFor:'accessing paths'!

addToClassPath:aPath

    (ClassPath includes:aPath) ifFalse:[

	ClassPath add:aPath

    ]

    "Modified: 7.2.1997 / 19:23:55 / cg"

    "Created: 1.8.1997 / 21:10:07 / cg"

!

addToSourcePath:aPath

    (SourceDirectories includes:aPath) ifFalse:[

	SourceDirectories add:aPath

    ]

    "Modified: 7.2.1997 / 19:23:55 / cg"

    "Created: 2.8.1997 / 14:12:31 / cg"

!

classPath

    ^ ClassPath

    "Created: 7.2.1997 / 19:23:45 / cg"

    "Modified: 7.2.1997 / 19:23:55 / cg"

!

classPath:aCollectionOfPaths

    ClassPath := aCollectionOfPaths asOrderedCollection

    "Created: 7.2.1997 / 19:23:45 / cg"

!

excludedClassPath

    ^ ExcludedClassPath

    "Modified: / 7.2.1997 / 19:23:55 / cg"

    "Created: / 27.1.1998 / 21:57:13 / cg"

!

isExcludedFromClassPath:fileName

    |nm|

    nm := fileName asFilename pathName.

    ExcludedClassPath do:[:excludedPath |

        (nm startsWith:excludedPath) ifTrue:[^ true].

    ].

    ^ false

    "Created: / 27.1.1998 / 22:00:40 / cg"

!

javaHome

    ^ JavaHome

    "Created: 6.8.1997 / 00:53:19 / cg"

!

javaHome:aPath

    JavaHome := aPath

    "Created: 6.8.1997 / 00:53:23 / cg"

!

removeFromClassPath:aPath

    (ClassPath includes:aPath) ifTrue:[

	ClassPath remove:aPath

    ]

    "Modified: 7.2.1997 / 19:23:55 / cg"

    "Created: 1.8.1997 / 21:10:21 / cg"

!

removeFromSourcePath:aPath

    (SourceDirectories includes:aPath) ifTrue:[

	SourceDirectories remove:aPath

    ]

    "Modified: 7.2.1997 / 19:23:55 / cg"

    "Created: 2.8.1997 / 14:13:01 / cg"

!

sourceDirectories

    ^ SourceDirectories

!

sourceDirectories:aCollectionOfPaths

    SourceDirectories := aCollectionOfPaths asOrderedCollection

    "

     Java

	sourceDirectories:#(

			    '/phys/ibm3/java/src'

			   )

    "

!

sourcePath

    ^ SourceDirectories

    "Created: / 16.1.1998 / 13:26:55 / cg"

! !

!Java class methodsFor:'class initialization'!

initAllClasses

     |system|

     self initAllStaticFields.

     system := self classForName:'java.lang.System'.

     system isInitialized ifFalse:[

	 system classInit.

	 self initSystemClass.

     ].

     self allClassesDo:[:cls |

	cls isInitialized ifFalse:[

	    cls classInit

	]

     ]

    "Modified: / 4.1.1998 / 14:41:12 / cg"

!

initAllStaticFields

     self allClassesDo:[:cls |

	cls initializeStaticFields

     ]

!

initSystemClass

    |system|

    system := Java at:'java.lang.System'.

    system isNil ifTrue:[

        JavaVM initializeVM.

        system := Java at:'java.lang.System'.

        system isNil ifTrue:[

            self error:'no ''java.lang.System'' class'.

            ^ self

        ].

    ].

    (system implements:#'initializeSystemClass()V') ifTrue:[

        system invokeStatic:#'initializeSystemClass()V'.

    ].

    "

     Java initSystemClass

     (Java at:'java.lang.System') 

        perform:#'getProperty(Ljava/lang/String;)Ljava/lang/String;'

        with:(Java as_String:'java.home')

    "

    "Modified: / 15.1.1998 / 00:29:37 / cg"

!

initialize

    |tryJDK1_2 jHome mozillaHome|

    "/ cannot use JDK1.2 yet (they made so many changes ...)

    tryJDK1_2 := false.

    ExcludedClassPath := OrderedCollection new.

    tryJDK1_2 ifTrue:[        

        jHome := '/phys/idefix/home2/java/jdk1.2beta2'.

    ].

    (jHome isNil or:[jHome asFilename exists not]) ifTrue:[

        jHome := '/usr/local/java/jdk113'.

        jHome asFilename exists ifFalse:[

            jHome := '/usr/lib/java'.

        ].

    ].

    self javaHome:jHome.

    self classPath:(Array with:jHome , '/lib/classes').

    self sourceDirectories:(Array with:jHome , '/src').

    mozillaHome := '/usr/local/java/moz3_0/lib_unix'.

    mozillaHome asFilename exists ifTrue:[

        Java addToClassPath:(mozillaHome , '/classes').

        "/

        "/ care to only load mozilla classes from there ...

        "/

        ExcludedClassPath add:(mozillaHome , '/classes/java/').

        ExcludedClassPath add:(mozillaHome , '/classes/sun/').

    ].

    self initializePrettyPrintStyle.

    "

     Java initialize

     JavaVM initializeVM

    "

    "Modified: / 28.1.1998 / 22:05:35 / cg"

!

initializePrettyPrintStyle

    PrettyPrintStyle := IdentityDictionary new.

    PrettyPrintStyle  at:#accessAttribute put:(#color -> (Color red:0 green:0 blue:25)).

    PrettyPrintStyle  at:#className       put:(Array with:(#color -> Color black) with:#bold).

    PrettyPrintStyle  at:#methodName      put:(Array with:(#color -> Color black) with:#bold).

    PrettyPrintStyle  at:#code            put:(#color -> Color black).

     "

      Java initializePrettyPrintStyle

     "

    "Created: 1.8.1997 / 11:08:43 / cg"

    "Modified: 1.8.1997 / 11:09:58 / cg"

!

reinitAllClasses

     self markAllClassesUninitialized.

     self initAllClasses

     "

      Java reinitAllClasses

     "

    "Modified: / 4.1.1998 / 00:34:29 / cg"

!

reinitialize

    "/ all JavaThreads are lost on a restart (for now)

    Threads := nil.

    "

     Java reinitialize

    "

    "Created: / 26.8.1997 / 20:07:00 / cg"

    "Modified: / 28.1.1998 / 23:13:07 / cg"

!

startupJavaSystem

    |haveEventThread haveScreenUpdater|

    "/

    "/ check if already running

    "/

    haveEventThread := true.

    (JavaEventThread isNil or:[JavaEventThread isDead]) ifTrue:[

        haveEventThread := false

    ].

    haveScreenUpdater := false.

    haveEventThread ifTrue:[

        self threads do:[:aJavaThread |

            aJavaThread name = 'JAVA-Screen Updater' ifTrue:[

                aJavaThread isDead ifFalse:[

                    "/ already running

                    haveScreenUpdater := true

                ]

            ]

        ].

    ].

    (haveEventThread and:[haveScreenUpdater]) ifTrue:[

        ^ self

    ].

    'JAVA [info]: (re)initializing JAVA environment completely ...' infoPrintCR.

    JavaVM initializeVM.

    'JAVA [info]: done JAVA initialization.' infoPrintCR.

    "

     Java startupJavaSystem

    "

    "Modified: / 1.2.1998 / 18:02:00 / cg"

!

terminateAllThreads

    |myself threadsToKill|

    Threads isNil ifTrue:[

        ^ self

    ].

    myself := Processor activeProcess.

    threadsToKill := IdentitySet new.

    Threads do:[:aJavaThread |

        aJavaThread ~~ myself ifTrue:[

            (aJavaThread isNil or:[aJavaThread == 0]) ifFalse:[

                (aJavaThread isMemberOf:JavaProcess) ifTrue:[

                    aJavaThread isDead ifFalse:[

                        threadsToKill add:aJavaThread

                    ]

                ]

            ]

        ]

    ].

    threadsToKill do:[:aThread |

        aThread terminate

    ].

    Threads := nil.

    "

     Java terminateAllThreads

    "

    "Created: / 26.8.1997 / 19:57:40 / cg"

    "Modified: / 1.2.1998 / 20:11:56 / cg"

! !

!Java class methodsFor:'enumerating'!

allClasses

    ^ Classes ? #()

    "

    |if|

    if := Java at:'java.awt.GraphicsEnvironment'.

    Java allClasses select:[:aClass |

                                aClass hasInterface:if

                            ]

    "

    "Modified: / 28.1.1998 / 01:42:04 / cg"

!

allClassesDo:aBlock

    Classes notNil ifTrue:[

	Classes do:aBlock

    ]

! !

!Java class methodsFor:'object conversions'!

as_Float:aNumber

    "convert an ST-float into a Java Float"

    |i|

    i := (Java at:'java.lang.Float') new.

    i perform:#'<init>(F)V' with:(aNumber asShortFloat).

    ^ i

    "

     Java as_Float:1

     Java as_Float:3.14159

    "

    "Created: 7.8.1997 / 21:21:13 / cg"

    "Modified: 7.8.1997 / 21:22:05 / cg"

!

as_Hashtable:aDictionary

    "given a smalltalk dictionary, create and return

     a Java hashTable for it"

    |hashTable|

    hashTable := (self classForName:'java.util.Hashtable') new.

    aDictionary keysAndValuesDo:[:k :v |

	|sk sv jk jv|

	(sk := k) isSymbol ifTrue:[

	    sk := sk asString

	].

	(sv := v) isSymbol ifTrue:[

	    sv := sv asString

	].

	jk := self as_Object:sk.

	jv := self as_Object:sv.

	hashTable 

	    perform:#'put(Ljava/lang/Object;Ljava/lang/Object;)Ljava/lang/Object;'    

	    with:jk

	    with:jv.

    ].

    ^ hashTable

    "

     Java as_Hashtable:(Dictionary new

			   at:'hello' put:'Hallo';

			   at:'world' put:'Welt';       

			   yourself)

    "

    "Modified: / 14.1.1998 / 17:02:13 / cg"

!

as_Integer:anInteger

    "convert an ST-integer into a Java Integer"

    |i|

    i := (Java at:'java.lang.Integer') new.

    i perform:#'<init>(I)V' with:anInteger.

    ^ i