"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

StandardSystemView subclass:#ChangesBrowser

	instanceVariableNames:'changeListView codeView changeFileName changeChunks

		changePositions changeClassNames changeHeaderLines

		changeIsFollowupMethodChange anyChanges changeNrShown

		changeNrProcessed skipSignal compareChanges compareCheckBox

		changeFileSize changeFileTimestamp checkBlock changeTimeStamps

		tabSpec autoUpdate editingClassSource lastSearchType'

	classVariableNames:'CompressSnapshotInfo'

	poolDictionaries:''

	category:'Interface-Browsers'

!

!ChangesBrowser class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this implements a browser for the changes-file.

    See the extra document 'doc/misc/cbrowser.doc' for how to use this browser.

    written jan 90 by claus

    [Class variables:]

	CompressSnapshotInfo            if true (the default), snapshot entries

					are also compressed in the compress function.

					Some users prefer them to be not compressed.

					Set it to false for this.

    Notice:

	this needs a total rewrite, to build up a changeSet from the file

	(which did not exist when the ChangesBrowser was originally written) 

	and manipulate that changeSet.

	This way, we get a browser for any upcoming incore changeSets for

	free. Also, this will put the chunk analyzation code into Change and

	subclasses (where it belongs) and give a better encapsulation and

	overall structure. Do not take this as an example for good style ;-)

    [author:]

	Claus Gittinger

    [start with:]

	ChangesBrowser open

    [see also:]

	( Using the ChangesBrowser :html: tools/cbrowser/TOP.html )

"

! !

!ChangesBrowser class methodsFor:'instance creation'!

new

    "create a new changes browser"

    ^ super 

        label:(self defaultLabel)

        icon:(self defaultIcon)

    "Modified: / 6.2.1998 / 13:25:18 / cg"

!

openOn:aFileName

    "create c changes browser on a change file"

    ^ ((self new label:(self defaultLabel , ': ', aFileName)) 

        changeFileName:aFileName) open

    "Modified: / 6.2.1998 / 13:27:19 / cg"

! !

!ChangesBrowser class methodsFor:'behavior'!

autoSelectNext

    "returning true here, makes a Delete operation automatically

     select the next change"

    ^ true

! !

!ChangesBrowser class methodsFor:'defaults'!

defaultIcon

    "return the browsers default window icon"

    <resource: #style (#ICON #ICON_FILE)>

    |nm i|

    (i := DefaultIcon) isNil ifTrue:[

	i := self classResources at:'ICON' default:nil.

	i isNil ifTrue:[

	    nm := ClassResources at:'ICON_FILE' default:'CBrowser.xbm'.

	    i := Image fromFile:nm resolution:100.

	    i isNil ifTrue:[

		i := Image fromFile:('bitmaps/' , nm) resolution:100.

		i isNil ifTrue:[

		    i := StandardSystemView defaultIcon

		]

	    ]

	].

	i notNil ifTrue:[

	    DefaultIcon := i := i on:Display

	]

    ].

    ^ i

    "Modified: 19.3.1997 / 20:48:34 / ca"

    "Modified: 18.4.1997 / 15:16:24 / cg"

!

defaultLabel

    ^ 'Changes Browser'

! !

!ChangesBrowser methodsFor:'compiler interface'!

wantChangeLog

    "sent by the compiler to ask if a changeLog entry should

     be written. Return false here."

    ^ false

! !

!ChangesBrowser methodsFor:'error handling'!

correctableError:aString position:relPos to:relEndPos from:aCompiler

    "compiler notifys us of an error - this should really not happen since

     changes ought to be correct (did someone edit the changes file ??).

     Show the bad change in the codeView and let codeView hilight the error;

     no corrections allowed here therefore return false"

    self error:aString position:relPos to:relEndPos from:aCompiler.

    ^ false

!

error:aString position:relPos to:relEndPos from:aCompiler

    "compiler notifys us of an error - this should really not happen since

     changes ought to be correct (did someone edit the changes file ??).

     Show the bad change in the codeView and let codeView hilight the error"

    |action|

    (changeNrProcessed ~~ changeNrShown) ifTrue:[

	self changeSelection:changeNrProcessed

    ].

    (skipSignal notNil) ifTrue:[

	codeView highlightingErrorPosition:relPos to:relEndPos do:[

	    |box|

	    "

	     start dialog - make certain cleanup is done

	    "

	    action := OptionBox 

			  request:aString

			  label:'Error'

			  form:(WarningBox iconBitmap)

			  buttonLabels:#('cancel' 'skip' 'continue')

			  values:#(#abort #skip #continue)

			  default:#continue.

	].

	action == #abort ifTrue:[

	    Object abortSignal raise.

	    ^ false

	].

	action == #skip ifTrue:[

	    skipSignal raise.

	    ^ false

	].

	^  false 

    ].

    ^ codeView error:aString position:relPos to:relEndPos from:aCompiler

    "Modified: 20.2.1996 / 20:47:59 / cg"

!

warning:aString position:relPos to:relEndPos from:aCompiler

    "compiler notifys us of a warning - ignore it"

    ^ self

! !

!ChangesBrowser methodsFor:'event handling '!

handlesKeyPress:key inView:view

    "this method is reached via delegation: are we prepared to handle

     a keyPress in some other view ?"

    <resource: #keyboard (#Delete #BackSpace #Accept #Find #FindPrev #FindNext)>

    view == changeListView ifTrue:[

	(key == #Delete 

	or:[key == #BackSpace

	or:[key == #Accept

	or:[key == #Find

	or:[key == #FindPrev

	or:[key == #FindNext]]]]]) ifTrue:[^ true].

    ].

    ^ false

    "Modified: 8.4.1997 / 11:01:42 / cg"

!

keyPress:key x:x y:y view:view

    "this method is reached via delegation from the changeListView"

    <resource: #keyboard (#Delete #BackSpace #Accept #Find #FindPrev #FindNext)>

    (key == #Delete or:[key == #BackSpace]) ifTrue:[

        self doDelete.

        ^ self

    ].

    (key == #Accept) ifTrue:[

        self doApply.

        ^ self

    ].

    (key == #Find) ifTrue:[

        self findClass.

        ^ self

    ].

    (key == #FindPrev) ifTrue:[

        self findPrevious.

        ^ self

    ].

    (key == #FindNext) ifTrue:[

        self findNext.

        ^ self

    ].

    changeListView keyPress:key x:x y:y

    "Modified: / 18.6.1998 / 22:15:36 / cg"

! !

!ChangesBrowser methodsFor:'help '!

helpTextFor:aComponent

    |s|

    aComponent == codeView ifTrue:[

	s := 'HELP_CODEVIEW'

    ].

    aComponent == changeListView ifTrue:[

	s := 'HELP_CHANGELIST'

    ].

    ((aComponent == compareCheckBox)

    or:[aComponent superView == compareCheckBox]) ifTrue:[

	s := 'HELP_CHECK_COMPARE'

    ].

    s notNil ifTrue:[

	^ resources string:s

    ].

    ^ nil

!

showActivity:someMessage

    "some activityNotification to be forwarded to the user;

     show it in the windows title area here."

    self label:someMessage

    "Created: 24.2.1996 / 19:35:42 / cg"

    "Modified: 23.4.1996 / 21:39:36 / cg"

! !

!ChangesBrowser methodsFor:'initialize / release'!

changeListMenu

    <resource: #keyboard ( #Accept #Delete ) >

    <resource: #programMenu >

    |items m|

    self sensor ctrlDown ifTrue:[

        lastSearchType == #selector ifTrue:[

            items := #(

                              ('search class'                 findClass             #Find         )

                              ('next for this class'          findNextForClass                    )

                              ('previous for this class'      findPreviousForClass                )

                              ('-'                                                                )

                              ('search selector'              findSelector                        )

                              ('next with this selector'      findNextForSelector     #FindNext   )

                              ('previous with this selector'  findPreviousForSelector #FindPrev   )

                     ).

        ] ifFalse:[

            items := #(

                              ('search class'                 findClass             #Find         )

                              ('next for this class'          findNextForClass      #FindNext     )

                              ('previous for this class'      findPreviousForClass  #FindPrev     )

                              ('-'                                                                )

                              ('search selector'              findSelector                        )

                              ('next with this selector'      findNextForSelector                 )

                              ('previous with this selector'  findPreviousForSelector             )

                     ).

        ].

        ^ PopUpMenu itemList:items resources:resources.

    ].

    items := #(

                      ('apply'                        doApply                    Accept)

                      ('apply to end'                 doApplyRest                      )

                      ('apply for class to end'       doApplyClassRest                 )

                      ('apply all'                    doApplyAll                       )

                      ('-'                                                             )

                      ('delete'                       doDelete                   Delete)

                      ('delete to end'                doDeleteRest                     )

                      ('delete for class to end'      doDeleteClassRest                )

                      ('delete for class from begin'  doDeleteClassFromBeginning       )

                      ('delete all for class'         doDeleteClassAll                 )

                      ('-'                                                             )

                      ('update view'                  doUpdate                         )

                      ('compress'                     doCompress                       )

                      ('compress for class'           doCompressClass                  )

                      ('compare with current version' doCompare                        )

                      ('browse'                       doBrowse                         )

                      ('-'                                                             )

                      ('make change a patch'          doMakePatch                      )

             ).

    editingClassSource ifFalse:[

        items := items , #(

                      ('fileout & delete all for class' doFileoutAndDeleteClassAll     )

                          )

    ].

    items := items , #(

                      ('-'                                             )

                      ('save in ...'                  doSave           )

                      ('save to end in ...'           doSaveRest       )

                      ('save for class to end in ...' doSaveClassRest  )

                      ('save all for class in ...'    doSaveClassAll   )

                      ('-'                                             )

                     ).

    editingClassSource ifTrue:[

        items := items , #(

                      ('writeback classFile'  doWriteBack )

                     )

    ] ifFalse:[

        items := items , #(

                      ('writeback changeFile' doWriteBack )

                     )

    ].

    m := PopUpMenu itemList:items resources:resources.

    "/

    "/ disable those that require a selected entry

    "/

    changeListView hasSelection ifFalse:[

        m disableAll:#(doApply doApplyClassRest doApplyRest doDelete doDeleteRest doDeleteClassRest

                       doDeleteClassFromBeginning doDeleteClassAll 

                       doCompare doCompressClass doMakePatch doSaveChangeInFile doMakePermanent

                       doSave doSaveRest doSaveClassAll doSaveClassRest doBrowse doFileoutAndDeleteClassAll) 

    ] ifTrue:[

        (self classNameOfChange:(changeListView selection)) isNil ifTrue:[

            m disableAll:#(doApplyClassRest doDeleteClassRest

                           doDeleteClassFromBeginning doDeleteClassAll 

                           doCompressClass

                           doSaveClassAll doSaveClassRest doBrowse doFileoutAndDeleteClassAll) 

        ]

    ].

    "/

    "/ disable those that do not make sense with autoUpdate

    "/ ('cause this would be overwritten by next update operation)

    "/

    autoUpdate ifTrue:[

        m disableAll:#(doDelete doDeleteRest doDeleteClassRest doDeleteClassAll doCompress 

                       doFileoutAndDeleteClassAll doWriteBack)

    ].

    ^ m

    "Modified: / 6.9.1995 / 17:14:22 / claus"

    "Modified: / 18.6.1998 / 22:28:34 / cg"

!

compare:aBoolean

    "sent from the compare-toggle"

    aBoolean ~~ compareChanges ifTrue:[

	compareChanges := aBoolean.

	compareChanges ifTrue:[

	    tabSpec positions:#(0  0.15  5   8.5 ).

	    self doUpdate

	] ifFalse:[

	    "/

	    "/ set tabs to hide compare-column

	    "/

	    tabSpec positions:#(-1  0    5   8.5 ).

	    changeListView invalidate. "/ clear; redraw.

	]

    ]

    "Modified: 29.5.1996 / 16:12:19 / cg"

!

focusSequence

    ^ Array with:changeListView with:codeView

!

initialize

    |panel v upperFrame buttonPanel autoUpdateCheckBox|

    super initialize.

    changeFileName := ObjectMemory nameForChanges. "/ 'changes'.

    compareChanges := false.

    autoUpdate := false.

    "

      checkBlock is executed by the Processor.

      We use #pushEvent: to perform the update

      in our windowgroups process.

    "

    checkBlock := [self pushEvent:#checkIfFileHasChanged].

    panel := VariableVerticalPanel origin:(0.0 @ 0.0)

                                   corner:(1.0 @ 1.0)

                              borderWidth:0

                                       in:self.

    upperFrame := View origin:(0.0 @ 0.0) corner:(1.0 @ 0.3) in:panel.

    v := HVScrollableView for:SelectionInListView miniScrollerH:true in:upperFrame.

    v origin:(0.0 @ 0.0) corner:(0.8 @ 1.0).

    changeListView := v scrolledView.

    changeListView delegate:self.

    changeListView menuHolder:self; menuPerformer:self; menuMessage:#changeListMenu.

    changeListView doubleClickAction:[:line | self doubleClickOnChange:line].

    buttonPanel := VerticalPanelView in:upperFrame.

    buttonPanel origin:(0.8 @ 0.0) corner:(1.0 @ 1.0).

    buttonPanel verticalLayout:#topSpace; horizontalLayout:#leftSpace.

    compareCheckBox := CheckBox new.

    compareCheckBox label:(resources string:'compare').

    compareCheckBox action:[:val | self compare:val].

    buttonPanel addSubView:compareCheckBox.

    autoUpdateCheckBox := CheckBox new.

    autoUpdateCheckBox label:(resources string:'auto update').

    autoUpdateCheckBox action:[:val | self autoUpdate:val].

    buttonPanel addSubView:autoUpdateCheckBox.

    v := HVScrollableView for:CodeView miniScrollerH:true miniScrollerV:false in:panel.

    v origin:(0.0 @ 0.3) corner:(1.0 @ 1.0).

    codeView := v scrolledView.

    codeView readOnly.

    anyChanges := false.

    ObjectMemory addDependent:self.   "to get shutdown-update"

    tabSpec := TabulatorSpecification new.

    tabSpec unit:#inch.

    tabSpec positions:#(-1      0        5      8.5 ).

    "                   +/-    cls>>sel  type   info"

    tabSpec align:    #(#left  #left     #left  #left).

    "Modified: / 27.3.1997 / 11:07:07 / stefan"

    "Modified: / 6.2.1998 / 13:08:16 / cg"