"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

Object subclass:#ProjectDefinition

	instanceVariableNames:''

	classVariableNames:'LibraryType GUIApplicationType NonGUIApplicationType

		PackagesBeingLoaded Verbose AbbrevDictionary AccessLock'

	poolDictionaries:''

	category:'System-Support-Projects'

!

ProjectDefinition class instanceVariableNames:'safeForOverwrittenMethods extensionOverwriteInfo projectIsLoaded'

"

 No other class instance variables are inherited by this class.

"

!

Object subclass:#AbbrevEntry

	instanceVariableNames:'className fileName category numClassInstVars'

	classVariableNames:''

	poolDictionaries:''

	privateIn:ProjectDefinition

!

!ProjectDefinition class methodsFor:'documentation'!

buildingMakefiles

"

    You can define additional rules and flag settings for use in the makeFile generation:

    redefinable build-file attributes:

        stcOptimizationOptions  -> STCLOCALOPT

        stcWarningOptions       -> STCLOCALOPT

        localIncludes_unix      -> LOCALINCLUDES (Make.proto)

        localIncludes_win32     -> LOCALINCLUDES (bc.mak)

    for applications:

        startupClassName

        startupSelector

    for libraries:

"

!

copyright

"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    As ST/X is (still) very tightly bound with stc, we keep the package and project information

    in a class-object (instead of some Project-object). This has the advantage, that it can be

    compiled and included in a compiled class library just like any other class.

    Every package includes an subclass of me (an instance of my meta), which provides useful

    information about the versioning and packaging. Me myself, I know how to generate dependency

    information and can generate makefiles and other build-support files for compilation.

    Some special notes about extension methods:

    if a package is loaded (Smalltalk loadPackage:'foo:bar/baz'), any already loaded package of which

    methods are overwritten by an extension of this package, the other package is asked to safe those

    methods in its safe(ForOverwrittenMethods). Thus, if the other package or any of its classes is asked

    to file itself out, it can do so using the safe (otherwise, you'D not be able to checkin a class while

    it has an overriding extension loaded).

    Also, the information about which other package was in charge when a method is overwritten is recorded in

    extensionOverwriteInfo. This is used to correctly reinstall an overwritten method, whenever a package is

    unloaded.

"

! !

!ProjectDefinition class methodsFor:'instance creation'!

definitionClassForMonticelloPackage:aMonicelloPackagename

    ^ self definitionClassForMonticelloPackage:aMonicelloPackagename createIfAbsent:false

    "

     self definitionClassForMonticelloPackage:'foobar'

    "

!

definitionClassForMonticelloPackage:aMonicelloPackagename createIfAbsent:createIfAbsent

    ^ self allSubclasses

        detect:[:eachProjectDefinition |

            eachProjectDefinition monticelloPackageName = aMonicelloPackagename ]

        ifNone:[

            |dfn squeakPackageInfo|

            createIfAbsent ifTrue:[

                dfn := ApplicationDefinition

                    definitionClassForPackage:'mc:',aMonicelloPackagename createIfAbsent:true projectType:GUIApplicationType.

                "/ if the squeak-stuff is loaded, use it.

                PackageInfo notNil ifTrue:[

                    squeakPackageInfo := PackageInfo allSubclasses

                                            detect:[:pi | pi new packageName = aMonicelloPackagename] ifNone:nil.

                ].

                squeakPackageInfo notNil ifTrue:[

                    dfn classNames:(squeakPackageInfo new classes collect:[:each | each name]).

                ].

            ] ifFalse:[

                nil

            ]

        ]

    "

     self definitionClassForMonticelloPackage:'foobar'

     self definitionClassForMonticelloPackage:'foobar' createIfAbsent:true

    "

    "Modified: / 30-10-2010 / 00:26:07 / cg"

!

definitionClassForPackage:aPackageID

    ^ self definitionClassForPackage:aPackageID createIfAbsent:false

    "Modified: / 17-08-2006 / 14:33:35 / cg"

!

definitionClassForPackage:aPackageID createIfAbsent:doCreateIfAbsent

    ^ self definitionClassForPackage:aPackageID createIfAbsent:doCreateIfAbsent projectType:nil

    "Modified: / 23-08-2006 / 14:29:15 / cg"

!

definitionClassForPackage: aPackageID createIfAbsent: doCreateIfAbsent projectType:typeOrNil

    |packageDefinitionClassName class|

    packageDefinitionClassName := self initialClassNameForDefinitionOf:aPackageID.

    class := Smalltalk classNamed:packageDefinitionClassName.

    class isNil ifTrue:[

        doCreateIfAbsent ifTrue:[

            class := self newForPackage:aPackageID.

            "setup before prerequisites are defined"

            class setupForType:typeOrNil.

            "/ look what is there and include it; is this ok ?

            class compileDescriptionMethods

        ].

    ] ifFalse:[

        typeOrNil notNil ifTrue:[

            class projectType == typeOrNil ifFalse: [

                class setupForType:typeOrNil.

            ].

        ].

    ].

    ^ class

    "Created: / 23-08-2006 / 14:29:21 / cg"

    "Modified: / 23-08-2006 / 15:35:26 / cg"

!

definitionClassForPackage:newProjectID projectType:typeOrNil createIfAbsent:createIfAbsent

    ^ (self definitionClassForType:typeOrNil)

            definitionClassForPackage:newProjectID

            createIfAbsent:createIfAbsent

            projectType:typeOrNil

    "Created: / 23-08-2006 / 14:28:53 / cg"

!

definitionClassForType: type

    "answer the class that describes a give project type"

    (type = LibraryType) ifTrue:[ ^ LibraryDefinition ].

    (type = GUIApplicationType) ifTrue:[ ^ ApplicationDefinition ].

    (type = NonGUIApplicationType) ifTrue:[ ^ ApplicationDefinition ].

    (type = 'Application') ifTrue:[ ^ ApplicationDefinition ].     "/ temporary - for backward compat.

    self error:'unknown project type'.

    "Created: / 17-08-2006 / 14:46:28 / cg"

    "Modified: / 23-08-2006 / 13:49:27 / cg"

!

newForPackage:packageID

    ^ self

        newNamed:(self initialClassNameForDefinitionOf:packageID)

        package:packageID.

    "Created: / 11-08-2006 / 14:27:19 / cg"

!

newNamed:newName package:packageID

    |newClass|

    "/ for now, we are strict.

    self assert:(self initialClassNameForDefinitionOf:packageID) = newName.

    self assert:(self ~~ ProjectDefinition).  "ProjectDefinition is abstract"

    newClass := self

                    subclass:(newName asSymbol)

                    instanceVariableNames:''

                    classVariableNames:''

                    poolDictionaries:''

                    category:(self defaultCategory).

    newClass package:packageID asSymbol.

    ^ newClass

    "Created: / 09-08-2006 / 17:57:37 / fm"

    "Modified: / 09-08-2006 / 19:27:53 / fm"

    "Modified: / 17-08-2006 / 17:24:23 / cg"

! !

!ProjectDefinition class methodsFor:'accessing'!

allPreRequisites

    "answer all (recursive) prerequisite project ids of myself - in random order."

    ^ self allPreRequisitesWithParentDo:[:parent :prereq |

        prereq = self package ifTrue:[ Transcript showCR:('oops: %1 depends on itself' bindWith:prereq) ].

      ]

    "

     stx_libbasic allPreRequisites

     stx_libbasic2 allPreRequisites

     stx_libview2 allPreRequisites

     ubs_application allPreRequisites

     ubs_application allPreRequisitesSorted

     exept_expecco_application allPreRequisites

     exept_expeccoNET_application allPreRequisites

     alspa_batch_application allPreRequisites

    "

    "Modified: / 13-04-2011 / 15:30:45 / sr"

    "Modified (comment): / 06-09-2011 / 08:26:06 / cg"

!

allPreRequisitesSorted

    "answer all the prerequisites of this projects sorted in

     the order they are needed.

     Use this to e.g. compile packages in the dependency order"

    |allPreRequisites orderedTuples effective allPreRequisitesWithExtensions sortedPackages|

    orderedTuples := OrderedCollection new.

    allPreRequisites := self allPreRequisites.

    allPreRequisitesWithExtensions := allPreRequisites union:self extensionPackages.

    allPreRequisites do:[:eachPackageID |

        |def|

        self assert:(eachPackageID ~= self package).

        orderedTuples add:(Array with:eachPackageID with:self package).

        def := self definitionClassForPackage:eachPackageID.

        def isNil ifTrue:[

            Transcript showCR:'Warning: no definition class for package: ', eachPackageID.

            effective := (self searchForPreRequisites: eachPackageID) keys.

        ] ifFalse:[

            effective := def effectivePreRequisites union:def extensionPackages.

            effective notEmptyOrNil ifTrue:[

                effective do:[:eachPrerequisitePackageID|

                    self assert:(eachPrerequisitePackageID ~= eachPackageID).

                    orderedTuples add:(Array with:eachPrerequisitePackageID with:eachPackageID).

                ].

            ].

        ].

    ].

    (orderedTuples detect:[:el | el first = el second] ifNone:nil) notNil ifTrue:[self halt].

    sortedPackages := orderedTuples topologicalSort.

    "packages which only result from extension methods are used for computing the sort order,

     but they are not added, if not present in the first place"

    ^ sortedPackages select:[:eachProject| allPreRequisites includes:eachProject]

    "

     stx_libbasic allPreRequisitesSorted

     stx_libbasic2 allPreRequisitesSorted

     stx_libwidg2 allPreRequisitesSorted

     exept_expecco_application allPreRequisitesSorted

     alspa_batch_application allPreRequisitesSorted

     ubs_application allPreRequisitesSorted

    "

    "Modified: / 13-04-2011 / 15:19:13 / sr"

    "Modified: / 28-06-2011 / 14:04:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

allPreRequisitesWithParentDo:aBlock

    "answer all (recursive) prerequisite project ids of myself - in random order.

     If we exclude a project, but one of our prerequisite projects depends on it,

     then what ????"

    |setOfAllPreRequisites toAdd|

    setOfAllPreRequisites := Set new.

    toAdd := Set new.

    toAdd addAll:self effectivePreRequisites.

    "is a subproject really a prerequisite??

     No, it works the other way: parent projects are prerequisites of sub projects,

     so the following line has been deleted.

     Unfortunately the meaning of 'subproject' has never been well defined. SV."

"/    toAdd addAll:self effectiveSubProjects.

    [toAdd notEmpty] whileTrue:[

        |aPreRequisiteProjectID def|

        aPreRequisiteProjectID := toAdd removeFirst.

        (setOfAllPreRequisites includes:aPreRequisiteProjectID) ifFalse:[

            setOfAllPreRequisites add:aPreRequisiteProjectID.

            def := self definitionClassForPackage:aPreRequisiteProjectID.

            def isNil ifTrue:[

                Transcript showCR:'ProjectDefinition ', aPreRequisiteProjectID, ' is missing - cannot find its preRequisites.'.

            ] ifFalse:[

                def effectivePreRequisites

                    select:[:eachSubPreRequisite | (setOfAllPreRequisites includes:eachSubPreRequisite) not]

                    thenDo:[:eachSubPreRequisite |

                                Verbose == true ifTrue:[

                                    Transcript show:'ProjectDefinition preRequisites: '; showCR:(aPreRequisiteProjectID, ' requires ', eachSubPreRequisite).

                                ].

                                aBlock value:def value:eachSubPreRequisite.

                                toAdd add:eachSubPreRequisite

                           ].

                "but subprojects of our prerequisites are also prerequisites"

                def effectiveSubProjects

                    select:[:eachSubSubRequisite | eachSubSubRequisite ~= self package and:[ (setOfAllPreRequisites includes:eachSubSubRequisite) not ]]

                    thenDo:[:eachSubSubRequisite |

                                Verbose == true ifTrue:[

                                    Transcript show:'ProjectDefinition preRequisites: '; showCR:(aPreRequisiteProjectID, ' hasSub ', eachSubSubRequisite).

                                ].

                                aBlock value:def value:eachSubSubRequisite.

                                toAdd add:eachSubSubRequisite

                           ].

            ].

        ]

    ].

    ^ setOfAllPreRequisites.

    "

     stx_libbasic allPreRequisites

     stx_libbasic2 allPreRequisites

     stx_libview2 allPreRequisites

     ubs_application allPreRequisites

     ubs_application allPreRequisitesSorted

     exept_expecco_application allPreRequisites

     exept_expeccoNET_application allPreRequisites

     alspa_batch_application allPreRequisites

    "

    "Created: / 13-04-2011 / 15:23:21 / sr"

    "Modified: / 20-07-2012 / 18:29:31 / cg"

!

directory

    "for packageId compatibility"

    ^ self moduleDirectory

    "

     bosch_dapasx_datenbasis_Definition moduleDirectory

     bosch_dapasx_parameter_system_Definition moduleDirectory

     stx_libbasic3 moduleDirectory

     cg_croquet moduleDirectory

     cg_croquet package asPackageId module

     cg_croquet moduleDirectory

     stx_goodies_xml_vw moduleDirectory

    "

    "Created: / 08-08-2006 / 20:25:39 / fm"

    "Modified: / 18-08-2006 / 12:18:33 / cg"

!

extensionsRevisionInfoForManager:managerOrNil

    "return the revisionInfo object for my extensions for a particular source code manager.

     Return nil, if there is either no manager, or I have no extensions"

    |mgr versionMethod revString|

    (mgr := managerOrNil) isNil ifTrue:[

        mgr := SourceCodeManagerUtilities default sourceCodeManagerFor:self.

        mgr isNil ifTrue:[

            ^ nil

        ].

    ].

    versionMethod := mgr nameOfVersionMethodForExtensions.

    (self class implements:versionMethod) ifFalse:[^ nil].

    revString := self perform:(mgr nameOfVersionMethodForExtensions) ifNotUnderstood:nil.

    revString isNil ifTrue:[

        ^ nil.

    ].

    ^ mgr revisionInfoFromString:revString.

    "

     (stx_libcomp extensionsRevisionInfoForManager:nil) revision  

     (stx_libbasic extensionsRevisionInfoForManager:nil) 

    "

    "Created: / 25-11-2011 / 14:34:01 / cg"

!

initialClassNameForDefinitionOf:aPackageId

    "given a package-ID, return an appropriate class name for this package"

    |s|

    s := aPackageId asString copy replaceAny:':/' with:$_.

    (s endsWith:$_) ifTrue:[

        s := s copyWithoutLast:1

    ].

    ^ s

    "

     DapasXProject initialClassNameForDefinitionOf:'bosch:dapasx/interactiver_editor'

     DapasXProject initialClassNameForDefinitionOf:'stx:libbasic'

     DapasXProject initialClassNameForDefinitionOf:'stx:goodies/xml'

    "

    "Created: / 09-08-2006 / 17:44:47 / fm"

    "Modified: / 11-08-2006 / 14:00:05 / cg"

!

libraryName

    ^ self package asPackageId libraryName

    "

     bosch_dapasx_datenbasis libraryName

     stx_libbasic3 libraryName

    "

    "Modified: / 09-08-2006 / 18:20:29 / fm"

    "Modified: / 18-08-2006 / 12:36:45 / cg"

!

libraryNameFor:aProjectID

    ^ aProjectID asPackageId libraryName

    "

     bosch_dapasx_datenbasis libraryName

     stx_libbasic3 libraryNameFor:'stx:libbasic'

     stx_libbasic3 libraryNameFor:'bosch:dapasx/datenbasis'

    "

    "Modified: / 09-08-2006 / 18:20:29 / fm"

    "Modified: / 18-08-2006 / 12:37:02 / cg"

!

loadDirectory

    "if I was loaded from a directory (as oposed to loaded via a dll or from a scm),

     return that directory. Otherwise return nil."

    ^ self getAttribute:#projectDirectory

!

loadDirectory:aDirectory

    "remember the directory from which I was loaded from"

    self setAttribute:#projectDirectory to:aDirectory

!

module

    ^ self moduleOfClass:self

    "

       bosch_dapasx_datenbasis_Definition module

       DapasX_Datenbasis module

       stx_libbasic3 module

       stx_libbasic3 directory

    "

    "Created: / 08-08-2006 / 20:24:53 / fm"