"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

AbstractFileBrowser subclass:#FileApplicationNoteBook

	instanceVariableNames:'canvasHolder selectedEditorPage listOfApplications tabMenuIndex

		tabList selectionHistoryList privateTabList'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-Tools-File'

!

AbstractFileApplicationNoteBookComponent subclass:#ArchiveViewApplication

	instanceVariableNames:'archiveFileList enableStopButton fileTable currentSortOrder

		selectionHolder tableColumns commandProcess errorListHolder

		viewErrorList temporaryDirectory enableRemoveErrorOutput

		errorListVisibilityHolder hasListEntriesHolder archiver process

		terminateByMe columnDescriptors inDropMode'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

Object subclass:#ArchivItem

	instanceVariableNames:'fileName size dateAndTime permissions icon ownerGroup method crc

		compressSize ratio version type isDirectory'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook::ArchiveViewApplication

!

AbstractFileApplicationNoteBookComponent subclass:#CommandResult

	instanceVariableNames:'resultStream enableStopButton process labelHolder'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#HtmlViewApplication

	instanceVariableNames:'htmlView labelHolder infoLabelHolder'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#ImageViewApplication

	instanceVariableNames:'imageFile imageView image fitSize fitMode'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#Terminal

	instanceVariableNames:'terminalView'

	classVariableNames:'DefaultLineLimit'

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#TextEditor

	instanceVariableNames:'fileContentsModel modifiedChannel editView enableSave

		enableReload presentation changeItemProcess closeApplication

		semaChangeItem wantToPrintAsHexDump printAsHexDump itemChanged

		itemRemoved enableHexToggle md5CheckSum

		md5HashValueComputationProcess viewModifiedChannel

		textEditorModificationTime checkModifiedBlock'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#XViewApplication

	instanceVariableNames:'xView xFile vncServerPID vncPortNr vncConnection viewerPID

		vncLock vncServerIsTerminated xItem ext'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

!FileApplicationNoteBook class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

! !

!FileApplicationNoteBook class methodsFor:'application list'!

applicationList

" returns a list of all applications to start by the NoteBookApplication with 

                #className                         #type                    

            example:

            #(  #'FooEditor'                       nil                      )

"

    ^ #(

            #(  #'TextEditor'                      #file                    )

            #(  #'TextEditor'                      #directoryDescription    )

            #(  #'HtmlViewApplication'             nil                      )

            #(  #'FindFileApplication'             nil                      )

            #(  #'Terminal'                        nil                      )

            #(  #'ImageViewApplication'            nil                      )

            #(  #'ArchiveViewApplication'          nil                      )

            #(  #'CommandResult'                   nil                      )

            #(  #'XViewApplication'                nil                      )

       )

!

classFor:aApplicationListItem

    |rawName cls|

    rawName := aApplicationListItem at:1.

    (cls := self privateClassesAt:rawName) isNil ifTrue:[

        cls := Smalltalk at:rawName.

    ].

    ^ cls

!

defaultApplication

" returns the application to be started if no itemQuery returns true or no supportedSuffix is supported

"

    ^ self applicationList detect:[: applItem|

        (((self classFor:applItem) == self textEditorClass)

        and:[(self typeFor:applItem) == #file])

    ] ifNone:[nil].

!

typeFor:aApplicationListItem

    ^ aApplicationListItem at:2

! !

!FileApplicationNoteBook class methodsFor:'classAccess'!

textEditorClass

    ^ TextEditor

! !

!FileApplicationNoteBook class methodsFor:'defaults'!

openAnotherApplicationOnSameItem

    ^ false

! !

!FileApplicationNoteBook class methodsFor:'interface specs'!

windowSpec

    "This resource specification was automatically generated

     by the UIPainter of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the UIPainter may not be able to read the specification."

    "

     UIPainter new openOnClass:NoteBookApplication andSelector:#windowSpec

     NoteBookApplication new openInterface:#windowSpec

     NoteBookApplication open

    "

    <resource: #canvas>

    ^ 

     #(#FullSpec

        #name: #windowSpec

        #window: 

       #(#WindowSpec

          #label: 'FileBrowserV2TextEditor'

          #name: 'FileBrowserV2TextEditor'

          #min: #(#Point 10 10)

          #max: #(#Point 1024 768)

          #bounds: #(#Rectangle 16 42 316 342)

        )

        #component: 

       #(#SpecCollection

          #collection: #(

           #(#NoteBookViewSpec

              #name: 'CommandAndTextEditor'

              #layout: #(#LayoutFrame 0 0.0 0 0.0 0 1.0 0 1.0)

              #model: #selectedEditorPage

              #menu: #tabList

              #useIndex: true

              #accessTabMenuAction: #tabMenuAt:

              #canvas: #canvasHolder

              #keepCanvasAlive: true

            )

           )

        )

      )

! !

!FileApplicationNoteBook class methodsFor:'menu specs'!

tabMenu

    "This resource specification was automatically generated

     by the MenuEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the MenuEditor may not be able to read the specification."

    "

     MenuEditor new openOnClass:FileApplicationNoteBook andSelector:#tabMenu

     (Menu new fromLiteralArrayEncoding:(FileApplicationNoteBook tabMenu)) startUp

    "

    <resource: #menu>

    ^ 

     #(#Menu

        #(

         #(#MenuItem

            #label: 'Add Text Editor'

            #itemValue: #newTextEditor

            #translateLabel: true

          )

         #(#MenuItem

            #label: '-'

          )

         #(#MenuItem

            #label: 'Select in Filelist'

            #itemValue: #doSelectInList

            #translateLabel: true

          )

         #(#MenuItem

            #label: '-'

          )

         #(#MenuItem

            #label: 'Rename Tab'

            #itemValue: #doRenameTab

            #translateLabel: true

          )

         #(#MenuItem

            #label: '-'

          )

         #(#MenuItem

            #label: 'Close'

            #itemValue: #doCloseApplication

            #translateLabel: true

          )

         #(#MenuItem

            #label: 'Close All...'

            #itemValue: #doCloseAllApplications

            #translateLabel: true

            #enabled: #closeAllApplicationsEnabled

          )

         )

        nil

        nil

      )

! !

!FileApplicationNoteBook methodsFor:'accessing'!

listOfApplications

    "return the value of the instance variable 'listOfApplications' (automatically generated)"

    listOfApplications isNil ifTrue:[

        listOfApplications := OrderedCollection new.

    ].

    ^ listOfApplications

!

selectionHistoryList

    selectionHistoryList isNil ifTrue:[

        selectionHistoryList := OrderedCollection new.

    ].

    ^ selectionHistoryList

!

selectionHistoryList:aCol

    selectionHistoryList := aCol 

! !

!FileApplicationNoteBook methodsFor:'accessing-applications'!

getAllApplicationsByClass:aClass andType:aType

    ^ self listOfApplications select:[ : appl  |

        ((appl class = aClass)

        and:[true"appl type = aType"])

    ].

!

getApplicationByType:aType

    ^ self listOfApplications detect:[ : appl  | 

        (appl type == aType)

    ] ifNone:[nil].

!

getIndexFor:aApplication

    | index |

    index := self listOfApplications indexOf:aApplication.

    index ~~ 0 ifTrue:[

        ^ index.

    ].

    ^ nil.

!

getSameApplicationsFor:aApplication

    ^ self listOfApplications select:[ : appl |

        ( (appl ~= aApplication)    

        and:[ (appl isKindOf:(aApplication class)) 

        and:[ (appl item = (aApplication item)) 

        and:[ (appl type == aApplication type) ]]])

    ].

! !

!FileApplicationNoteBook methodsFor:'actions-app-common'!

changeItem:anItem for:aAppl

    | applIndex string isDirectory |

    applIndex := self getIndexFor:aAppl.

    anItem notNil ifTrue:[

        isDirectory := anItem isDirectory or:[anItem linkTargetIsDirectory ].

        (isDirectory not) ifTrue:[

            (aAppl changeItem:anItem) ifFalse:[ ^ self].

            self fileHistory add:anItem.

            self enableFileHistory value:true.

        ].

    ].

    string := aAppl getTabString.

    self privateTabList at:applIndex put:(Text fromString:string).

    self doSelect:aAppl.

!

changeModified:aSymbol for:aAppl

    | index text stream|

    index := self getIndexFor:aAppl.

    index isNil ifTrue:[ ^ self].

    stream := WriteStream with:aAppl getTabString.

    aSymbol ~~ #unchanged ifTrue:[

        stream space.

        stream nextPut:$[.

        stream nextPutAll:aSymbol asString.

        stream nextPut:$].

        text := stream contents asText.

        text emphasizeAllWith:UserPreferences current emphasisForModifiedBuffer.

    ] ifFalse:[

        text := stream contents asText.

    ].

    self privateTabList at:index put:text.

    self selectedEditorPage value == index ifTrue:[

        self changeFileBrowserTitleTo:text.

    ].

!

closeSubCanvas:aApplication

    | applIndex historyList localHistoryList selectedPage|

    applIndex := self getIndexFor:aApplication.

    applIndex notNil ifTrue:[

"/        "/ UPDATE THE LAST SELECTION BECAUSE SEL INDEX IS DECREMENTED FOR HIGHER INDEXES

"/        self lastSelection:applIndex.

        historyList := self selectionHistoryList.

        historyList remove:applIndex ifAbsent:nil.

        localHistoryList := OrderedCollection new.

        historyList notEmpty ifTrue:[

            selectedPage := historyList last.

        ] ifFalse:[

            selectedPage := 1.

        ].  

        self selectedEditorPage value:selectedPage.

        historyList do:[ : index |

            index <= applIndex ifTrue:[

                localHistoryList add:index

            ] ifFalse:[

                localHistoryList add:(index - 1)

            ]

        ].

        self selectionHistoryList:localHistoryList.

        self listOfApplications removeIndex:applIndex.

        self privateTabList removeIndex:applIndex.

        self privateTabList isEmpty ifTrue:[

            self viewNoteBookApplicationHolder value:false.

            self enableViewNoteBookApplication value:false.

            self changeFileBrowserTitleTo:'FileBrowser V2'.

        ] ifFalse:[

            historyList notEmpty ifTrue:[

                self selectedEditorPage value:(self selectionHistoryList last).

            ]

        ]

    ].

    "/ because subCanvas was configured to keep its view,

    "/ we must destroy it here.

    aApplication window destroy.

!

doCloseAllApplications

    | appl |

    (Dialog confirm:(resources string:'Really close all Tabs ?')) ifFalse:[^ self].

    appl := self listOfApplications copy do:[:eachApp | eachApp doClose.].

!

doCloseApplication

    | appl |

    appl := self listOfApplications at:tabMenuIndex.

    appl doClose.

!

doRenameTab

    | newLabel |

    newLabel := Dialog request:'New Tab Label:' initialAnswer:(self privateTabList at:tabMenuIndex).

    newLabel size == 0 ifTrue:[^ self ].

    self privateTabList at:tabMenuIndex put:newLabel

!

doSelectInList

    | appl fileName|

    appl := self listOfApplications at:tabMenuIndex.

    fileName := appl fileName.

    fileName notNil ifTrue:[

        self gotoFile:fileName.

    ].

!

openApplByFileItem:anItem

" use the default class list for open of applications by item "

    | applList applItem itemClass itemType appl|

    anItem isNil ifTrue:[ ^ self ].

    anItem isDirectory ifTrue:[

        self warn:'No Application to open for directory:', anItem fileName asString, ' found'.

        ^ nil.

    ].

    applList := self applicationList.

    self openAlwaysInTextEditor value ifTrue:[

        ^ self openDefaultApplicationByItem:anItem.

    ].

    applItem := applList 

                    detect:[: aApplItem|

                        itemClass := self class classFor:aApplItem.

                        (itemClass canOpenItem:anItem).

                    ] ifNone:[nil].

    applItem isNil ifTrue:[ 

        ^ self openDefaultApplicationByItem:anItem

    ].

    itemType := self class typeFor:applItem.

    itemClass := self class classFor:applItem.

    appl := self openApplicationClass:itemClass withItem:anItem withType:itemType.

    appl notNil ifTrue:[ ^ appl].

    ^ self openDefaultApplicationByItem:anItem.            

!

openApplicationClass:aClass withItem:anItem withType:aType

    ^ self openApplicationClass:aClass withItem:anItem withType:aType checkExisting:true

!

openApplicationClass:aClass withItem:anItem withType:aType checkExisting:checkExisting

    ^ self  openApplicationClass:aClass 

            withItem:anItem 

            withType:aType 

            checkExisting:checkExisting 

            preSetItem:nil

!

openApplicationClass:aClass withItem:anItem withType:aType checkExisting:checkExisting preSetItem:aBlock

    |existingAppl newAppl|