"

 COPYRIGHT (c) 1997 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

ImageView subclass:#ImageEditView

	instanceVariableNames:'magnification imageReaderClass resourceClass resourceSelector

		mouseKeyColorMode undoImages modifiedHolder editMode

		lastPastePoint imageInfoHolder activityInfoHolder

		pickedColorHolder drawingColors drawingPixels drawingColorHolders

		drawingPixelHolders clickInfoCallBack penWidth'

	classVariableNames:'Clipboard ClipboardMagnified LastMagnification

		GridMagnificationLimit MaxUndos LastSaveDirectory LastSaveClass

		EditModePoint EditModeBox EditModeFilledBox EditModeFill

		EditModeCopy EditModePasteUnder EditModePaste

		EditModePasteWithMask EditModeSpecialOperation'

	poolDictionaries:''

	category:'Views-Misc'

!

!ImageEditView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice. This software may not

 be provided or otherwise made available to, or used by, any

 other person. No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    An ImageEditView is a view which can be used by applications

    like the Image Editor for editing or inspecting (bitmap-) images.

    [see also:]

        ImageEditor Image

    [author:]

        Thomas Zwick

"

! !

!ImageEditView class methodsFor:'initialization'!

initialize

    MaxUndos := 10.

    GridMagnificationLimit := 8 @ 8.

    EditModePoint := #point.

    EditModeBox := #box.

    EditModePaste := #paste.

    EditModePasteUnder := #pasteUnder.

    EditModePasteWithMask := #pasteWithMask.

    EditModeFilledBox := #filledBox.

    EditModeFill := #fill.

    EditModeCopy := #copy.

    EditModeSpecialOperation := #specialOperation.

    "

     self initialize

    "

! !

!ImageEditView class methodsFor:'accessing'!

editModeBox

    ^ EditModeBox

!

editModeCopy

    ^ EditModeCopy

!

editModeFill

    ^ EditModeFill

!

editModeFilledBox

    ^ EditModeFilledBox

!

editModePaste

    ^ EditModePaste

!

editModePasteUnder

    ^ EditModePasteUnder

!

editModePasteWithMask

    ^ EditModePasteWithMask

!

editModePoint

    ^ EditModePoint

!

editModeSpecialOperation

    ^ EditModeSpecialOperation

!

gridMagnificationLimit

    ^ GridMagnificationLimit

!

gridMagnificationLimit:anInteger

    GridMagnificationLimit := anInteger

! !

!ImageEditView class methodsFor:'helpers'!

copyImageToClipboard:copiedImage

    ClipboardMagnified := nil.

    Clipboard := copiedImage.

! !

!ImageEditView class methodsFor:'resources'!

classResources

    ^ ImageEditor classResources

! !

!ImageEditView methodsFor:'accessing'!

activityInfoHolder

    "return the value of the instance variable 'activityInfoHolder' (automatically generated)"

    ^ activityInfoHolder

    "Created: / 29.7.1998 / 18:49:39 / cg"

!

activityInfoHolder:something

    "set the value of the instance variable 'activityInfoHolder' (automatically generated)"

    activityInfoHolder := something.

    "Created: / 29.7.1998 / 18:49:39 / cg"

!

clearModified

    self modified:false

!

clickInfoCallBack:aTwoArgBlock

     clickInfoCallBack := aTwoArgBlock

    "Created: / 10.2.2000 / 23:07:14 / cg"

!

clipBoard

    ^ Clipboard

!

drawingColors:anArrayTwoColors

    (drawingColorHolders at:1) value:(anArrayTwoColors at:1).

    (drawingColorHolders at:2) value:(anArrayTwoColors at:2).

!

image:anImage scroll:doScroll

    |retVal fileName|

    anImage isImage ifTrue:[           

        true "(image isNil or: [self checkModified])" ifTrue: [

            image notNil ifTrue: [

                fileName := image fileName.

                anImage fileName isNil ifTrue: [anImage fileName: fileName].

            ].

            super image:anImage scroll:doScroll.

            retVal := self.

        ].

    ] ifFalse: [

        super image:nil scroll:true.

    ].

    "/ self changed:#image.

    image isNil ifTrue:[

        self clearModified.

    ] ifFalse:[

        self setModified.

    ].

    self updateImageInfo: self imageInfoString. 

    ^ retVal

    "Modified: / 10.2.2000 / 23:33:12 / cg"

!

imageInfoHolder

    ^ imageInfoHolder

    "Created: / 29.7.1998 / 18:29:50 / cg"

!

imageInfoHolder:something

    imageInfoHolder := something.

    "Created: / 29.7.1998 / 18:29:50 / cg"

!

magnification

    ^magnification

!

magnification: aPoint

    |oldOrg|

    magnification ~= aPoint

    ifTrue:

    [

	oldOrg := self viewOrigin / magnification.

	magnification := aPoint asPoint.

	self scrollTo:(oldOrg * magnification) rounded redraw:false.        

"/        self scrollToTopLeft.

	self contentsChanged.

	self invalidate.

	ClipboardMagnified := nil.

    ]

    "Modified: / 31.7.1998 / 02:38:47 / cg"

!

modified

    ^ modifiedHolder value

!

modified:aBoolean

    modifiedHolder value:aBoolean

!

modifiedHolder

    ^ modifiedHolder

!

penWidth

    ^ penWidth ? 1

    "Created: / 01-11-2007 / 23:34:49 / cg"

!

penWidth:n

    penWidth := n

    "Created: / 01-11-2007 / 23:34:56 / cg"

!

removelastUndo

    undoImages removeLast

!

resourceClass

    ^ resourceClass

!

resourceClass: aClassOrClassNameString

    "support for names will vanish - obsolete left over from tz"

    resourceClass := aClassOrClassNameString.

    resourceClass notNil ifTrue:[

        resourceClass isBehavior ifFalse: [ 

            resourceClass := Smalltalk classNamed:aClassOrClassNameString 

        ]

    ]

!

resourceClassName

    resourceClass isNil ifTrue:[^ ''].

    ^ resourceClass name

!

resourceMessage

    (resourceClass isNil or:[resourceSelector isNil]) ifTrue:[^ ''].

    ^ resourceClass name, ' ', resourceSelector

!

resourceSelector

    ^ resourceSelector

!

resourceSelector: aStringOrSymbol

    aStringOrSymbol isNil ifTrue:[

        resourceSelector := nil

    ] ifFalse:[

        resourceSelector := aStringOrSymbol asSymbol

    ]

!

selectedColor

    ^ (drawingColorHolders at:mouseKeyColorMode) value

!

selectedColor: aColor

    (drawingColorHolders at:mouseKeyColorMode) value:aColor

!

selectedColorIndex

    ^ (drawingPixelHolders at:mouseKeyColorMode) value

!

selectedColorIndex: aPixelIndex

    (drawingPixelHolders at:mouseKeyColorMode) value: aPixelIndex

!

setModified

    self modified:true

!

undoImages

    ^ undoImages

! !

!ImageEditView methodsFor:'drawing'!

drawFrame

    self paint:Color black.

    self lineWidth: (magnification x//3 min: 3).

    self displayRectangle: ((0@0) extent:(image extent * magnification) + margin).

    self lineWidth:1.

!

drawFramesIn: aRectangle

    magnification >= GridMagnificationLimit

    ifTrue:

    [   

        |origin lineStartingPoint lineEndingPoint oldColor|

        origin := aRectangle origin - 1.

        lineStartingPoint := origin + (0@magnification y).

        lineEndingPoint   := lineStartingPoint + (aRectangle width@0).

        oldColor := self paint.

        self xoring:

        [

            self displayLineFrom: lineStartingPoint to: lineEndingPoint.

            lineStartingPoint x to: lineStartingPoint x + aRectangle width - magnification x by: magnification x do:

            [:x|   

                self displayLineFrom: x@(origin y) to: x@(origin y + magnification y)

            ].

        ].

        self paint: oldColor.

    ]

!

drawPasteRectangleAt: aPoint

    |currentPoint gridCorrection extent|

    magnification >= GridMagnificationLimit ifFalse: [gridCorrection := 0] ifTrue: [gridCorrection := 1].

    currentPoint := aPoint // magnification*magnification + margin. 

    self repairDamage.

    currentPoint ~= lastPastePoint ifTrue:[              

        ClipboardMagnified isNil ifTrue:[

            ClipboardMagnified := (Clipboard magnifiedBy: magnification) onDevice: device

        ].   

        "/ currentPoint := currentPoint - self viewOrigin.

        self redraw: (((lastPastePoint ? currentPoint)"-self viewOrigin") extent: extent).

        "/ self repairDamage.

false "        (extent x > 400 or: [extent y > 400])" ifTrue:[

            self xoring: [

                self fillRectangle: (currentPoint extent: extent)

            ]   

        ] ifFalse:[

            ClipboardMagnified notNil ifTrue:[

                self displayDeviceForm: ClipboardMagnified 

                                     x: currentPoint x - self viewOrigin x 

                                     y: currentPoint y - self viewOrigin y.

            ].

            editMode == EditModePastUnder ifTrue:[

                self redrawImageX:currentPoint x y:currentPoint y width:extent x height:extent y unmaskedOnly:true

            ]

        ]  

    ]. 

    lastPastePoint := currentPoint.

!

fillFramedRectangle: aRectangle

    self fillRectangle: aRectangle.

    self drawFramesIn: aRectangle

!

redraw:aRectangle

    self 

        invalidate:(aRectangle origin "+ self viewOrigin" extent:aRectangle extent)

        repairNow:true. 

"/    super redraw:(aRectangle origin + self viewOrigin extent:aRectangle extent).

    "Modified: / 15.11.2001 / 16:43:53 / cg"

!

redrawImageX:x y:y width:w height:h

    self redrawImageX:x y:y width:w height:h unmaskedOnly:false

    "Modified: / 18.5.1999 / 20:14:03 / cg"

!

redrawImageX:x y:y width:w height:h unmaskedOnly:unmaskedOnly

    |ih iw magX magY minX maxX minY maxY 

     color lastColor lastY runW x0 xI yI maskColor mask

     sizeOfMaskPoint useNearestColor|

    useNearestColor := device visualType == #PseudoColor.

    mask := image mask.

    ih := image height.

    iw := image width.

    magX := magnification x.

    magY := magnification y.

    minX := (x // magX - 1) max: 0.

    minX >= iw ifTrue:[minX := (iw - 1) max: 0].

    minY := (y // magY - 1) max: 0.

    minY >= ih ifTrue:[minY := (ih - 1) max: 0].

    maxX := (x + w) // magX + 1.

    maxX > iw ifTrue:[maxX := iw].

    maxY := (y + h) // magY + 1.

    maxY > ih ifTrue:[maxY := ih].

    lastY := -1.

    x0 := minX.

    runW := 0.

    maskColor := false.

    sizeOfMaskPoint := magnification//3.

    image 

        colorsFromX:minX y:minY toX:maxX-1 y:maxY-1 

        do:[:xx :yy :color|

            shown ifFalse:[^ self].

            yy ~~ lastY ifTrue:[

                runW ~~ 0 ifTrue:[

                    |origin|

                    origin := (x0 * magX + margin)@(lastY * magY + margin).

                    (unmaskedOnly not or:[maskColor not]) ifTrue:[

                        self fillFramedRectangle: (origin extent: (runW@magY)).                    

                        maskColor ifTrue:[

                            self xoring: [self fillRectangle: (origin + sizeOfMaskPoint extent: sizeOfMaskPoint)]

                        ]

                    ].

                    runW := 0.

                ]. 

                x0 := xx.

                lastY := yy.

            ]. 

            color ~= lastColor ifTrue:[

                runW ~~ 0 ifTrue:[

                    |origin|

                    origin := (x0 * magX + margin)@(yy * magY + margin).

                    (unmaskedOnly not or:[maskColor not]) ifTrue:[

                        self fillFramedRectangle: (origin extent: (runW@magY)).

                        maskColor ifTrue:[

                            self xoring: [self fillRectangle: (origin + sizeOfMaskPoint extent: sizeOfMaskPoint)]

                        ].

                    ].

                    runW := 0.

                ].