"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

"{ NameSpace: Smalltalk }"

AbstractFileBrowser subclass:#FileApplicationNoteBook

	instanceVariableNames:'canvasHolder selectedEditorPage listOfApplications tabMenuIndex

		tabList selectionHistoryList privateTabList'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-Tools-File'

!

AbstractFileApplicationNoteBookComponent subclass:#ArchiveViewApplication

	instanceVariableNames:'archiveFileList enableStopButton fileTable currentSortOrder

		selectionHolder tableColumns commandProcess errorListHolder

		viewErrorList temporaryDirectory enableRemoveErrorOutput

		errorListVisibilityHolder hasListEntriesHolder archiver process

		terminateByMe columnDescriptors inDropMode selectionIndexHolder'

	classVariableNames:'LastSearchedInName'

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

Object subclass:#ArchivItem

	instanceVariableNames:'fileName size dateAndTime permissions icon ownerGroup method crc

		compressSize ratio version type isDirectory'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook::ArchiveViewApplication

!

AbstractFileApplicationNoteBookComponent subclass:#CommandResult

	instanceVariableNames:'resultStream enableStopButton process labelHolder'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#DigitalNotepadFileViewApplication

	instanceVariableNames:'imageView image fitSize fitMode'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#HtmlViewApplication

	instanceVariableNames:'htmlView labelHolder infoLabelHolder webBrowserPage'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#ImageViewApplication

	instanceVariableNames:'imageFile imageView image fitSize fitMode imageReadProcess'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#Terminal

	instanceVariableNames:'terminalView scrollLockedHolder'

	classVariableNames:'DefaultLineLimit'

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#TextEditor

	instanceVariableNames:'fileContentsModel modifiedChannel editView enableSave

		enableReload changeItemProcess closeApplication semaChangeItem

		wantToPrintAsHexDump printAsHexDump itemChanged itemRemoved

		enableHexToggle md5CheckSum md5HashValueComputationProcess

		viewModifiedChannel textEditorModificationTime checkModifiedBlock

		fileEncodingHolder doNotShowFontDialog lockFileEncodingHolder

		enableSelectInBrowser tagsBrowserVisibleHolder tagsBrowser

		editorToolBarVisibleHolder editorOperationsToolBarVisibleHolder

		editorOperationsMenuSpecHolder characterEncodingInDump

		radixInDump presentationHolder doMD5ModificationCheck'

	classVariableNames:'DefaultTagsBrowserVisible MaxFileSizeLoadedWithoutAsking

		DefaultEditorToolBarVisible DefaultEditorOperationsToolBarVisible'

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#XMLViewApplication

	instanceVariableNames:'xmlTreeApp labelHolder infoLabelHolder'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

AbstractFileApplicationNoteBookComponent subclass:#XViewApplication

	instanceVariableNames:'xView xFile vncServerPID vncPortNr vncConnection viewerPID

		vncLock vncServerIsTerminated xItem ext'

	classVariableNames:''

	poolDictionaries:''

	privateIn:FileApplicationNoteBook

!

!FileApplicationNoteBook class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    [Author:]

        Christian Penk

"

! !

!FileApplicationNoteBook class methodsFor:'application list'!

applicationList

    " returns a list of all applications to start by the NoteBookApplication with 

                #className                         #type                    

            example:

            #(  #'FooEditor'                       nil                      )

    "

    ^ #(

            #(  #'TextEditor'                        #file                    )

            #(  #'TextEditor'                        #directoryDescription    )

            #(  #'HtmlViewApplication'               nil                      )

            #(  #'FindFileApplication'               nil                      )

            #(  #'Terminal'                          nil                      )

            #(  #'ImageViewApplication'              nil                      )

            #(  #'ArchiveViewApplication'            nil                      )

            #(  #'CommandResult'                     nil                      )

            #(  #'XViewApplication'                  nil                      )

            #(  #'DigitalNotepadFileViewApplication' nil                      )

            #(  #'XMLViewApplication'                nil                      )

       )

    "Modified: / 21-02-2011 / 17:21:54 / cg"

!

classFor:aApplicationListItem

    |rawName cls|

    rawName := aApplicationListItem at:1.

    (cls := self privateClassesAt:rawName) isNil ifTrue:[

        cls := Smalltalk at:rawName.

    ].

    ^ cls

!

defaultApplication

" returns the application to be started if no itemQuery returns true or no supportedSuffix is supported

"

    ^ self applicationList detect:[: applItem|

        (((self classFor:applItem) == self textEditorClass)

        and:[(self typeFor:applItem) == #file])

    ] ifNone:[nil].

!

typeFor:aApplicationListItem

    ^ aApplicationListItem at:2

! !

!FileApplicationNoteBook class methodsFor:'classAccess'!

textEditorClass

    ^ TextEditor

! !

!FileApplicationNoteBook class methodsFor:'defaults'!

openAnotherApplicationOnSameItem

    ^ false

! !

!FileApplicationNoteBook class methodsFor:'interface specs'!

windowSpec

    "This resource specification was automatically generated

     by the UIPainter of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the UIPainter may not be able to read the specification."

    "

     UIPainter new openOnClass:FileApplicationNoteBook andSelector:#windowSpec

     FileApplicationNoteBook new openInterface:#windowSpec

     FileApplicationNoteBook open

    "

    <resource: #canvas>

    ^ 

    #(FullSpec

       name: windowSpec

       uuid: 'eaf34c24-2b12-11ea-b016-10ddb1cc5928'

       window: 

      (WindowSpec

         label: 'FileBrowserV2TextEditor'

         name: 'FileBrowserV2TextEditor'

         uuid: 'eaf3539a-2b12-11ea-b016-10ddb1cc5928'

         min: (Point 10 10) bounds: (Rectangle 0 0 300 300)

      ) component: 

      (SpecCollection

         collection: (

          (NoteBookViewSpec

             name: 'CommandAndTextEditor'

             layout: (LayoutFrame 0 0.0 0 0.0 0 1.0 0 1.0) uuid: 'eaf35af2-2b12-11ea-b016-10ddb1cc5928'

             model: selectedEditorPage

             menu: tabList

             useIndex: true

             accessTabMenuAction: tabMenuAt:

             translateLabel: false

             destroyTabAction: destroyTabAt:

             canvas: canvasHolder

             keepCanvasAlive: true

          )

        )

      )

    )

! !

!FileApplicationNoteBook class methodsFor:'menu specs'!

tabMenu

    "This resource specification was automatically generated

     by the MenuEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the MenuEditor may not be able to read the specification."

    "

     MenuEditor new openOnClass:FileApplicationNoteBook andSelector:#tabMenu

     (Menu new fromLiteralArrayEncoding:(FileApplicationNoteBook tabMenu)) startUp

    "

    <resource: #menu>

    ^ 

     #(Menu

        (

         (MenuItem

            label: 'Add Text Editor'

            itemValue: newTextEditor

            translateLabel: true

          )

         (MenuItem

            label: '-'

          )

         (MenuItem

            label: 'Select in Filelist'

            itemValue: doSelectInList

            translateLabel: true

          )

         (MenuItem

            label: '-'

          )

         (MenuItem

            label: 'Rename Tab...'

            itemValue: doRenameTab

            translateLabel: true

          )

         (MenuItem

            label: '-'

          )

         (MenuItem

            label: 'Close Tab'

            itemValue: doCloseApplication

            translateLabel: true

          )

         (MenuItem

            enabled: closeAllApplicationsEnabled

            label: 'Close all Tabs'

            itemValue: doCloseAllApplications

            translateLabel: true

          )

         (MenuItem

            enabled: closeAllApplicationsEnabled

            label: 'Close all but this Tab'

            itemValue: doCloseAllOtherApplications

            translateLabel: true

          )

         )

        nil

        nil

      )

    "Modified: / 27-03-2007 / 11:13:52 / cg"

! !

!FileApplicationNoteBook methodsFor:'accessing'!

listOfApplications

    "return the value of the instance variable 'listOfApplications' (automatically generated)"

    listOfApplications isNil ifTrue:[

        listOfApplications := OrderedCollection new.

    ].

    ^ listOfApplications

!

selectionHistoryList

    selectionHistoryList isNil ifTrue:[

        selectionHistoryList := OrderedCollection new.

    ].

    ^ selectionHistoryList

!

selectionHistoryList:aCol

    selectionHistoryList := aCol 

! !

!FileApplicationNoteBook methodsFor:'accessing-applications'!

getAllApplicationsByClass:aClass andType:aType

    ^ self listOfApplications 

        select:[ : appl  | 

            ((appl class = aClass)

            "and:[appl type = aType]")

        ].

    "Modified (format): / 29-11-2011 / 19:08:20 / cg"

!

getApplicationByType:aType

    ^ self listOfApplications detect:[ : appl  | 

        (appl type == aType)

    ] ifNone:[nil].

!

getIndexFor:aApplication

    | index |

    index := self listOfApplications indexOf:aApplication.

    index ~~ 0 ifTrue:[

        ^ index.

    ].

    ^ nil.

!

getSameApplicationsFor:anApplication

    ^ self listOfApplications 

        select:[:appl |

            ( (appl ~= anApplication)    

            and:[ (appl isKindOf:(anApplication class)) 

            and:[ (appl item = (anApplication item)) 

            and:[ (appl type == anApplication type) ]]])

        ].

! !

!FileApplicationNoteBook methodsFor:'actions-app-common'!

changeItem:anItem for:anAppl

    | applIndex string isDirectory iconOrNil tabItem|

    anItem notNil ifTrue:[

        isDirectory := anItem isDirectory or:[anItem linkTargetIsDirectory ].

        isDirectory ifFalse:[

            (anAppl changeItem:anItem) ifFalse:[ ^ self].

            self fileHistory addFirst:anItem.

            self enableFileHistory value:true.

        ].

    ].

    string := anAppl getTabString.

    tabItem := Text string:string.

    iconOrNil := anAppl getTabIcon.

    iconOrNil notNil ifTrue:[

        tabItem := LabelAndIcon icon:iconOrNil string:tabItem.

    ].

    applIndex := self getIndexFor:anAppl.

    self privateTabList at:applIndex put:tabItem.

    "/ self doSelect:anAppl.

!

changeModified:aSymbol for:anAppl

    |text stream|

    stream := WriteStream with:anAppl getTabString.

    aSymbol ~~ #unchanged ifTrue:[

        stream space.

        stream nextPut:$[.

        stream nextPutAll:aSymbol asString.

        stream nextPut:$].

        text := stream contents asText.

        text emphasizeAllWith:UserPreferences current emphasisForModifiedBuffer.

    ] ifFalse:[

        text := stream contents asText.

    ].

    self tabStringChangeTo:text for:anAppl.

!

closeSubCanvas:aApplication

    | applIndex historyList localHistoryList selectedPage|

    applIndex := self getIndexFor:aApplication.

    applIndex notNil ifTrue:[

"/        "/ UPDATE THE LAST SELECTION BECAUSE SEL INDEX IS DECREMENTED FOR HIGHER INDEXES

"/        self lastSelection:applIndex.

        historyList := self selectionHistoryList.

        historyList remove:applIndex ifAbsent:nil.

        localHistoryList := OrderedCollection new.

        historyList notEmpty ifTrue:[

            selectedPage := historyList last.

        ] ifFalse:[

            selectedPage := 1.

        ].  

        self selectedEditorPage value:selectedPage.

        historyList do:[ : index |

            index <= applIndex ifTrue:[

                localHistoryList add:index

            ] ifFalse:[

                localHistoryList add:(index - 1)

            ]

        ].

        self selectionHistoryList:localHistoryList.

        self listOfApplications removeIndex:applIndex.

        self privateTabList removeIndex:applIndex.

        self privateTabList isEmpty ifTrue:[

            self viewNoteBookApplicationHolder value:false.

            self enableViewNoteBookApplication value:false.

            self changeFileBrowserTitleTo:'FileBrowser V2'.

        ] ifFalse:[

            historyList notEmpty ifTrue:[

                self selectedEditorPage value:(self selectionHistoryList last).

            ]

        ]

    ].

    "/ because subCanvas was configured to keep its view,

    "/ we must destroy it here.

    aApplication window destroy.

!

destroyTab:tabIndex

    (self listOfApplications at:tabIndex) doClose

!

doCloseAllApplications

    (Dialog confirm:(resources string:'Really close all Tabs ?')) ifTrue:[

        "/ must enumerate a copy here

        self listOfApplications copy do:[:eachApp | eachApp doClose.].

    ].

!

doCloseAllOtherApplications

    | currentApp |

    "/ (Dialog confirm:(resources string:'Really close all other Tabs ?')) ifFalse:[^ self].

    currentApp := self currentTabMenusApplication.

    "/ must enumerate a copy here

    self listOfApplications copy do:[:eachApp | 

        eachApp ~~ currentApp ifTrue:[

            eachApp doClose.

        ].

    ]

!

doCloseApplication

    self currentTabMenusApplication doClose.

!

doRenameTab

    | newLabel |