"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

StandardSystemView subclass:#ChangesBrowser

	instanceVariableNames:'changeListView codeView changeFileName changeChunks

		changePositions changeClassNames changeHeaderLines

		changeIsFollowupMethodChange anyChanges changeNrShown

		changeNrProcessed skipSignal compareChanges compareCheckBox

		changeFileSize changeFileTimestamp checkBlock changeTimeStamps

		tabSpec autoUpdate editingClassSource lastSearchType

		lastSearchString applyInOriginalNameSpace lastSaveFileName'

	classVariableNames:'CompressSnapshotInfo NoColoring ShowWarningDialogs DefaultIcon'

	poolDictionaries:''

	category:'Interface-Browsers'

!

!ChangesBrowser class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this implements a browser for the changes-file (actually, it can display

    any sourceFiles contents).

    See the extra document 'doc/misc/cbrowser.doc' for how to use this browser.

    written jan 90 by claus

    [Class variables:]

        CompressSnapshotInfo            if true (the default), snapshot entries

                                        are also compressed in the compress function.

                                        Some users prefer them to be not compressed.

                                        Set it to false for this.

    Notice:

        this needs a total rewrite, to build up a changeSet from the file

        (which did not exist when the ChangesBrowser was originally written) 

        and manipulate that changeSet.

        This way, we get a browser for any upcoming incore changeSets for

        free. Also, this will put the chunk analyzation code into Change and

        subclasses (where it belongs) and give a better encapsulation and

        overall structure. Do not take this as an example for good style ;-)

        The Change hierarchy is currently been completed, and the changes browser

        will be adapted soon.

    [author:]

        Claus Gittinger

    [start with:]

        ChangesBrowser open

    [see also:]

        ( Using the ChangesBrowser :html: tools/cbrowser/TOP.html )

"

! !

!ChangesBrowser class methodsFor:'instance creation'!

new

    "create a new changes browser"

    ^ super 

        label:(self defaultLabel)

        icon:(self defaultIcon)

    "Modified: / 6.2.1998 / 13:25:18 / cg"

!

openOn:aFileName

    "create c changes browser on a change file"

    ^ ((self new label:(self defaultLabel , ': ', aFileName)) 

        changeFileName:aFileName) open

    "Modified: / 6.2.1998 / 13:27:19 / cg"

! !

!ChangesBrowser class methodsFor:'behavior'!

autoSelectNext

    "returning true here, makes a Delete operation automatically

     select the next change"

    ^ true

! !

!ChangesBrowser class methodsFor:'defaults'!

defaultIcon

    "return the browsers default window icon"

    <resource: #style (#ICON #ICON_FILE)>

    |nm i|

    (i := DefaultIcon) isNil ifTrue:[

        i := self classResources at:'ICON' default:nil.

        i isNil ifTrue:[

            nm := ClassResources at:'ICON_FILE' default:'CBrowser.xbm'.

            i := Smalltalk imageFromFileNamed:nm inPackage:#'stx:libtool'.

            i isNil ifTrue:[

                i := StandardSystemView defaultIcon

            ]

        ].

        i notNil ifTrue:[

            DefaultIcon := i := i onDevice:Display

        ]

    ].

    ^ i

    "Modified: 19.3.1997 / 20:48:34 / ca"

    "Modified: 18.4.1997 / 15:16:24 / cg"

!

defaultLabel

    ^ 'Changes Browser'

!

isVisualStartable

    "return true, if this application can be started via #open.

     (to allow start of a change browser via double-click in the browser)"

    ^ true

    "Created: / 27.9.1999 / 12:28:27 / cg"

! !

!ChangesBrowser methodsFor:'compiler interface'!

wantChangeLog

    "sent by the compiler to ask if a changeLog entry should

     be written when compiling. Return false here."

    ^ false

! !

!ChangesBrowser methodsFor:'compiler interface - error handling'!

correctableError:aString position:relPos to:relEndPos from:aCompiler

    "compiler notifys us of an error - this should really not happen since

     changes ought to be correct (did someone edit the changes file ??).

     Show the bad change in the codeView and let codeView hilight the error;

     no corrections allowed here therefore return false"

    ShowWarningDialogs == true ifTrue:[

        self error:aString position:relPos to:relEndPos from:aCompiler.

    ] ifFalse:[

        Transcript showCR:aString.

    ].

    ^ false

!

correctableSelectorWarning:aString position:relPos to:relEndPos from:aCompiler

    "compiler notifys us of a warning"

    ^ false

    "Modified: / 19.1.2000 / 16:25:31 / cg"

    "Created: / 19.1.2000 / 16:27:23 / cg"

!

error:aString position:relPos to:relEndPos from:aCompiler

    "compiler notifys us of an error - this should really not happen since

     changes ought to be correct (did someone edit the changes file ??).

     Show the bad change in the codeView and let codeView hilight the error"

    |action|

    (changeNrProcessed ~~ changeNrShown) ifTrue:[

        self changeSelection:changeNrProcessed

    ].

    (skipSignal notNil) ifTrue:[

        codeView highlightingErrorPosition:relPos to:relEndPos do:[

            |box|

            "

             start dialog - make certain cleanup is done

            "

            action := OptionBox 

                          request:aString

                          label:'Error'

                          form:(WarningBox iconBitmap)

                          buttonLabels:#('cancel' 'skip' " 'shut up' " 'continue')

                          values:#(#abort #skip " #shutUp " #continue)

                          default:#continue.

        ].

"/        action == #shutUp ifTrue:[

"/            aCompiler ignoreWarnings.

"/            ^  false 

"/        ].

        action == #abort ifTrue:[

            Object abortSignal raise.

            ^ false

        ].

        action == #skip ifTrue:[

            skipSignal raise.

            ^ false

        ].

        ^  false 

    ].

    ^ codeView error:aString position:relPos to:relEndPos from:aCompiler

    "Modified: 20.2.1996 / 20:47:59 / cg"

!

warning:aString position:relPos to:relEndPos from:aCompiler

    "compiler notifys us of a warning - ignore it"

    ^ self

! !

!ChangesBrowser methodsFor:'event handling'!

handlesKeyPress:key inView:view

    "this method is reached via delegation: are we prepared to handle

     a keyPress in some other view ?"

    <resource: #keyboard (#Delete #BackSpace #Accept #Find #FindPrev #FindNext)>

    view == changeListView ifTrue:[

	(key == #Delete 

	or:[key == #BackSpace

	or:[key == #Accept

	or:[key == #Find

	or:[key == #FindPrev

	or:[key == #FindNext]]]]]) ifTrue:[^ true].

    ].

    ^ false

    "Modified: 8.4.1997 / 11:01:42 / cg"

!

keyPress:key x:x y:y view:view

    "this method is reached via delegation from the changeListView"

    <resource: #keyboard (#Delete #BackSpace #Accept #Find #FindPrev #FindNext)>

    (key == #Delete or:[key == #BackSpace]) ifTrue:[

        self doDelete.

        ^ self

    ].

    (key == #Accept) ifTrue:[

        self doApply.

        ^ self

    ].

    (key == #Find) ifTrue:[

        self findClass.

        ^ self

    ].

    (key == #FindPrev) ifTrue:[

        self findPrevious.

        ^ self

    ].

    (key == #FindNext) ifTrue:[

        self findNext.

        ^ self

    ].

    changeListView keyPress:key x:x y:y

    "Modified: / 18.6.1998 / 22:15:36 / cg"

! !

!ChangesBrowser methodsFor:'help '!

helpTextFor:aComponent

    |s|

    aComponent == codeView ifTrue:[

	s := 'HELP_CODEVIEW'

    ].

    aComponent == changeListView ifTrue:[

	s := 'HELP_CHANGELIST'

    ].

    ((aComponent == compareCheckBox)

    or:[aComponent superView == compareCheckBox]) ifTrue:[

	s := 'HELP_CHECK_COMPARE'

    ].

    s notNil ifTrue:[

	^ resources string:s

    ].

    ^ nil

!

showActivity:someMessage

    "some activityNotification to be forwarded to the user;

     show it in the windows title area here."

    self label:someMessage

    "Created: 24.2.1996 / 19:35:42 / cg"

    "Modified: 23.4.1996 / 21:39:36 / cg"

! !

!ChangesBrowser methodsFor:'initialize / release'!

changeListMenu

    "return the menu for the change (upper) list"

    <resource: #keyboard ( #Accept #Delete ) >

    <resource: #programMenu >

    |items m replNext replPrev|

    self sensor ctrlDown ifTrue:[

        "/ notice - findNext/prev shortKeys will search for the same thing again.

        items := #(

                          ('search class...'              findClass               #Find       )

                          ('next for this class'          findNextForClass        #FindNextClass      )

                          ('previous for this class'      findPreviousForClass    #FindPrevClass      )

                          ('-'                                                                )

                          ('search selector...'           findSelector                        )

                          ('next with this selector'      findNextForSelector     #FindNextSelector   )

                          ('previous with this selector'  findPreviousForSelector #FindPrevSelector   )

                          ('-'                                                                )

                          ('search string...'             findString                        )

                          ('next with this string'        findNextForString       #FindNextString   )

                          ('previous with this string'    findPreviousForString   #FindPrevString   )

                          ('-'                                                                )

                          ('next snapshot'                findNextSnapshot        #FindNextSnapshot   )

                          ('previous snapshot'            findPreviousSnapshot    #FindPrevSnapshot   )

                 ).

        lastSearchType == #selector ifTrue:[

            replNext := #FindNextSelector.

            replPrev := #FindPrevSelector.

        ] ifFalse:[

            lastSearchType == #snapshot ifTrue:[

                replNext := #FindNextSnapshot.

                replPrev := #FindPrevSnapshot.

            ] ifFalse:[

                lastSearchType == #string ifTrue:[

                    replNext := #FindNextString.

                    replPrev := #FindPrevString.

                ] ifFalse:[

                    replNext := #FindNextClass.

                    replPrev := #FindPrevClass.

                ]

            ]

        ].

        items := items deepCopy.

        items do:[:each | 

                        each replaceAll:replNext with:#FindNext.

                        each replaceAll:replPrev with:#FindPrev.

                        each replaceAny:#(FindNextClass FindPrevClass 

                                          FindNextSelector FindPrevSelector

                                          FindNextSnapshot FindPrevSnapshot

                                          FindNextString FindPrevString)

                             with:nil.

                 ].

        ^ PopUpMenu itemList:items resources:resources.

    ].

    items := #(

                      ('apply'                        doApply                    Accept)

                      ('apply to end'                 doApplyRest                      )

                      ('apply for class to end'       doApplyClassRest                 )

                      ('apply all'                    doApplyAll                       )

                      ('-'                                                             )

                      ('delete'                       doDelete                   Delete)

                      ('delete to end'                doDeleteRest                     )

                      ('delete for class to end'      doDeleteClassRest                )

                      ('delete for class from begin'  doDeleteClassFromBeginning       )

                      ('delete all for class'         doDeleteClassAll                 )

                      ('delete all for class & its private classes' doDeleteClassAndPrivateClassesAll )

                      ('-'                                                             )

                      ('compress'                     doCompress                       )

                      ('compress for class'           doCompressClass                  )

                      ('compare and compress'         doCompareAndCompress             )

                      ('-'                                                             )

                      ('compare with current version' doCompare                        )

                      ('browse class'                 doBrowse                         )

                      ('-'                                                             )

                      ('make change a patch'          doMakePatch                      )

             ).

    editingClassSource ifFalse:[

        items := items , #(

                      ('fileout & delete all for class' doFileoutAndDeleteClassAll     )

                      ('checkIn & delete all for class' doCheckinAndDeleteClassAll     )

                          )

    ].

    items := items , #(

                      ('-'                                            )

                      ('save in...'                  doSave           )

                      ('save to end in...'           doSaveRest       )

                      ('save for class to end in...' doSaveClassRest  )

                      ('save all for class in...'    doSaveClassAll   )

                      ('-'                                            )

                     ).

    editingClassSource ifTrue:[

        items := items , #(

                      ('writeback classFile'  doWriteBack )

                     )

    ] ifFalse:[

        items := items , #(

                      ('writeback changeFile' doWriteBack )

                     )

    ].

    items := items , #(

                  ('-'                                                             )

                  ('update view'                  doUpdate                         )

                 ).

    m := PopUpMenu itemList:items resources:resources.

    "/

    "/ disable those that require a selected entry

    "/

    changeListView hasSelection ifFalse:[

        m disableAll:#(doApply doApplyClassRest doApplyRest doDelete doDeleteRest doDeleteClassRest

                       doDeleteClassFromBeginning doDeleteClassAll doDeleteClassAndPrivateClassesAll 

                       doCompare doCompressClass doMakePatch doSaveChangeInFile doMakePermanent

                       doSave doSaveRest doSaveClassAll doSaveClassRest doBrowse 

                       doFileoutAndDeleteClassAll doCheckinAndDeleteClassAll) 

    ] ifTrue:[

        (self classNameOfChange:(changeListView selection)) isNil ifTrue:[

            m disableAll:#(doApplyClassRest doDeleteClassRest

                           doDeleteClassFromBeginning doDeleteClassAll doDeleteClassAndPrivateClassesAll

                           doCompressClass

                           doSaveClassAll doSaveClassRest doBrowse 

                           doFileoutAndDeleteClassAll doCheckinAndDeleteClassAll) 

        ]

    ].

    "/

    "/ disable those that do not make sense with autoUpdate

    "/ ('cause this would be overwritten by next update operation)

    "/

    autoUpdate ifTrue:[

        m disableAll:#(doDelete doDeleteRest doDeleteClassRest doDeleteClassAll 

                       doDeleteClassAndPrivateClassesAll doCompress 

                       doFileoutAndDeleteClassAll doCheckinAndDeleteClassAll

                       doWriteBack)

    ].

    ^ m

    "Modified: / 6.9.1995 / 17:14:22 / claus"

    "Modified: / 22.8.1998 / 15:50:17 / cg"

!

compare:aBoolean

    "sent from the compare-toggle"

    aBoolean ~~ compareChanges ifTrue:[

	compareChanges := aBoolean.

	compareChanges ifTrue:[

	    tabSpec positions:#(0  0.15  5   8.5 ).

	    self doUpdate

	] ifFalse:[

	    "/

	    "/ set tabs to hide compare-column